Fehler beim Drehen eines Bildes

[Hazardos]

Hallo!!

Ich möchte ein Bild drehen, habe auch schon ne Procedure, aber ich sehe kein Ergebnis. Stattdessen bleibt das vorherige BIld wie es war in der TImage Komponente und wenn man mit einem anderen Fenster rüberfährt ist plötzlich nichts mehr zu sehen. Ich hatte die Selbe Procedure auch in einem anderen Programm verbaut, da funktioniert sie einwandfrei, deshalb kann ich mir nicht erklären, warum das bei mir nicht so ist. Bitte um jede Hilfe!!

[scp]

Hast du auch ein Code-Beispiel? Wenn es zu lang ist, kannst dus ja als Datei anhängen.

[Hazardos]

Declaration

Delphi-Quellcode:

type
TRGBArray    = ARRAY[0..0] OF TRGBTriple;
pRGBArray    = ^TRGBArray;
THelpRGB = packed record
rgb    : TRGBTriple;
dummy  : byte;
end;

die Procedure :

Delphi-Quellcode:

procedure Drehen(Bitmap:TBitmap);
var P       : PRGBQuad; //^THelpRGB;
    x,y,b,h : Integer;
    RowOut  : ^TMyHelp;
    help    : TBitmap;
begin
   Bitmap.pixelformat := pf32bit;
   help := TBitmap.Create;
   help.PixelFormat := pf32bit;
   b := bitmap.Height;
   h := bitmap.Width;
   help.Width := b;
   help.height := h;
   for y := 0 to (h-1) do begin
     rowOut := help.ScanLine[y];
     P  := Bitmap.scanline[bitmap.height-1];
     inc(p,y);
     for x := 0 to (b-1) do begin
        rowout[x] := p^;
        inc(p,h);
     end;
   end;
   bitmap.Assign(help);
end;

aber vielleicht gibt es ja auch ne andere Möglichkeit, das Bild zu drehen.

[Keldorn]

Hallo diese Procedure ist aus nem DoKo- buch oder?
sie ist nicht sauber (Bereichsprüfung muß deaktiviert sein) aber ise geht. wie sieht denn dein Aufruf aus? bei DokO ist auch ein Beipsiel mit dabei

Delphi-Quellcode:

procedure TForm1.Button2Click(Sender: TObject);
begin
  image1.Picture.bitmap.PixelFormat := pf24bit;
  Drehen90Grad(image1.picture.bitmap);
end;

Mfg Frank

[Hazardos]

Die Procedure hab ich aus einem Buch, welches wir in der Schule bekommen haben. Der Aufruf sieht genauseo aus, wie du ihn beschriben hast, nur funktioniert es nicht. Vielleicht hast du ja noch eine andere Lösung für das Problem. Wenn ja, kannst du sie bitte hiuer reinstellen??

mfg Hazardos

[scp]

So gehts (bei mir):

Delphi-Quellcode:

procedure Drehen90Grad(Bitmap:TBitmap);
var P       : PRGBQuad;
    x,y,b,h : Integer;
    RowOut  : PRGBQuad;  // <-- Hier Typ geändert
    help    : TBitmap;
begin
   Bitmap.pixelformat := pf32bit;
   help := TBitmap.Create;
   help.PixelFormat := pf32bit;
   b := bitmap.Height; 
   h := bitmap.Width;
   help.Width := b;
   help.height := h;
   for y := 0 to (h-1) do begin
     rowOut := help.ScanLine[y];
     P  := Bitmap.scanline[bitmap.height-1];
     inc(p,y);
     for x := 0 to (b-1) do begin
        rowout^ := p^;  // <-- Und hier geändert
        Inc(rowout); // <--- Das dazu
        inc(p,h);
     end;
   end;
   bitmap.Assign(help);
end;

[Hazardos]

Es ist echt zum Verzweifeln. Ich kann mir einfach nicht erklären, warum das nicht läuft, obwohl es bei dem anderen Programm läuft. Auch deine Änderungen haben nichts bei mir bewirken können. Habe ich vielleicht irgendwas vergessen?? In der Projekt-Unit oder im FormCreate??

[scp]

Na, dann erzähl mal ein paar Sachen. Ist das ein Bitmap (BMP), das du in TImage hast? Lädst du das Bild nachträglich per LoadFromFile oder was rein oder über die IDE?

[Hazardos]

Hauptsächllich werden jpegs via LoadFromFile reingeladen. Dazu habe ich einfach die JPEG-Unit hinzugefügt.

[scp]

Da das Drehen auf Bitmapebene passiert, müssen die Daten erstmal umgewandelt werden:

Delphi-Quellcode:

function Graphic2Bmp(AGraphic : TGraphic) : TBitmap;
begin
  result := TBitmap.Create;

  result.PixelFormat := pf24bit;
  result.Height := AGraphic.Height;
  result.Width  := AGraphic.Width;
  result.Canvas.Draw(0, 0, AGraphic);
end;

Delphi-Quellcode:

procedure TForm1.Button2Click(Sender: TObject);
begin
  If not image1.Picture.Graphic.Empty then
    image1.Picture.bitmap := Graphic2Bmp(image1.Picture.Graphic);
  image1.Picture.bitmap.PixelFormat := pf24bit;
  Drehen90Grad(image1.picture.bitmap);
end;

[Hazardos]

Das war der Fehler!!!
Jetzt funzt alles, wie es soll!!
Danke für die Hilfe

mfg Hazardos

[Keldorn]

@scp: damit schafft du dir aber ein Speicherloch, da du bei graphic2bmp zwar eine Bitmap erzeugst, diese aber nie wieder freigibst.

Mfg Frank

[scp]

@Keildorn
In dem Fall wird doch das Bitmap an das TImage übergeben, somit übernimmt das die Verwaltung und auch die Freisetzung.

[Keldorn]

Zitat:

Zitat von scp

@Keildorn
In dem Fall wird doch das Bitmap an das TImage übergeben, somit übernimmt das die Verwaltung und auch die Freisetzung.

nein, das ist nicht richtig. nimm dir das Programm memproof zur hilfe.

Delphi-Quellcode:

image1.Picture.bitmap := Graphic2Bmp(image1.Picture.Graphic);

ist

Delphi-Quellcode:

image1.Picture.bitmap.assign(Graphic2Bmp(image1.Picture.Graphic));

oder sowas in der Art. auf alle Fälle steht ein assign dahinter.Das wird in der Set-methode geregelt. Du kopierst nur die bitmap. die übergebene Bitmap ist nach wie vor da. Das wäre sonst ja auch schlimm.

entweder du schreibst die Funktion um und übergibst eine Bitmap oder

Delphi-Quellcode:

Var bmp:Tbitmap;
begin
  If not image1.Picture.Graphic.Empty then
    begin
      bmp:=Graphic2Bmp(image1.Picture.Graphic);
      image1.Picture.bitmap := bmp;
      bmp.free;
    end;
...

Ich persönlich finde Objekte als Rückgabe von Funktionen nicht gut, hier vergißt man schnell das free.

im übrigen fehlt auch beim drehen ein free:

Delphi-Quellcode:

procedure Drehen90Grad(Bitmap:TBitmap);
...
begin
   Bitmap.pixelformat := pf32bit;
   help := TBitmap.Create;
   ....
   bitmap.Assign(help);
   help.free;
end;

Das ist vielleicht auch der Grund, warum immer auch über DoKo-Bücher gemeckert wird. Das free zu vergessen sind Anfängerfehler, außerdem fehlt hier ein try-block.

Mfg Frank

[Niko]

Zitat:

Zitat von scp

somit übernimmt das die Verwaltung und auch die Freisetzung

Nein, denn bei der Zuweisung an TPicture.Bitmap wird ein neues Bitmap erzeugt und das übergebene per Assign übernommen. Um die Freigabe des eigenen Bitmaps muss man sich also selbst kümmern.

[scp]

Naja, ein Anfänger bin ich nicht. In der Regel verwende ich auch Free. Nur in dem Fall habe ich mich vertan, habe grad mal in Graphics.pas geguckt, stimmt, wird nur ein Assign() durchgeführt.

[Keldorn]

Zitat:

Zitat von scp

Naja, ein Anfänger bin ich nicht. In der Regel verwende ich auch Free. Nur in dem Fall habe ich mich vertan, habe grad mal in Graphics.pas geguckt, stimmt, wird nur ein Assign() durchgeführt.

nein, hier hast du mich falsch verstanden, bzw ich habe mich vielleicht n bißchen blöd ausgedrückt :oops: . Ich meinte damit, das ich es nicht gut finde, wenn im Doko-buch fehlerhafte Proceduren enthalten sind.

Sorry Frank