bmp in Panel zeichnen

[youuu]

Hallo,

kann man ein bmp in einen Panel zeichnen ohne Paintbox oder TImage?

[DeddyH]

Leite Dir eine Klasse von TPanel ab, mache dort die Canvas-Eigenschaft öffentlich und zeichne dann darauf.

[Fussball-Robby]

Oder ohne Ableiten mittels GetWindowDC, ein kleines Beispiel:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  X: TBitmap;
  H: HDC;
begin
  X := TBitmap.Create;
  try
    X.Width := 20;
    X.Height := 20;
    X.Canvas.Ellipse(0, 0, 20, 20);
    H := GetWindowDC(Panel1.Handle);
    BitBlt(H, 0, 0, 20, 20, X.Canvas.Handle, 0, 0, SRCCOPY);
  finally
    X.Free;
  end;
end;

Gruß

[youuu]

Hast du darüber zufällig ein Tutorial?
Habe soetwas noch nie gemacht.

[DeddyH]

Da vermisse ich aber ein ReleaseDC ;)

[edit]

Zitat:

Zitat von youuu

Hast du darüber zufällig ein Tutorial?
Habe soetwas noch nie gemacht.

Wen meinst Du jetzt? [/edit]

[Fussball-Robby]

Zitat:

Zitat von DeddyH

Da vermisse ich aber ein ReleaseDC ;)

Huch, mir war nicht bewusst, dass man das machen muss :| Habe selber nicht oft damit gearbeitet :wink:
Also, dahinter noch ein

Delphi-Quellcode:

ReleaseDC(Panel1.Handle, H);

Ich hoffe das stimmt jetzt so..

[turboPASCAL]

@Fussball-Robby ...und dach dem verschieben oder wenn ein fenster drüber war ist alles pfutsch. ;)

[stoxx]

Du musst natürlich im Ereignis Onpaint des Formulars oder Panels immer wieder alles neu reinmalen.
Das übernimmt ansonsten Delphi für Dich, da aber Delphi nix davon weiß, weil Du ja keine Paintbox genommen hast, dann musst Du Dich selbst um das neuzeichnen kümmern ..

[DeddyH]

Also in etwa so:

Delphi-Quellcode:

...
interface

uses ..., ExtCtrls;

type
  TPanel = class(ExtCtrls.TPanel)
  protected
    procedure Paint;override; //erspart dann das Öffentlichmachen von Canvas
  end;

  TForm1 = class(TForm)
    Panel1: TPanel;
    ...
  end;

...

implementation

procedure TPanel.Paint;
var bmp: TBitmap;
begin
  inherited;
  bmp := TBitmap.Create;
  try
    bmp.LoadFromFile('C:\Program Files\Common Files\CodeGear Shared\Images\BackGrnd\Calendar.bmp');
    Canvas.Draw(0,0,bmp);
  finally
    bmp.Free;
  end;
end;

...

Das ist natürlich nur ein Beispiel, man kann die Bitmap auch zum Programmstart einmalig laden und im Speicher halten etc.

[turboPASCAL]

Oder So:

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls;

type
  TPanel = class(ExtCtrls.TPanel)   // Wichtig, als erstes for TForm1
  private
    { Private-Deklarationen }
    FOnPaint: TNotifyEvent;
  protected
    { Protected-Deklarationen }
    procedure Paint; override;
  public
    { Public-Deklarationen }
    property Canvas;
  published
    { Published-Deklarationen }
    property OnPaint: TNotifyEvent read FOnPaint write FOnPaint;
  end;

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
    procedure OnPanel1Paint(Sender: TOBject);
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TPanel.Paint;
begin
  inherited;
  if assigned(fOnPaint) then fOnPaint(Self);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Panel1.OnPaint := OnPanel1Paint;
end;

procedure TForm1.OnPanel1Paint(Sender: TOBject);
var r: Trect;
begin
  r := Panel1.ClientRect;
  InflateRect(r, -2, -2);

  With Panel1 do
  begin
    Canvas.Brush.Color := clWindow;
    Canvas.RoundRect(r.Left, r.Top, r.Right, r.Bottom, 20, 20);
    Canvas.Brush.Color := Panel1.Color;
    Canvas.Draw(5, 5, Application.Icon);
  end;
end;

end.

- eine neues Project erstellen
- Ein Panel auf eine Form klatschen
- zwei mal auf die Form klicken und sich im FormCreate wiederfinden
- Copy & Paste mit diesem Quelltext den alten Quelltext ersetzen
- fertisch.



//Edit:

@Detlef, das gibt ne Beule ! ;)

Code:

procedure [color=#ff001f]TPanel.Paint;[/color] [color=#ff001f]  <--<<<[/color]
var bmp: TBitmap;
begin
  ...
    bmp.[color=#ff001f]LoadFromFile[/color]('C:\Program Files\Common Files\CodeGear Shared\Images\BackGrnd\Calendar.bmp'); [color=#ff001f]<--<<<[/color]
  ...
end;

[Dipl Phys Ernst Winter]

Zitat:

kann man ein bmp in einen Panel zeichnen ohne Paintbox oder TImage?

Nein, das kann man nicht!

Man muss das Panel mit einer Komponente überdecken, die eine Canvas bereitstellt. Mit deren Methoden Draw bzw. StretchDraw kann man die bmp anzeigen.

[Namenloser]

Zitat:

Zitat von Dipl Phys Ernst Winter

Nein, das kann man nicht!

Naja, wenn du dir mit GetDC das Canvas holst, schon... die Paintbox wäre aber auf jeden Fall vorzuziehen.

[DeddyH]

@Matti: wie ich oben bereits schrieb, ist das ja auch nur ein Beispiel, es ging ja nicht darum, wo die Bitmap jetzt herkommt ;)
@Ernst: und was ist mit den Codebeispielen weiter oben?

[_frank_]

warum unbedingt ein TPanel? leite einfach von TCustomControl ab, da hast ein Control mit Canvas...und sparst die Implementation des Canvas/OnPaint

Gruß Frank

[DeddyH]

Einen echten Vorteil kann ich darin aber nicht erkennen. Wenn man ein Panel nimmt, kann man das wie gewohnt zur Designtime einstellen und sehen (nur eben ohne die Grafik).

[lbccaleb]

Noch eine möglichkeit währe, das TJVPanel (aus den Jedis) zu verwenden! Dieses besitzt auch die möglichkeit ohne ableitung auf den Canvas zuzugreifen. So kannst du das Bild wie oben beschrieben auf das Panel zeichnen!