Wieder ein Variablen Problem - komme nicht weiter.

[AlexII]

Hallo, muss erst mal sagen, dass bis Gestern nie Probleme oder Fehler mit Variablen hatte, aber seit Gestern schon das zweite und zwar:

Habe bis jetzt diesen Code gehabt:

Delphi-Quellcode:

function RundeAufStelle(zahl: double; stellen: integer): double;
var multi: double;
begin
  multi:=IntPower(10, stellen);
  zahl:=round(zahl*multi);
  result:=zahl/multi;
end;

procedure TForm1.Note;
var note: Real;
begin
if (FiCountCorrect=0) and (jkeins=1) and (jkzwei=1) then
begin
note:=7;
end else if (FiCountCorrect=0) and (jkeins=1) then
         begin
         note:=65/10;
         end else if (FiCountCorrect=0) and (jkzwei=1) then
                  begin
                  note:=65/10;
                  end else if (FiCountCorrect=0) then
                           begin
                           note:=6;
                           end else if (jkeins=1) then
                                    begin
                                    note:=StrToFloat(Label3.Caption);
                                    note:=note+1/2;
                                    end else if (jkzwei=1) then
                                             begin
                                             note:=StrToFloat(Label3.Caption);
                                             note:=note+1/2;
                                             end else
                                                 begin
                                                 note:=StrToFloat(Label3.Caption);
                                                 note:=note-5/15;
                                                 end;
Label3.Caption:=FloatToStr(note);
Label7.Caption:=FloatToStr(RundeAufStelle(StrToFloat(Label3.Caption), 1));
end;

und hab diesen etwas auf diese Version geändert, aber der spinnt jetzt auf ein mal und ich bekomme eine Warnung "[Warnung] MAIN.pas(134): Variable 'cache' ist möglicherweise nicht initialisiert worden" Weiß nicht wo der Fehler liegt.

Delphi-Quellcode:

function RundeAufStelle(zahl: double; stellen: integer): double;
var multi: double;
begin
  multi:=IntPower(10, stellen);
  zahl:=round(zahl*multi);
  result:=zahl/multi;
end;

procedure TForm1.Note;
var note, cache: Real;
begin
if (FiCountCorrect=0) and (jkeins=1) and (jkzwei=1) then
begin
note:=7;
end else if (FiCountCorrect=0) and (jkeins=1) then
         begin
         note:=65/10;
         end else if (FiCountCorrect=0) and (jkzwei=1) then
                  begin
                  note:=65/10;
                  end else if (FiCountCorrect=0) then
                           begin
                           note:=6;
                           end else if (jkeins=1) then
                                    begin
                                    note:=cache;
                                    note:=note+1/2;
                                    end else if (jkzwei=1) then
                                             begin
                                             note:=cache;
                                             note:=note+1/2;
                                             end else
                                                 begin
                                                 note:=cache;
                                                 note:=note-5/15;
                                                 end;
cache:=note;
Label7.Caption:=FloatToStr(RundeAufStelle(cache, 1));
end;

[Luckie]

Sagt doch die Fehlermeldung, sie kann einen nicht definierten Wert annehmen.

Du gibst sie am Ende aus

Delphi-Quellcode:

Label7.Caption:=FloatToStr(RundeAufStelle(cache, 1));

Aber welchen Wert hat sie, wenn schon die erste if-Bedingung nicht zutrifft?

Und du solltest dringend dein Einrückungsstil überdenken und zumindest bei Postings hier im Forum dich ungefähr an den Borlandstil halten.

[AlexII]

Aber wenn ich die Variable cache durch Labe3.Caption ersetzte funktionier alles bestens. Ich verstehe die Logik nicht, hab ja nix verändert, nur label durch Variable ersetzt.

[Luckie]

Die Caption deines Labels hat einen definierten Anfangswert.

[AlexII]

Zitat:

Zitat von Luckie

Und du solltest dringend dein Einrückungsstil überdenken und zumindest bei Postings hier im Forum dich ungefähr an den Borlandstil halten.

Was für Stil? Hab das in der Fachabi so gelernt, alle Beschwerden bitte an das stattliche Schulwesen richten. :lol: Das hat mir der Staat so beigebracht. :gruebel:

[AlexII]

Luckie kannst du mir vielleicht wenigstens nen Tipp geben wie ich den Code richtig schreiben soll. :gruebel:

[Luckie]

Und wie kannst du da erkennen, welches end zu welchem begin gehört?

Was ist besser lesbar? Deins:

Delphi-Quellcode:

procedure TForm1.Note;
var note, cache: Real;
begin
if (FiCountCorrect=0) and (jkeins=1) and (jkzwei=1) then
begin
note:=7;
end else if (FiCountCorrect=0) and (jkeins=1) then
         begin
         note:=65/10;
         end else if (FiCountCorrect=0) and (jkzwei=1) then
                  begin
                  note:=65/10;
                  end else if (FiCountCorrect=0) then
                           begin
                           note:=6;
                           end else if (jkeins=1) then
                                    begin
                                    note:=cache;
                                    note:=note+1/2;
                                    end else if (jkzwei=1) then
                                             begin
                                             note:=cache;
                                             note:=note+1/2;
                                             end else
                                                 begin
                                                 note:=cache;
                                                 note:=note-5/15;
                                                 end;
cache:=note;
Label7.Caption:=FloatToStr(RundeAufStelle(cache, 1));
end;

Oder meins:

Delphi-Quellcode:

procedure TForm1.Note;
var
  note, cache       : Real;
begin
  if (FiCountCorrect = 0) and (jkeins = 1) and (jkzwei = 1) then
  begin
    note := 7;
  end
  else if (FiCountCorrect = 0) and (jkeins = 1) then
  begin
    note := 65 / 10;
  end
  else if (FiCountCorrect = 0) and (jkzwei = 1) then
  begin
    note := 65 / 10;
  end
  else if (FiCountCorrect = 0) then
  begin
    note := 6;
  end
  else if (jkeins = 1) then
  begin
    note := cache;
    note := note + 1 / 2;
  end
  else if (jkzwei = 1) then
  begin
    note := cache;
    note := note + 1 / 2;
  end
  else
  begin
    note := cache;
    note := note - 5 / 15;
  end;
  cache := note;
  Label7.Caption := FloatToStr(RundeAufStelle(cache, 1));
end;

Und dann sieht man auf den ersten Blick den Grund der Warnung.

[DeddyH]

Ich würde "cache" als Übergabeparameter definieren, dann kann m.E. nicht viel schiefgehen.

[AlexII]

Ich hab mich schon an meine bzw. staatliche (ist wirklich so, zu mindest in meiner Schule) Schreibweise gewöhnt, aber danke für die Muster. :thumb:

Ich komme mir schon dumm vor, aber sehe nix. Also die vierte Bedingung wird am Anfang immer erfüllt - note:=6; danach wird nach unten gesprungen und

Delphi-Quellcode:

cache:=note;
Label7.Caption:=FloatToStr(RundeAufStelle(cache, 1));

ausgeführt, somit ist die Variable cache gefüllt. Als nächste wird die letzte Anweisung immer ausgeführt, dabei sind doch alle zwei Variablen schon gefühlt. :wall:

[Luckie]

Aber das weiß ja der Compiler nicht, denn woher soll er wissen, dass FiCountCorrect immer null ist. Da stellt sich mir die Frage, warum nimmst du es als Bedingung auf, wenn es doch sowieso immer null?

Und was das else angeht:

Delphi-Quellcode:

else
  begin
    note := cache;
    note := note - 5 / 15;
  end;

cache ist undefiniert und es wird auch nicht definierter, wenn du es hin und her schiebst. Denn dann machst du:

Delphi-Quellcode:

cache := note;

[AlexII]

Zitat:

Zitat von DeddyH

Ich würde "cache" als Übergabeparameter definieren, dann kann m.E. nicht viel schiefgehen.

Kannst du mir das vielleicht bisschen näher erklären?

[AlexII]

FiCountCorrect ist eine globale Variable und ist beim öffnen des Programms gleich Null. Somit wird die vierte Bedienung erfüllt, note auf 6 gesetzt und in der vorletzten Zeile wird cache auf 6 gesetzt. Wenn die Procedur das nächste mal ausgeführt wird ist FiCountCorrect=1 und die allerletzte Anweisung ist dran, und sie muss eigentlich funken, da beide Variablen schon gefüllt sind.

Oder spinne ich schon? :wall:

[Luckie]

Zitat:

Zitat von AlexII

FiCountCorrect ist eine globale Variable und ist beim öffnen des Programms gleich Null.

Ja, das mag ja alles so sein, aber woher soll der Compiler wissen, ob sich die globale Variable zwischen durch nicht ändert? Dann trifft die Bedingung nämlich nicht mehr zu und dann ist die Variable undefiniert. Und auf diese Tatsache weißt dich der Compiler mit der Warnung hin.

[DeddyH]

Delphi-Quellcode:

procedure TForm1.Note(cache: real); //so muss etwas übergeben wreden, cache ist also initialisiert
var
  note: Real;

[Luckie]

Warum ist cache dann initialisiert? Davon mal abgesehen, würde das Alex wohl komplett aus der bahn werfen, wenn er seine ganzen Code jetzt noch umbauen sollte.

[AlexII]

Zitat:

Zitat von Luckie

Ja, das mag ja alles so sein, aber woher soll der Compiler wissen, ob sich die globale Variable zwischen durch nicht ändert? Dann trifft die Bedingung nämlich nicht mehr zu und dann ist die Variable undefiniert. Und auf diese Tatsache weißt dich der Compiler mit der Warnung hin.

Die Variable FiCountCorrect wird immer vor der NoteProcedur geändert, somit weißt jeder wie sie lautet, der Compiler sowieso nehme ich an.

[AlexII]

Zitat:

Zitat von Luckie

Davon mal abgesehen, würde das Alex wohl komplett aus der bahn werfen, wenn er seine ganzen Code jetzt noch umbauen sollte.

Ich bin schon längst aus der Bahn, verstehe die Welt nicht mehr. Ist das mit dem Label3.Caption wenigsten richtig? Dann lasse ich das so und basta.

[jfheins]

Zitat:

Zitat von AlexII

FiCountCorrect ist eine globale Variable und ist beim öffnen des Programms gleich Null. Somit wird die vierte Bedienung erfüllt, note auf 6 gesetzt und in der vorletzten Zeile wird cache auf 6 gesetzt. Wenn die Procedur das nächste mal ausgeführt wird ist FiCountCorrect=1 und die allerletzte Anweisung ist dran, und sie muss eigentlich funken, da beide Variablen schon gefüllt sind.

Oder spinne ich schon? :wall:

Hä? Wenn die Procedure zum zweiten mal ausgeführt wird, sind die beiden lokalen Variablen doch nicht initialisiert, also funkt da nichts !?
Woher sind die denn bitte gefüllt? Vom vorherigen Aufruf?

(siehe auch #10 von Luckie ...)

[nahpets]

Hallo,

Zitat:

Zitat von AlexII

FiCountCorrect ist eine globale Variable und ist beim öffnen des Programms gleich Null. Somit wird die vierte Bedienung erfüllt, note auf 6 gesetzt und in der vorletzten Zeile wird cache auf 6 gesetzt. Wenn die Procedur das nächste mal ausgeführt wird ist FiCountCorrect=1 und die allerletzte Anweisung ist dran, und sie muss eigentlich funken, da beide Variablen schon gefüllt sind.

Oder spinne ich schon? :wall:

der Compiler weiss nicht, dass FiCountCorrect = 0, was ist denn, wenn FiCountCorrect = 42 (warum auch immer).
Der Compiler weist ja auch "nur" darauf hin, dass cache eventuell nicht initialisiert ist, er weist darauf hin, dass es Situationen geben kann, in denen cache nicht initialisiert ist. Bei den von Dir verwendeten (vermuteten) Werten ist cache halt initialisiert (Zufall?).

Bau doch am Anfang einfach direkt hinter dem ersten begin

Delphi-Quellcode:

cache := StrToFloat(Label3.Caption);

ein.

Zitat:

Zitat von AlexII

Die Variable FiCountCorrect wird immer vor der NoteProcedur geändert, somit weißt jeder wie sie lautet, der Compiler sowieso nehme ich an.

Irrtum, der Compiler muss davon ausgehen, dass die Funktion auch noch an jeder beliebigen anderen Stelle im Programm eingesetzt werden kann. Er betrachtet die Funktion absolut losgelöst von dem sie umgebenden Code.

Stephan

[AlexII]

Zitat:

Zitat von jfheins

Woher sind die denn bitte gefüllt? Vom vorherigen Aufruf?

Etwa nicht? :coder2:

[jfheins]

Zitat:

Zitat von AlexII

Zitat:

Zitat von jfheins

Woher sind die denn bitte gefüllt? Vom vorherigen Aufruf?

Etwa nicht? :coder2:

Bei lokalen Variablen: Nein, natürlich nicht ;)

[AlexII]

Zitat:

Zitat von nahpets

Der Compiler weiss nicht, dass FiCountCorrect = 0, was ist denn, wenn FiCountCorrect = 42 (warum auch immer).

Wieso nicht? Beim FormCreate wird die auf Null gesetzt und danach in ner Schleife immer verändert. Also sie ist immer im Griff.

Zitat:

Zitat von nahpets

Bau doch am Anfang einfach direkt hinter dem ersten begin

Delphi-Quellcode:

cache := StrToFloat(Label3.Caption);

Ich wollte die Label3 gerade los werden, aber anscheinend lasse ich den Code so wie am Anfang, mit dem Label halt.

[nahpets]

Hallo,

Zitat:

Zitat von Alex

Wieso nicht? Beim FormCreate wird die auf Null gesetzt und danach in ner Schleife immer verändert. Also sie ist immer im Griff.

Der Compiler guckt nicht den gesamten Quelltext und alle eingebundenen Units... durch, ob für eine bestimmte Situation eventuell unter Umständen vielleicht zu einem bestimmten Zeitpunkt eine bestimmte Bedingung irgendwo Aufgrund des Setzens von irgendwelchen Variabeln im Quelltext (ggfls. auch das Auslesen von Dateien, Datenbanken...) erfüllt sein könnte.
Er betrachtet die Prozudur losgelöst vom "Rest der Welt". Für ihn ist innerhalb der Prozedur nicht erkennbar, das cache immer und zu jedem Zeitpunkt einen Wert hat und er verlässt sich nicht darauf, dass eine Prozedur immer nur so aufgerufen wird, dass jede Variabel immer einen Wert hat.
Wenn er immer und überall überprüfen müsste, dass jede Variabel zu jeder Zeit, zu jeder Bedingung immer über gültige Werte verfügt, so müsste er zur Compilezeit das Programm mit sämtlichen möglichen Kombinationen von Werten... durchrechnen. Der Compiler, der das kann, der weiß auch, das die Antwort auf alle Fragen 42 ist :wink:

Zitat:

Zitat von Alex

Ich wollte die Label3 gerade los werden, aber anscheinend lasse ich den Code so wie am Anfang, mit dem Label halt.

Einmal musst Du den Wert von Label3.Caption in die Prozedur bekommen, entweder in der Prozedur per Zuweisung oder eben als Parameter, wie von DeddyH schon beschrieben.

Stephan

[DeddyH]

Aber als Übergabeparameter ist sie laut Luckie ja auch nicht initialisiert :zwinker:. Ich frag mich nur, wozu es die Dinger dann überhaupt gibt.

[nahpets]

Zitat:

Zitat von DeddyH

Aber als Übergabeparameter ist sie laut Luckie ja auch nicht initialisiert :zwinker:. Ich frag mich nur, wozu es die Dinger dann überhaupt gibt.

Was? die Variabeln, schreiben wir überall 42 rein 8)
Stephan

[AlexII]

Ok danke dir. Muss mir mal heute alles über Proceduren durchlesen. :roll:

[Luckie]

Delphi-Quellcode:

procedure foo(c: Real);
begin
  // tu was
end;

// ...;

procedure bar;
var
  cache: Real;
begin
  foo(cache);
end;

Wo ist sie jetzt initialisiert?

[DeddyH]

Davon war ja nicht die Rede. Das Spiel kannst Du natürlich endlos treiben.

[Eos-PVU]

Hi!

Zuerst mal haben wir hier wohl das Mißverständnis, daß eine lokale Variable beim nächsten Prozeduraufruf noch ihren alten Wert habe - das mag bei anderen Programmiersprachen so sein, bei Delphi ist das nicht der Fall.

Aufgrund des unter Windows ereignisgesteuerten Programmablaufs kann man ja auch nicht vorhersagen, in welcher Reihenfolge was aufgerufen wird - Tastatur- Maus- und Fensterereignisse passieren nun mal unvorhersehbar und rufen (sofern vom Programmierer da etwas geschrieben wurde) ihre Ereignisverarbeitungen auf. Wenn dann lokale Variablen als Zwischenspeicher verwendet werden könnten, kämen die merkwürdigsten Ergebnisse heraus. Bei Verwendung globaler Variablen kann das auch unter Delphi passieren.

Leider hat der Fragesteller nicht die Zeile genannt, in der der Fehler gemeldet wird - die letzte Zeile dürfte es nicht sein.

Hier mal Luckies Umformung des Codes mit meinen Anmerkungen, wo der Compiler warnen sollte:

Delphi-Quellcode:

procedure TForm1.Note;
var
  note, cache       : Real;
begin
  if (FiCountCorrect = 0) and (jkeins = 1) and (jkzwei = 1) then
  begin
    note := 7;
  end
  else if (FiCountCorrect = 0) and (jkeins = 1) then
  begin
    note := 65 / 10;
  end
  else if (FiCountCorrect = 0) and (jkzwei = 1) then
  begin
    note := 65 / 10;
  end
  else if (FiCountCorrect = 0) then
  begin
    note := 6;
  end
  else if (jkeins = 1) then
  begin
    note := cache;   //==> cache möglicherweise nicht initialisiert
    note := note + 1 / 2;
  end
  else if (jkzwei = 1) then
  begin
    note := cache;   //==> cache möglicherweise nicht initialisiert
    note := note + 1 / 2;
  end
  else
  begin
    note := cache;   //==> cache möglicherweise nicht initialisiert
    note := note - 5 / 15;
  end;
  cache := note;
  Label7.Caption := FloatToStr(RundeAufStelle(cache, 1));
end;

Entweder cache als globale Variable im Formular haben oder als VAR-Parameter übergeben - dann natürlich vor dem ersten Aufruf der Prozedur das Initialisieren nicht vergessen.
Dabei könnte man dann auch gleich die übrigen globalen Werte per Parameter übergeben:

Delphi-Quellcode:

procedure TForm1.Note (const FiCountCorrect, jkeins, jkzwei: integer; var cache: real);
var
  note: Real;
begin
  if (FiCountCorrect = 0) and (jkeins = 1) and (jkzwei = 1) then
  begin
    note := 7;
  end
  else if (FiCountCorrect = 0) and (jkeins = 1) then
  begin
    note := 65 / 10;
  end
  else if (FiCountCorrect = 0) and (jkzwei = 1) then
  begin
    note := 65 / 10;
  end
  else if (FiCountCorrect = 0) then
  begin
    note := 6;
  end
  else if (jkeins = 1) then
  begin
    note := cache;
    note := note + 1 / 2;
  end
  else if (jkzwei = 1) then
  begin
    note := cache;
    note := note + 1 / 2;
  end
  else
  begin
    note := cache;
    note := note - 5 / 15;
  end;
  cache := note;
  Label7.Caption := FloatToStr(RundeAufStelle(cache, 1));
end;

Gruß

Eos-PVU

[AlexII]

Delphi-Quellcode:

procedure TForm1.Note (const FiCountCorrect, jkeins, jkzwei: integer; var cache: real);

Aber FiCountCorrect, jkeins, jkzwei sind doch nicht constant oder wie meinst du das?

[Eos-PVU]

Hi!

Zitat:

Zitat von AlexII

Aber FiCountCorrect, jkeins, jkzwei sind doch nicht constant oder wie meinst du das?

Es geht dabei um die Art, wie Werte an eine Prozedur übergeben werden. Die Werte werden nämlich auf den Stack gepackt:

Bei

Delphi-Quellcode:

procedure foo (bar: tbar);

wird die komplette Variable "bar" auf den Stack gepackt. Änderungen an "bar" sind innerhalb der Prozedur möglich, wirken aber nur auf die lokale Kopie. Beim Aufruf von "foo" können auch Konstanten (const-Deklarierte Werte) und Literale (Werte im Quelltext wie 1 oder 'foobar') übergeben werden.
Braucht bei komplexen Typen, z.B. Records, viel Stackspeicher.

Bei

Delphi-Quellcode:

procedure foo (var bar: tbar);

wird eine Referenz (Pointer) auf die Variable übergeben. Änderungen von "bar" innerhalb der Prozedur verändern die beim Aufruf angegebene Variable. Die Übergabe von Konstanten und Literalen ist natürlich nicht möglich.
Braucht nur einen Pointer auf dem Stack.

Bei

Delphi-Quellcode:

procedure foo (const bar: tbar);

wird ebenfalls eine Referenz (Pointer) auf die Variable übergeben. Änderungen von "bar" innerhalb der Prozedur werden vom Compiler verhindert. Die Übergabe von Konstanten und Literalen ist möglich.
Braucht nur einen Pointer auf dem Stack und spart deshalb bei komplexen Typen gegenüber der ersten Variante viel Speicherplatz.
Bei Integer besteht kein Unterschied.

Werte, die in einer Prozedur/Funktion nicht geändert werden (das ist bei Deinen Werten FiCountCorrect, jkeins, jkzwei der Fall) übergebe ich immer als const - eine versehentliche Zuweisung läßt sich dann gar nicht compilieren. das "const" könnte hier auch weggelassen werden.

Gruß

Eos-PVU