ALTER TABLE CHANGE - Spaltennamen ändern in Access

[Moony]

Hallo zusammen,

so, hier ist das nächste Problem:

Ich prüfe in meiner Anwendung ob ich eine vorhandene Datenbank habe und prüfe dann deren Feldstruktur. Wenn diese mit einer aöten übereinstimmt, dann will ich die Feldnamen ändern. Normalerweise macht man das ja mit folgendem Code:

Delphi-Quellcode:

ALTER TABLE Tabelle CHANGE FeldnameAlt FeldnameNeu Feldtyp

Aber irgendwie sagt Access nur, dass es einen Fehler in der SQL Syntax gibt.

Nun seid ihr gefragt: Wie kann ich meine Feldnamen ändern?

Gruß, Moony

[nahpets]

Hallo,

bin mir nicht sicher, das Change zur allgemeinen SQL-Syntax gehört.
Normalerweise kenn' ich das Umbenennen von Spalten nur in der Form:

Neue (temporäre) Spalte mit den alten Attributen.
Daten in diese Spalte kopieren.
Alte Spalte löschen.
Neu Spalte mit den neuen Attributen.
Inhalte aus der temporären Spalte in die neue Spalte.
Temporäre Spalte löschen.

[Moony]

Wird dann aber nicht die Spaltenreihenfolge geändert?

[nahpets]

Hallo,

die wird mit Sicherheit geändert.

Ansonsten müsstest Du eine temporäre Tabelle mit der alten Struktur erstellen, die Daten dort hinein kopieren, die alte Tabelle löschen, eine neue Tabelle in alter Struktur mit neuen Attributen erstellen, die Daten aus der temporären Tabelle kopieren und die temporäre Tabelle löschen.

Ist die Spaltenreihenfolge den für Dich wichtig?
Zumindest beim Zugriff per SQL sollte das doch eigentlich egal sein.

Musst Du Deine Änderungen "von Hand" oder per Delphi machen oder kannst Du das auch über Access machen? Wenn ja, so müsste das Umbenenne über die Oberfläche eigentlich funktionieren (wenn ich das recht in Erinnerung habe).

[Moony]

Ich muß die Änderungen während der Laufzeit per DelphiCode machen. Ich bin mir noch nicht ganz sicher ob die Reihenfolge der Felder relevant ist. Zumindest vergleiche ich bei der Überprüfung den FieldList.Commatext mit meinem vorhandenen. Wenn die identisch sind, dann muß ich die Umbenennung durchführen.

Ist es aber nicht einfacher statt einer temporären Tabelle direkt eine neue zu erstellen und die Daten sofort dorthin zu kopieren ohne mit einer temporären Tabelle zu arbeiten?

[nahpets]

Zitat:

Zitat von Moony

Ich muß die Änderungen während der Laufzeit per DelphiCode machen. Ich bin mir noch nicht ganz sicher ob die Reihenfolge der Felder relevant ist. Zumindest vergleiche ich bei der Überprüfung den FieldList.Commatext mit meinem vorhandenen. Wenn die identisch sind, dann muß ich die Umbenennung durchführen.

Ist es aber nicht einfacher statt einer temporären Tabelle direkt eine neue zu erstellen und die Daten sofort dorthin zu kopieren ohne mit einer temporären Tabelle zu arbeiten?

Wenn die neue Tabelle den gleichen Namen wie die Alte haben soll, muss Du diesen Umweg nehmen. Bekommt die neue Tabelle einen anderen Namen, dann kannst Du Dir die temporäre Tabelle selbstverständlich sparen.

[Moony]

Ich kann doch nachträglich den Tabellennamen ändern. Das ist nun wirklich SQL standard. Oder vorher die alte Tabelle umbenennen und die neue direkt richtig erstellen.

[Ydobon]

Jet kennt etwas zum Umbenennen anscheinend nicht, zumindest schweigt sich die Hilfe von Access dazu aus.
Darum wurde ja ADOX erfunden:

Delphi-Quellcode:

var cat: _Catalog;
begin
  cat:=CoCatalog.Create;
  cat.Set_ActiveConnection(ADOConnection1.ConnectionObject);
  cat.Tables.Item['AlterName'].Name:='NeuerName';

[Moony]

Ok, dann versuche ich das so:

1. alte Tabelle umbenennen
2. neue Tabelle erstellen
3. Daten kopieren
4. alte Tabelle löschen

[Moony]

So, habe jetzt alles fertig, aber bekomme beim Verlassen der Routine eine Access Violation.

So sieht alles bei mir aus:

Delphi-Quellcode:

const
  PHOTOTABLE = 'Tabellenname';

...
if (UpperCase(PhotoTB.FieldList.CommaText) = UpperCase(ImageSet.DefLst.CommaText)) and
   (PhotoTB.FieldCount = ImageSet.DefLst.Count) then
begin
  // alte Tabelle umbenennen
  PhotoTB.Close;
  cat := CoCatalog.Create;
  try
    cat.Set_ActiveConnection(PhotoDB.ConnectionObject);
    cat.Tables.Item[PHOTOTABLE].Name := '_images';
    cat._Release;
  except
    Result := false;
    Exit;
  end;

  // Neue Tabelle erstellen
  SQL := 'CREATE TABLE ' + PHOTOTABLE + ' (';
  if Length(_myLen) >= ImageSet.DefLst.Count then
  begin
    for i := 0 to ImageSet.DefLst.Count - 1 do
      if ImageSet.DefLst.Strings[i] <> 'Filename' then
        SQL := SQL + ' Field' + ImageSet.DefLst.Strings[i] + ' CHAR(' + IntToStr(_myLen[i]) + '),';

      SQL := SQL + 'FileName VARCHAR(' + IntToStr(_myLen[ImageSet.DefLst.Count-1]) + '))';
      PhotoCmd.CommandText := SQL;
      PhotoCmd.Execute;
  end
  else begin
    Result := false;
    Exit;
  end;

  // Daten kopieren
  myDS := TADODataSet.Create(nil);
  try
    myDS.Connection := PhotoDB;
    myDS.CommandText := 'SELECT * FROM _' + PHOTOTABLE;
    myDS.Open;
    myDS.First;

    PhotoTB.CommandText := 'SELECT * FROM ' + PHOTOTABLE;
    PhotoTB.Open;
    PhotoTB.First;
    while not myDS.Eof do
    begin
      PhotoTB.Append;
      for i := 0 to myDS.FieldCount - 1 do
      begin
        if UpperCase(myDS.Fields.Fields[i].FieldName) <> UpperCase('FileName') then
     PhotoTB.FieldByName('Field' + myDS.Fields.Fields[i].FieldName).Text := myDS.Fields.Fields[i].AsString
        else PhotoTB.FieldByName(myDS.Fields.Fields[i].FieldName).Text := myDS.Fields.Fields[i].AsString;
      end;
      try
        PhotoTB.Post;
        myDS.Next;
      except
        PhotoTB.Cancel;
        Result := false;
        Exit;
      end;
    end;

    myDS.Close;
    myDS.Free;
    PhotoTB.Close;
    PhotoDB.Close;
  except
    myDS.Free;
    Result := false;
    Exit;
  end;

  // alte Tabelle löschen
  PhotoCmd.CommandText := 'DROP TABLE _' + PHOTOTABLE;
  PhotoCmd.Execute();
  Application.ProcessMessages;
end;

if not PhotoDB.Connected then
  PhotoDB.Open;
if not PhotoTB.Active then
  PhotoTB.Open;

PhotoTB.Active := True;
Exit; <- an dieser Stelle bekomme ich die Access Violation
...

Die einzelnen Operationen verlaufen alle richtig. Tabelle umbenennen, neue Tabelle erstellen, Daten kopieren und die alte löschen. Aber ich kann hier nicht raus.

Hoff ihr wisst weiter....

[nahpets]

Hallo,

funktionieren die anderen Exit alle? Hast Du mal entsprechende Fehler eingebaut, um das zu prüfen?
Das Einzige, was mir auffällt ist:

Delphi-Quellcode:

if not PhotoTB.Active then 
  PhotoTB.Open; 

PhotoTB.Active := True; // <-- überflüssig, da nach PhotoDB.Open Active = True.

aber dass das der Fehler sein sollte, halte ich für unwahrscheinlich.
Result könnte zu dem Zeitpunkt noch undefiniert sein, sofern es nicht in dem von Dir durch ... dargestellten Ausschnitt mit einem Wert versehen wurde.

[Moony]

An dieser Zeile liegts definitiv nicht. Der Result wird zu Anfang der Routine auf true gesetzt und nur im Fehlerfall auf False. Das Exit hat ja vor meinem Umbau funktioniert, auch in dieser Konstellation.

[Jürgen Thomas]

Zitat:

Zitat von Moony

Ich kann doch nachträglich den Tabellennamen ändern. Das ist nun wirklich SQL standard.

Damit hier nichts unwidersprochen stehen bleibt: CHANGE ist nach wie vor nicht SQL-Standard!

Zitat:

SQL (Wikipedia)
Die Alter-Definition ist ADD Attribut-Definition. In SQL-92 gibt es noch ALTER Attribut Default-Wert oder DROP Attribut. Da SQL-92 sehr restriktiv bezüglich der ALTER-Anweisung ist, ist dies eine der Anweisungen, die von den Herstellern universell erweitert wurde, so dass beliebige Änderungen möglich sind wie durch eine Folge von DROP und ADD-Anweisungen.

Über Whitemarsh: SQL habe ich Dokumente gefunden, u.a. (ISO-ANSI Working Draft) Foundation (SQL/Foundation) WG3:HBA-003 / H2-2003-305 (August, 2003) in 5WD-02-Foundation-2003-09.pdf. Im Abschnitt 11.10 <alter table statement> (Seite 571) steht nichts von CHANGE.

Es gilt deshalb das, was hier ansonsten vorgeschlagen wurde: Wenn ein spezieller SQL-Dialekt so etwas anbietet, kann es natürlich benutzt werden. Wenn nicht, müssen die genannten Alternativen (Temp-Column, Temp-Table) verwendet werden. Es ist deshalb immer nützlich, die bestehenden Hilfen zu studieren.

Gruß Jürgen

[Moony]

Ich hab das ja jetzt anders gelöst. ohne eine Temp-Tabelle. Aber mein Problem ist ,dass ich abschließend eine Access Violation erhalte.

[Ydobon]

Ups, ich Idiot, da habe ich etwas zu früh aufgehört. Ein Tabellenobjekt enthält aber wiederum eine Column Collection, mit deren Mitgliedern geht das Umbenennen genauso. Sollte eigentlich da oben stehen.

Die Fehlermeldung dürfte an cat._Release liegen. Das scheint die Laufzeitumgebung nicht so richtig mitzubekommen und versucht am Ende der Prozedur den Katalog noch einmal zu schließen. Also entweder das Release weglassen oder mit Pointer(cat):=Nil Delphi die Lust am Schließen vermiesen.

[Moony]

upi, das wars. Jetzt funktioniert alles wunderbar. :thumb:

Danke allen für die Unterstützung!