Problem mit Buttons OnMouseEnter. Alle Buttons gläntzern

[Praxist]

Hallo

by speedbuttons und Bitbtn Buttons leuchten alle Buttons zusamen, wenn ich den Mousezeiger
auf ein Button oder auf ein Control in Form bewege
Onmouse Enter bekommt das Button ein neues Icon und auch beim OnMouseleave :

Delphi-Quellcode:

procedure TForm1.ButtonsCMMouseEnter(var Message: TMessage);
begin
if WindowFromPoint(ptWork) = BitBtn2.Handle then
ImageList1.GetBitmap(2, BitBtn2.Glyph); 
//...
procedure TForm1.ButtonsCMMouseleave(var Message: TMessage);
begin
if WindowFromPoint(ptWork) <> BitBtn2.Handle then
ImageList1.GetBitmap(3, BitBtn2.Glyph);

gibt es eine Lösung für das Problem
Ich weiß nicht, warum alle Buttons glitzern, wenn der Mausezeiger auf ein Control in Form bewegt :(

[TonyR]

Ich versteh nicht ganz, möchtest du bei allen BitButtons diesen Effekt haben, oder nur bei einem?

Bei letzterem würde ich folgene Anweisung nicht verstehen

Delphi-Quellcode:

if WindowFromPoint(ptWork) = BitBtn2.Handle then

Und bei Ersterem nicht, warum du nicht ganz normal über die OnEnter Prozedur des Bitbtn zugreifst!?

[Praxist]

Zitat:

Zitat von TonyR

Ich versteh nicht ganz, möchtest du bei allen BitButtons diesen Effekt haben, oder nur bei einem?

Bei letzterem würde ich folgene Anweisung nicht verstehen

Delphi-Quellcode:

if WindowFromPoint(ptWork) = BitBtn2.Handle then

Und bei Ersterem nicht, warum du nicht ganz normal über die OnEnter Prozedur des Bitbtn zugreifst!?

ich möchte diesen Effekt bei mehreren BitButtons haben
>> warum du nicht ganz normal über die OnEnter Prozedur des Bitbtn zugreifst!?
weil D7 den Event OnMouseLeave nicht hat sondern nur OnMouseMouve

Das Problem kommt von dem Event OnMouseEnter, was ich programmiert habe, und
möchte ich ändern

>> Bei letzterem würde ich folgene Anweisung nicht verstehen

Delphi-Quellcode:

procedure TForm1.ButtonsCMMouseEnter(var Message: TMessage); 
var
  ptWork : TPoint;
begin
  GetCursorPos(ptWork);
  if WindowFromPoint(ptWork) = BitBtn2.Handle then // wenn der cursor drauf kommt

[TonyR]

Zitat:

Zitat von Praxist

...
weil D7 den Event OnMouseLeave nicht hat sondern nur OnMouseMouve
...

sorry, daran hatte ich nicht gedacht.


geht das bei MouseEnter vllt. auch so:

Delphi-Quellcode:

procedure TForm1.BitBtn1MouseEnter(Sender: TObject);
begin
TBitbtn(sender).Glyph:= {irgendwas} ;
end;

[Praxist]

OnMouseEnter und OnMouseNove beide funktionieren
Das Problem was macht man OnMouseLeave ?
Das BitButton soll ein anderes Bild bekommen wenn der Cursor das Button verlässt

[TonyR]

Oder du lädst dir einfach die LMD Tools herunter: http://www.lmd.de/download/#LMD%20Freeware

Da ist der TLMDButton unter der Rubrik LMDStd dabei, der besitzt OnMouseEnter + OnMouseExit, da umgehst du die ganze Sache

Edit: Außerdem kann man in diesen Button natürlich auch ein Glyph laden ;-)

[Praxist]

BitButton hat auch besitzt OnMouseEnter + OnMouseExit
Das geht um OnMouseLeave

[DeddyH]

Unter Delphi 7 hat ein BitBtn kein Ereignis OnMouseEnter oder OnMouseExit.

[Praxist]

Versehen, das war OnEnte und OnExit aber kein OnMouseEnter
Kann man sie nicht programmieren ?

[DeddyH]

Kann man. Kleines Beispiel (komplette Unit):

Delphi-Quellcode:

unit bla;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Buttons;

type

  TBitBtn = class(Buttons.TBitBtn)
  private
    procedure CMMOUSEENTER(var Msg: TMessage); message CM_MOUSEENTER;
    procedure CMMOUSELEAVE(var Msg: TMessage); message CM_MOUSELEAVE;
  end;

  TForm1 = class(TForm)
    btn1: TBitBtn;
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TBitBtn }

procedure TBitBtn.CMMOUSEENTER(var Msg: TMessage);
begin
  inherited;
  Font.Style := Font.Style + [fsBold];
end;

procedure TBitBtn.CMMOUSELEAVE(var Msg: TMessage);
begin
  inherited;
  Font.Style := Font.Style - [fsBold];
end;

end.

[Praxist]

Es geht mit dem Vorschlag. Sollen aber alle BitBtns den selben Effekt haben ?
Wenn ich den Effekt für ein bestimtes Button zuweise, bekomme ich Fehler:
Undeclared BitBtn1 !

Delphi-Quellcode:

Bitbtn1.Font.Style := Bitbtn1.Font.Style + [fsBold];

[DeddyH]

Da muss man etwas weiter ausholen:

Delphi-Quellcode:

unit bla;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Buttons;

type

  TBitBtn = class(Buttons.TBitBtn)
  private
    FOnMouseEnter: TNotifyEvent;
    FOnMouseLeave: TNotifyEvent;
    procedure CMMOUSEENTER(var Msg: TMessage); message CM_MOUSEENTER;
    procedure CMMOUSELEAVE(var Msg: TMessage); message CM_MOUSELEAVE;
  public
    constructor Create(aOwner: TComponent); override;
    property OnMouseEnter: TNotifyEvent read FOnMouseEnter write FOnMouseEnter;
    property OnMouseLeave: TNotifyEvent read FOnMouseLeave write FOnMouseLeave;
  end;

  TForm1 = class(TForm)
    btn1: TBitBtn;
    btn2: TBitBtn;
    btn3: TBitBtn;
    procedure FormCreate(Sender: TObject);
    procedure DoOnEnter(Sender: TObject);
    procedure DoOnLeave(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TBitBtn }

procedure TBitBtn.CMMOUSEENTER(var Msg: TMessage);
begin
  inherited;
  if Assigned(FOnMouseEnter) then
    FOnMouseEnter(Self);
end;

procedure TBitBtn.CMMOUSELEAVE(var Msg: TMessage);
begin
  inherited;
  if Assigned(FOnMouseLeave) then
    FOnMouseLeave(Self);
end;

constructor TBitBtn.Create(aOwner: TComponent);
begin
  inherited;
  FOnMouseEnter := nil;
  FOnMouseLeave := nil;
end;

procedure TForm1.DoOnEnter(Sender: TObject);
begin
  (Sender as TBitBtn).Font.Style := (Sender as TBitBtn).Font.Style + [fsBold];
end;

procedure TForm1.DoOnLeave(Sender: TObject);
begin
  (Sender as TBitBtn).Font.Style := (Sender as TBitBtn).Font.Style - [fsBold];
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  btn2.OnMouseEnter := DoOnEnter;
  btn2.OnMouseLeave := DoOnLeave;
end;

end.

Hier werden die beiden definierten Events nur für btn2 zugewiesen.

[Praxist]

Wie konnte ich für ein bestimmtes Btn ein bestimmtes Bild zuweisen ?

Delphi-Quellcode:

ImageList1.GetBitmap(2, Btn2.Glyph);

[DeddyH]

Schau Dir in meinem Beispiel mal DoOnEnter und DoOnLeave an. Statt die Schriftart zu ändern, kannst Du dort auch andere Bilder zuweisen.

[Praxist]

dort habe folgendes eingegeben

Delphi-Quellcode:

procedure TForm1.DoOnEnter(Sender: TObject);
begin
  //(Sender as TBitBtn).Font.Style := (Sender as TBitBtn).Font.Style + [fsBold];
  ImageList1.GetBitmap(1, Btn1.Glyph);
  ImageList1.GetBitmap(2, Btn2.Glyph);
end;

Aber die Bilder werden in alle Buttons angezeigt, wenn der Cursor auf ein Button kommt
Das Bild soll aber nur angezeigt, wenn der der Cursor auf sein Button kommt
Wie kann ich das machen ?
Vorteil mit diesem Code die Buttons glitzern nicht : )

[DeddyH]

Es kommt mir ein wenig so vor, als hättest Du das Prinzip nicht verstanden :gruebel:, oder wieso stehen da benannte Instanzen (Btn2 und Btn2)?

[Praxist]

Nicht ganz

[TonyR]

Also Praxist,

schau noch einmal in Beitrag #12 (hier nur ein Auszug mit Erläuterungen):

Delphi-Quellcode:

...
procedure TForm1.DoOnEnter(Sender: TObject);
begin
  //(Sender as TBitBtn).Font.Style := (Sender as TBitBtn).Font.Style + [fsBold];
  //das brauchst du nicht, vielmehr folgendes:
  ImageList1.GetBitmap(1, (Sender as TBitBtn).Glyph);
end;

procedure TForm1.DoOnLeave(Sender: TObject);
begin
  //(Sender as TBitBtn).Font.Style := (Sender as TBitBtn).Font.Style - [fsBold];
  //hier genau dasselbe nur eben das andere Bildchen
  //ich weiß ja jetzt nicht welches, aber ungefähr so eben:
  ImageList1.GetBitmap(2, (Sender as TBitBtn).Glyph);   
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  //und hier ist es ganz wichtig, dass du für alle
  //Bitbtns Enter und Leave zuweist!

  //also nicht nur
  btn2.OnMouseEnter := DoOnEnter;
  btn2.OnMouseLeave := DoOnLeave;

  //sondern auch:
  btn1.OnMouseEnter := DoOnEnter;
  btn1.OnMouseLeave := DoOnLeave;

  //wenn das zu viele Komponenten sind dann
  //verwende eine Schleife die alle Komponenten durchläuft
  //und es den Bitbtns zuweist,
  //das gehört dann aber nicht in diesen Thread
end;

end.

Ich hoffe das hilft, sieh es dir genau an.

[Praxist]

Du hast auch das Button nicht hingeschrieben !

Delphi-Quellcode:

  //das brauchst du nicht, vielmehr folgendes:
  ImageList1.GetBitmap(1, (Sender as TBitBtn).Glyph); // für welches Button ?

[TonyR]

Zitat:

Zitat von Praxist

Du hast auch das Button nicht hingeschrieben !

Delphi-Quellcode:

  //das brauchst du nicht, vielmehr folgendes:
  ImageList1.GetBitmap(1, (Sender as TBitBtn).Glyph); // für welches Button ?

Das bestimmt der Sender, welcher Button das ist,
hast du den Code mal so probiert?
Vielleicht funktioniert es!?

[Praxist]

>> hast du den Code mal so probiert?
Alle BitButtons bekommen das selbe Bilder OnMouseEnter, logisch
Aber jedes Bild soll ein bestimmtes Bild haben

[mkinzler]

Wende den Code halt auf Sender an

[Praxist]

Zitat:

Zitat von Praxist

>> hast du den Code mal so probiert?
Alle BitButtons bekommen das selbe Bilde OnMouseEnter, logisch
Aber jedes Bild soll ein bestimmtes Bild haben

[DeddyH]

Dann müsste man eine Abfrage auf den Sender einbauen.

Delphi-Quellcode:

if (Sender = btn1) then
  ImageList1.GetBitmap(1, btn1.Glyph)
else if (Sender = btn2) then
  ImageList1.GetBitmap(2, btn2.Glyph)
...

Evtl. gibt es auch eine elegantere Methode, aber die fällt mir gerade nicht ein.

[mkinzler]

Man könnte den Index als Tag im Button hinterlegen

[DeddyH]

Stimmt, die Tag-Property vergesse ich immer wieder, dabei kann sie so nützlich sein :lol:

[Praxist]

So sieht es aus :

Delphi-Quellcode:

procedure TForm1.DoOnEnter(Sender: TObject);
begin
 if (Sender = btn1) then begin Btn1.Glyph := nil;
  ImageList1.GetBitmap(1, btn1.Glyph); end
else if (Sender = btn2) then begin Btn2.Glyph := nil;
  ImageList1.GetBitmap(3, btn2.Glyph);end
  else if (Sender = btn3) then begin Btn3.Glyph := nil;
  ImageList1.GetBitmap(5, btn3.Glyph);end;
end;

procedure TForm1.DoOnLeave(Sender: TObject);
begin
  //(Sender as TBitBtn).Font.Style := (Sender as TBitBtn).Font.Style - [fsBold];
    if (Sender <> btn1) then begin Btn1.Glyph := nil;
  ImageList1.GetBitmap(0, btn1.Glyph);end
else if (Sender <> btn2) then begin Btn2.Glyph := nil;
  ImageList1.GetBitmap(2, btn2.Glyph); end
  else if (Sender <> btn3) then begin Btn3.Glyph := nil;
  ImageList1.GetBitmap(4, btn3.Glyph);end;
end;

Es funktioniert nicht schnell und das Button bekommt nicht sofort ein neues Bild
OnMouseLeave sondern nur nach hin und her den Cursor auf andere BitButtons bewegen !
Das ganze funktioniert mit einer Verzögerung
Btn3 wechselt sein Bild überhaupt nicht !

[DeddyH]

Liest Du eigentlich, was wir hier schreiben? Markus' Idee mit dem Tag ist doch super, die musst Du nur umsetzen. Also: btn1 bekommt Tag 1, btn2 Tag 3 und btn3 Tag5 (im OI). Und nun müsste das so doch gehen:

Delphi-Quellcode:

procedure TForm1.DoOnEnter(Sender: TObject);
begin
  ImageList1.GetBitmap((Sender as TBitBtn).Tag, (Sender as TBitBtn).Glyph);
end;

procedure TForm1.DoOnLeave(Sender: TObject);
begin
  ImageList1.GetBitmap(Pred((Sender as TBitBtn).Tag), (Sender as TBitBtn).Glyph);
end;

[Praxist]

Mit dem Tag funktioniert OnMouseEnter wunderbar :

Delphi-Quellcode:

procedure TForm1.DoOnEnter(Sender: TObject);
begin
   If (sender AS TBitBtn).Tag = 1 then begin
  ImageList1.GetBitmap(1, btn1.Glyph); end;
  If (sender AS TBitBtn).Tag = 2 then begin
  ImageList1.GetBitmap(3, btn2.Glyph); end;
    If (sender AS TBitBtn).Tag = 3 then begin
  ImageList1.GetBitmap(5, btn3.Glyph); end
end;

Mit OnMouseLeave kapiere ich immer noch nicht

Delphi-Quellcode:

procedure TForm1.DoOnLeave(Sender: TObject);
begin
  ImageList1.GetBitmap(Pred((Sender as TBitBtn).Tag), (Sender as TBitBtn).Glyph);
end;

[mkinzler]

Ich würde keine feste Referenzen verwenden sonder den Sender auswerten

Delphi-Quellcode:

ImageList1.GetBitmap((Sender as TButton).Tag, (Sender as TButton).Glyph);

[DeddyH]

Und ich verstehe nicht, dass Du unsere Posts ignorierst oder nur halb liest.

Zitat:

Zitat von DeddyH

btn1 bekommt Tag 1, btn2 Tag 3 und btn3 Tag 5 (im OI).

Der Tag bestimmt den Index der ImageList und kann direkt aus dem Sender ausgelesen werden.

Zitat:

Delphi-Quellcode:

ImageList1.GetBitmap((Sender as TBitBtn).Tag, (Sender as TBitBtn).Glyph);

Und was verstehst Du an meinem DoOnLeave nicht? Ist doch genau dasselbe Prinzip, nur dass der Index dann Tag - 1 entspricht.

[Praxist]

Ich habe nicht gewusst, dass den tag automatisch ausgelesen wird
Wie gesagt OnMouseEnter geht super

In MouseLeave habe ich den selben Prinzip, wie Du geschrieben hast aber passiert nicht

Delphi-Quellcode:

procedure TForm1.DoOnLeave(Sender: TObject);
begin
//  ImageList1.GetBitmap(Pred((Sender as TBitBtn).Tag-1), (Sender as TBitBtn).Glyph);
ImageList1.GetBitmap((Sender as TBitBtn).Tag-1, (Sender as TBitBtn).Glyph);
end;

Oder vielleicht muss man das Bild vorher löschen

[DeddyH]

Funktioniert es denn, wenn Du als Index fest die 0 reinschreibst? Wird die Methode überhaupt aufgerufen?

[Praxist]

Wie ich gedacht habe, man mus sowohl OnMouseEnter als auch OnMouseLeave vorher das BitBtn Graphic löschen :

Delphi-Quellcode:

procedure TForm1.DoOnLeave(Sender: TObject);
begin 
(Sender as TBitBtn).Glyph := nil;
// dann kommt der code

Danke für die Hilfe und für Deine Geduld : )