TidTCP records senden/empfangen

[XXcD]

Hallo,
ich kann komischerweise keine records vom idtcpserver zum idtcpclient senden.

Ich habe den Code aus folgendem Thread:
http://www.delphipraxis.net/internal...t.php?p=989054

Mein Code sieht so aus:

Server:

Delphi-Quellcode:

type
  TSendChannellist = record
   Channels: String;
  end;

  type
  TChannel = class(TObject)
  ID: String;
  Name: string;
  Port: Integer;
  MaxUser: Integer;
  Password: string;
  end;

var
ChannelList: TList;

...

procedure TLogin.ServerExecute(AThread: TidContext);
var
SendChannelsList: TSendChannellist;
Buffer: TIdBytes;
Channel: TChannel;
begin

with AThread as TidContext do
   begin
   read:=Connection.Socket.ReadLn;
   end;

//Channellist abrufen
if unpackpacketid(Read)='02' then
begin
Channel:=ChannelList.Items[0];
SendChannelsList.Channels:= Channel.Name;

Buffer := RawToBytes(SendChannelsList, sizeof (TSendChannellist));
TidContext(AThread).Connection.IOHandler.Write(Buffer);
end;
end;

Client:

Delphi-Quellcode:

type
  TSendChannellist = record
   Channels: String;
  end;
PSendChannellist = ^TSendChannellist;

...

procedure TForm3.Button6Click(Sender: TObject);
var
Buffer: TIdBytes;
SendChannellist: PSendChannellist;
begin
IdTCPClient1.Socket.WriteLn(Edit2.Text);
New(SendChannellist);

IdTCPClient1.IOHandler.ReadBytes(Buffer, SizeOf (TSendChannellist));
BytesToRaw (Buffer, SendChannellist^, SizeOf (TSendChannellist));

Memo9.Lines.Add(SendChannellist.Channels);

end;

Beim Server läuft alles einwandfrei, doch beim Client kommt nur ein leerer String an.
Was kann denn da schiefgelaufen sein?

[franktron]

Du sendest doch nur ein Byte wie soll das den gehen

[XXcD]

Achso ok das hilft mir schon mal weiter.
Ich habe den Code nämlich selbst noch nicht so ganz verstanden, da ich soetwas noch nie brauchte.

Wie kann ich denn ganze records senden?
Dort müssen z.b. Bilder, Stringlists und strings rein.

[Klaus01]

Wenn Du Bilder und StringListen in den Record
speichern willst mußt Du die Inhalte der Bilder udn StringListen
abspeichern, denn im Record steht dann nur die Adresse der ObjectInstanz.

Grüße
Klaus

[XXcD]

Ja ok könntest du mir denn zeigen wie das mit Stringlisten geht?
Einfach so ein Beispiel, bei dem eine Stringlist vom Server zum Client gesendet wird

[Klaus01]

Hallo,

ein Beispiel habe ich gerade nicht zur Hand.
Aber den Inhalt der TStringList bekommst Du
mit sl.text (wenn sl Deine StringList ist)
und den Text kannst Du wie gewohnt versenden.

Grüße
Klaus

[XXcD]

Es muss doch auch möglich seon ganze packete zu verschicken, wo strings usw. Drin sind. Das wäre nämlich wichtig ich z.b. Bilder mit texten dazu laden möchte.

[Klaus01]

Guten Abend,

dann solltest Du dir ein geignetes Protokoll überlegen.

Nehmen wir an

Beginn der Übertragung(2Byte),Länge des Textes(2Byte),Text,Größe der Bilddatei(4Byte).Bilddatei,Ende der Übertragung(2Byte);

Für jeden Sendevorgang mußt Du dir alles entsprechend zusammenbauen.
Der Empfänger kann es dann wieder richtig auspacken.

Grüße
Klaus

[XXcD]

Ok aber wie funktioniert das genau?
Gibt es da nicht irgendwelche Demos für TCP die so einen Fall beinhalten?

[Blup]

Dein Problem hat mit TCP nur sekundär zu tun.

Überführe deine Datenstruktur in eine transportablen Datenstrom, am besten in einen Stream.
Statte jeden verwendeten Datentyp mit einer Methode SavetoStream und LoadfromStream aus.
Zusammengesetzte Datentypen müssen intern für jedes Unterelement SavetoStream bzw. LoadFromStream aufrufen.
Alternativ könnte man mit Hilfsklassen arbeiten (Reader/Writer) die diese Aufgabe übernehmen.

Delphi-Quellcode:

TChannel = class(TObject) 
  ID: String; 
  Name: string; 
  Port: Integer; 
  MaxUser: Integer; 
  Password: string;
  procedure LoadFromStream(AStream: TStream);
  procedure SaveToStream(AStream: TStream);
end;

procedure TChannel.SaveToStream(AStream: TStream);
var
  iLen: Integer;
begin
  {String ID}
  iLen := Length(ID);
  AStream.Write(iLen, SizeOf(iLen));
  AStream.Write(ID[1], iLen);
  {String Name}
  iLen := Length(Name);
  AStream.Write(iLen, SizeOf(iLen));
  AStream.Write(Name[1], iLen);
  {Integer ID}
  AStream.Write(Port, SizeOf(Port));
{...}

end;

procedure TChannel.LoadFromStream(AStream: TStream);
var
  iLen: Integer;
begin
  {String ID}
  AStream.Read(iLen, SizeOf(iLen));
  SetLength(ID, iLen);
  AStream.Read(ID[1], iLen);
  {String Name}
  AStream.Read(iLen, SizeOf(iLen));
  SetLength(Name, iLen);
  AStream.Read(Name[1], iLen);
  {Integer ID}
  AStream.Write(Port, SizeOf(Port));
{...}

end;

Jetzt solltest du z.B. einen TMemoryStream erzeugen und deine Datenstruktur speichern und wieder lesen können.
Der TMemorystream verfügt über einen Buffer in dem die gespeicherten Daten als ein zusammenhängender Speicherblock abgelegt sind. Das Problem reduziert sich darauf diesen Block zu übertragen.
Dazu sollte erst die Anzahl der Byte (Stream.Size) und anschließend die eigentlichen Daten (Stream.Buffer^) gesendet werden.
Beim Empfangen entsprechend erst die Anzahl der Byte zuweisen (Stream.Size) und anschließend die Daten lesen.

[XXcD]

Ich habe mich jetzt gerade nochmal mit dem Problem beschäftigt und wollte noch gerne ein Bild zusätzlich in den Stream laden.
Nur leider bekomme ich das nicht so richtig hin.

Delphi-Quellcode:

  type
  TProfile = class(TObject)
  id: String;
  name: string;
  image: TMemorystream;
  procedure LoadFromStream(AStream: TStream);
  procedure SaveToStream(AStream: TStream);
  end;

...

procedure TProfile.SaveToStream(AStream: TStream);
var
  iLen: Integer;
begin
  {String ID}
  iLen := Length(ID);
  AStream.Write(iLen, SizeOf(iLen));
  AStream.Write(ID[1], iLen);
  {String Name}
  iLen := Length(Name);
  AStream.Write(iLen, SizeOf(iLen));
  AStream.Write(Name[1], iLen);

  {TBitmap Picture}
  AStream.Write(image, SizeOf(image));
end;

procedure TProfile.LoadFromStream(AStream: TStream);
var
  iLen: Integer;
begin
  {String ID}
  AStream.Read(iLen, SizeOf(iLen));
  SetLength(ID, iLen);
  AStream.Read(ID[1], iLen);
  {String Name}
  AStream.Read(iLen, SizeOf(iLen));
  SetLength(Name, iLen);
  AStream.Read(Name[1], iLen);

    {TBitmap Picture}
  AStream.Read(image, SizeOf(image));
end;

Benutzt habe ich zum speichern einen Tmemorystream:

Delphi-Quellcode:

Profile:= TProfile.Create;
Profile.id:='1';
Profile.name:='huhu';
Profile.image:= TMemoryStream.Create;
Profile.image.loadfromfile(ExtractFilePath(ParamStr(0))+'Images/bg_Eingangshalle.png');
Stream:= TMemoryStream.Create;
Profile.SaveToStream(Stream);

Und das auslesen habe ich so gestaltet:

Delphi-Quellcode:

Profile1:= TProfile.Create;
Profile1.LoadFromStream(stream);
WriteLn(Profile1.id);
WriteLn(Profile1.name);
Profile1.image:= TMemoryStream.Create;
Profile1.image.SaveToFile('C:\Test.png');

Das ganze ist erstmal zum testen, beim speichern kommt kein fehler.
Allerdings beim auslesen werden unendlich neue Zeilen in der Konsole erzeugt.
Wo liegt denn da der Fehler?

[Blup]

Da Image ein Objekt ist und Objektvariablen nur Referenzen sind (also Zeiger auf einen Speicherbereich wo die eigentlichen Objektdaten liegen) ist SizeOf(image) immer 4. Mit der abgespeicherten Adresse des Objektes kann man aber nichts anfangen.
Das Objekt selbst soll auch nicht geladen werden, sondern nur die enthaltenen Daten.

Wie bei allen Daten mit variabler Länge wird erst die Größe und dann die eigentlichen Daten gespeichert/gelesen.

Delphi-Quellcode:

iLen := Image.Size;
AStream.Write(iLen, SizeOf(iLen)); 
Image.Position := 0;
AStream.CopyFrom(Image, iLen) 


AStream.Read(iLen, SizeOf(iLen)); 
Image.Clear;
Image.CopyFrom(AStream, iLen);

[XXcD]

Ok leider bekomme ich beim auslesen immer den Fehler Zugriffsverletzung.

Delphi-Quellcode:

  type
  TProfile = class(TObject)
  id: String;
  name: Ansistring;
  image: TMemorystream;
  procedure LoadFromStream(AStream: TStream);
  procedure SaveToStream(AStream: TStream);
  end;

...

procedure TProfile.SaveToStream(AStream: TStream);
var
  iLen: Integer;
begin
  {String ID}
  iLen := Length(ID);
  AStream.Write(iLen, SizeOf(iLen));
  AStream.Write(PChar(ID)^, iLen);
  {String Name}
  iLen := Length(Name);
  AStream.Write(iLen, SizeOf(iLen));
  AStream.Write(PChar(Name)^, iLen);


  {memorystream image}
  iLen := Image.Size;
  AStream.Write(iLen, SizeOf(iLen));
  Image.Position := 0;
  AStream.CopyFrom(Image, iLen)
end;

procedure TProfile.LoadFromStream(AStream: TStream);
var
  iLen: Integer;
begin
  {String ID}
  AStream.Read(iLen, SizeOf(iLen));
  SetLength(ID, iLen);
  AStream.Read(PChar(ID)^, iLen);
  {String Name}
  AStream.Read(iLen, SizeOf(iLen));
  SetLength(Name, iLen);
  AStream.Read(PChar(Name)^, iLen);

  {memorystream image}
  AStream.Read(iLen, SizeOf(iLen));
  Image.Clear;
  Image.CopyFrom(AStream, iLen);
end;

Zum schreiben das sieht so aus:

Delphi-Quellcode:

        Profile:= TProfile.Create;
        Profile.id:='2';
        Profile.name:='huhu';
        Profile.image:= TMemorystream.Create;
        Profile.image.LoadFromFile(ExtractFilePath(ParamStr(0))+'Images/test.png');

        Stream:= TMemoryStream.Create;
        Profile.SaveToStream(Stream);

Und an anderer Stelle lese ich das so wieder aus:

Delphi-Quellcode:

        Profile1:= TProfile.Create;
        Stream.Position:=0;
        Profile1.LoadFromStream(stream);
        WriteLn(Profile1.id);
        WriteLn(Profile1.name);
        Profile1.image:= TMemorystream.Create;
        Profile1.image.SaveToFile('C:\test.png');

Oder kann ich vielleicht direkt den Typ image in den Stream laden, aber da weiß ich nicht welchen typ ich nehmen kann.

[XXcD]

Ahh habs gerade ebend rausgefunden musste nur MemoryStream.Create vor dem LoadFromStream ausführen.
Danke das hat mir echt weitergeholfen.