Kein doppelter Programstart aber Fenster in den Vordergrund

[r_kerber]

Hallo,

ich nutze die folgende Unit um einen doppelten Programmstart zu verhindern:

Delphi-Quellcode:

unit CopyVertragRunOnce;

interface

implementation

uses windows, Dialogs, sysutils, Forms;

var mHandle: THandle;    // Mutexhandle

Initialization
  mHandle := CreateMutex(nil, True, PChar(Application.Title));
  // 'xxxxx' Der Anwendungsname ist hier einzutragen
  if GetLastError = ERROR_ALREADY_EXISTS then begin   
    // Anwendung läuft bereits
    showMessage('Anwendung läuft bereits!!!!!');
    // Wenn du deine Meldung willst, mach die Klammern weg
    Halt;
  end;

finalization   // ... und Schluß
  if mHandle <> 0 then
    ReleaseMutex(mHandle);
end. {Dieter Hirt}

Ich möchte jetzt aber nicht eine Meldung auf den Bildschirm bekommen. Stattdessen soll die Instanz des Programmes, die schon läuft in den Vordergrund gehoben werden. Ich kann dies mit den API-Funktionen SetForegroundWindow oder BringWindowToTop erreichen. Beide benötigen jedoch das Fensterhandle. Gibt es eine Möglichkeit aus dem Mutex irgendwie das Fensterhandle zu ermitteln oder muß ich FindWindow verwenden?

[Luckie]

Ich denke, es führt kein Weg um FindWindow drumrum.

[r_kerber]

Und wellche Funktion nehme ich zum in den Vordergrund bringen. Bei mir passiert nämlich nichts. Kann auch sein, das ich die falschen Werte für class name bzw. window name verwende. :oops:

[Luckie]

Zeig mal Code. Zum Nachvorneholen würde ich SetWindowPos nehmen mit HWND_TOP als zweiten Parameter.

[toms]

Schau mal ins Attachment.

[Christian Seehase]

Moin Rainer,

Du könntest auch, mittels RegisterWindowMessage, eine eigene Message für Dein Programm erzeugen, die Du dann mittels Handle HWND_BROADCAST an alle Top Level Windows verschickst.
Die laufende Instanz kann sich dann selber in den Vordergrund holen, sobald es diese Message erhält.

Als Messagestring solltest Du Dir am besten eine GUID von der IDE generieren lassen, damit die Message auch eindeutig wird, und das Registrieren nicht fehlschlägt.

[r_kerber]

Mit SetWindowPos ändere ich doch auch die Fensterkoordinaten und -größe. :?
Hier jetzt der aktuelle Code der Unit:

Delphi-Quellcode:

unit CopyVertragRunOnce;

interface

implementation

uses windows, Dialogs, sysutils, Forms;

var
  mHandle: THandle;    // Mutexhandle
  hWindow: HWND;

Initialization
  mHandle := CreateMutex(nil, True, PChar(Application.Title));
  // 'xxxxx' Der Anwendungsname ist hier einzutragen
  if GetLastError = ERROR_ALREADY_EXISTS then begin   
    // Anwendung läuft bereits
    hWindow := FindWindow('TApplication', 'CopyVertrag');
//    BringWindowToTop(hWindow);
    SetForegroundWindow(hWindow);
//    showMessage('Anwendung läuft bereits!!!!!');
    // Wenn du deine Meldung willst, mach die Klammern weg
    Halt;
  end;

finalization   // ... und Schluß
  if mHandle <> 0 then
    ReleaseMutex(mHandle);
end. {Dieter Hirt}

[toms]

Zitat:

Mit SetWindowPos ändere ich doch auch die Fensterkoordinaten und -größe.

Wenn du die richtigen Parameter setzt, dann nicht. SetWindowPos ---> F1!

[r_kerber]

Zitat:

Zitat von toms

Wenn du die richtigen Parameter setzt, dann nicht. SetWindowPos ---> F1!

Man sollte die OH vollständig lesen :oops: Bringt aber trotzdem nichts. :wall:
@toms: Ist das wirklich so aufwändig?

[Rumpi]

Hallo alle zusammen,

alles Gute fürs Neue Jahr.

Delphi-Quellcode:

// ab damit in deine Tools.pas oder so

function ForceForegroundWindow(hwnd: THandle): boolean;
const
  SPI_GETFOREGROUNDLOCKTIMEOUT = $2000;
  SPI_SETFOREGROUNDLOCKTIMEOUT = $2001;
var
  ForegroundThreadID: DWORD;
  ThisThreadID : DWORD;
  timeout : DWORD;
begin
  if IsIconic(hwnd) then
    ShowWindow(hwnd, SW_RESTORE);
  if GetForegroundWindow = hwnd then
    Result := true
  else
  begin
  // Windows 98/2000 doesn't want to foreground a window when some other
  // window has keyboard focus

    if ((Win32Platform = VER_PLATFORM_WIN32_NT) and (Win32MajorVersion > 4)) or
       ((Win32Platform = VER_PLATFORM_WIN32_WINDOWS) and
       ((Win32MajorVersion > 4) or ((Win32MajorVersion = 4) and
       (Win32MinorVersion > 0)))) then
    begin
      // Code from Karl E. Peterson, [url]www.mvps.org/vb/sample.htm[/url]
      // Converted to Delphi by Ray Lischner
      // Published in The Delphi Magazine 55, page 16

      Result := false;
      ForegroundThreadID :=
      GetWindowThreadProcessID(GetForegroundWindow,nil);
      ThisThreadID := GetWindowThreadPRocessId(hwnd,nil);
      if AttachThreadInput(ThisThreadID, ForegroundThreadID, true) then
      begin
        BringWindowToTop(hwnd); // IE 5.5 related hack
        SetForegroundWindow(hwnd);
        AttachThreadInput(ThisThreadID, ForegroundThreadID, false);
        Result := (GetForegroundWindow = hwnd);
      end;
      if not Result then
      begin
        // Code by Daniel P. Stasinski

        SystemParametersInfo(SPI_GETFOREGROUNDLOCKTIMEOUT, 0, @timeout, 0);
        SystemParametersInfo(SPI_SETFOREGROUNDLOCKTIMEOUT, 0, TObject(0),
        SPIF_SENDCHANGE);
        BringWindowToTop(hwnd); // IE 5.5 related hack
        SetForegroundWindow(hWnd);
        SystemParametersInfo(SPI_SETFOREGROUNDLOCKTIMEOUT, 0,
        TObject(timeout), SPIF_SENDCHANGE);
      end;
    end
    else
    begin
      BringWindowToTop(hwnd); // IE 5.5 related hack
      SetForegroundWindow(hwnd);
    end;

    Result := (GetForegroundWindow = hwnd);
  end;
end; { ForceForegroundWindow }


....


var
  hW : hWnd;

  ....

  hW := FindWindowEx( 0,0,'TApplication', 'Deine Name den du suchst' );
  if IsWindow(hW ) then
  begin
    //... 
    Result := ForceForegroundWindow( hW );
    exit;
  end;

  // Bau deinen Mutex bitte mit ein
....

Ich hoffe das Hift dir Weiter

mfg Rumpi

[r_kerber]

Hallo Rumpi,

diese Möglichkeit kannte ich bereits (allerdings ohne die Erweiterung für aktuelle BS). Ich werde diese wohle nutzen, obwohl mir an anderer Stelle mal gesagt unter 32-Bit-Windows sollte man die Mutexe verwenden.

[MrKnogge]

Also ich benutze immer folgenden Code:

Delphi-Quellcode:

function BereitsAktiv: Boolean;
var 
  semName, 
  appClass: PChar; 
  hSem    : THandle; 
  hWndMe  : HWnd; 
  appTitle: Array[0..MAX_PATH] of Char; 
begin 
  // Init 
  Result := FALSE; 
  GetMem(semName,15); 
  GetMem(appClass,15); 
  StrPCopy(semName,'sema');
  StrPCopy(appClass,'TApplication'); 
  StrPCopy(appTitle,ExtractFileName(Application.Title)); 

  // Create a Semaphore in memory.  If this is the 
  // first instance, then hSem's value should be 0. 
  hSem := CreateSemaphore(nil,0,1,semName); 

  // Check to see if the semaphore exists 
  if (hSem <> 0) and (GetLastError() = 
                      ERROR_ALREADY_EXISTS) then 
    begin 
      CloseHandle(hSem); 

      // Get the current window's handle then change 
      // its title so we can look for the other instance 
      hWndMe := FindWindow(appClass,appTitle); 
      SetWindowText(hWndMe,'ZZZZZZZ'); 

      // Search for other instance of this window then bring 
      // it to the top of the Z-order stack.  We find it by 
      // matching the Application Class and 
      // Application Title. 
      hWndMe := FindWindow(appClass,appTitle); 
      if (hWndMe <> 0) then 
        begin 
          BringWindowToTop(hWndMe); 
          ShowWindow(hWndMe,SW_SHOWNORMAL);
          SetForeGroundWindow(hWndMe);
        end; 

      Result := TRUE; 
    end; 

  // Destroy PChars 
  FreeMem(semName,15); 
  FreeMem(appClass,15); 
end;


Initialization
if BereitsAktiv then
  Halt

Den habe ich mal hier im Forum gefunden, und noch "SetForeGroundWindow"
reingebastelt. Der isn bissl kürzer, und eventuell noch leichter zu
verstehen.

[Motzi]

Zitat:

Zitat von Christian Seehase

Als Messagestring solltest Du Dir am besten eine GUID von der IDE generieren lassen, damit die Message auch eindeutig wird, und das Registrieren nicht fehlschlägt.

Dasselbe empfehle ich für den Namen des Mutex..!

Wobei ich auch hier wiedermal erwähne, dass es zu empfehlen ist ein Semaphore-Objekt statt einem Mutex zu verwenden. Die Frage nach dem "warum" beantwortet die Forensuche hier und unter www.delphi-forum.de

[Hansa]

Aha, (teilweise) mein Quelltext schon hier. :lol: Der Vollständigkeit halber nur noch folgendes: diese Unit muß in der DPR unter uses aufgeführt werden und das wars ! Im Hauptprogramm muß dann nur das geändert werden:

Delphi-Quellcode:

begin
  Application.Initialize;
  if not BereitsAktiv then begin
    Application.CreateForm(TForm1, Form1);
...
    Application.Run;
  end
  else
    Application.Terminate;
end.

[r_kerber]

Ich habe mich erst mal für Rumpi's Variante entschieden.
@Hansa: Hier wird das Fenster der bereits existierenden Instanz nicht in den Vordergrund gebracht. Ein Mischen beider Varianten habe ich jetzt auf die Schnelle nicht hinbekommen. :wall:

[Hansa]

Zitat:

Zitat von r_kerber

@Hansa: Hier wird das Fenster der bereits existierenden Instanz nicht in den Vordergrund gebracht.

Hää ? Wieso das ???

[r_kerber]

weil

Delphi-Quellcode:

          BringWindowToTop(hWndMe);

allein manchmal micht ausreicht! Sie Quellcode von Rumpi.

[MGC]

Auch wenn dieses Thema schon ein wenig älter ist...

Zitat:

Zitat von MrKnogge (Beitrag 103948)

Delphi-Quellcode:

      // Get the current window's handle then change 
      // its title so we can look for the other instance 
      hWndMe := FindWindow(appClass,appTitle); 
      SetWindowText(hWndMe,'ZZZZZZZ'); 

      // Search for other instance of this window then bring 
      // it to the top of the Z-order stack.  We find it by 
      // matching the Application Class and 
      // Application Title. 
      hWndMe := FindWindow(appClass,appTitle); 
      if (hWndMe <> 0) then 
        begin 
          BringWindowToTop(hWndMe); 
          ShowWindow(hWndMe,SW_SHOWNORMAL);
          SetForeGroundWindow(hWndMe);
        end;

Aus welchem Grund machst Du es Dir an der oberen Stelle so schwer? Das Handle der gerade laufenden Instance ist Dir doch bekannt.

Delphi-Quellcode:

// Fenster-Caption speichern (da sich diese vielleicht mal ändert)
  AppTitle := PAnsiChar(Application.Title);
  // Danach das eigene Caption ändern, da ja bekannt ist, dass die App bereits
  // vorhanden ist
  SetWindowText(Application.Handle,'ZZZ');
  // Nun nach dem anderen Fenster suchen und Handle speichern
  hLA := FindWindow(nil,AppTitle);
  // Wenn das Fenster gefunden wurde, in den Fordergrund setzen
  if hLA <> 0 then ForceForeGroundWindow(hLA) // <- unschön aber schnell ;-)

ForceForeGround ist auch nicht kompliziert, es umgeht (soweit ich es beim Überfliegen verstanden habe) OS-Versionskonflikte und sorgt dafür, dass das Fenster auch auf älteren Win-Plattformen wirklich in den Vordergrund gesetzt wird.

Probleme kann es aber geben, wenn das Fenster versteckt (fMainForm.Hide) ist und über ein TrayIcon gesteuert werden soll.
In diesem Fall wird zwar Deine App in der Taskbar angezeigt, aber es wird kein Fenster eingeblendet.
Dieses Problem kann man aber umgehen, wenn man auf die Message (z.B. SW_SHOW) reagiert und entsprechend das Form wieder sichtbar macht.

Viele Grüße,