[batch] ordnernamen

[_frank_]

ich suche schon seit Ewigkeiten nach einer Möglichkeit den aktuellen Ordnernamen (nicht den ganzen Pfad) zu ermitteln...nach stundenlangem googlen habe ich bisschen mit %cd% rumexperimentiert, jedoch habe ich keine funktionierende Variante hinbekommen.

Hoffe irgendjemand hat da eine Idee :)

Gruß Frank

[Christian Seehase]

Moin Frank,

der aktuelle Order wird schlicht durch . (ein Punkt) angegeben.
Oder brauchst Du explizit den Namen?

[Fussball-Robby]

Den Namen bekommst du so:

Code:

@echo off
for %%i in (%cd:\=,%) do set MyDir=%%i
echo %MyDir% 
pause

[_frank_]

ich brauch den namen...

ums mal zu erklären, ich will ein script schreiben, welches mir bestimmte dateien in einem Verzeichnis (mittels 7zip) packt, wo das archiv den Namen des ordners hat. wie die funktion "hinzufügen zu <ordner>.zip" nur halt automatisiert, da ich noch Dateien ausklammern will (funktioniert schon).

Danke Robby, das war genau das, was ich gesucht habe :)

Gruß Frank

[Christian Seehase]

Moin Robert,

auch schön.

Ich hätte noch folgendes anzubieten:

Code:

@ECHO OFF
for %%I IN (%~0) DO SET SELF=%%~dI%%~pI
SET SELF=%SELF:~,-1%
ECHO %SELF%
pause

Lässt man das zweite SET weg, bekommt man den Pfad mit \ am Ende, sonst ohne.

[Fussball-Robby]

Hallo Christian,

bei deiner Variante bekomme ich den ganzen Pfad zum Ordner. Das wollte der TE aber nicht, er wollte doch nur den Ordnernamen..

[_frank_]

was jetzt noch interesant wäre: ob es möglich ist, 2 ebenen weiter oben den Namen zu bekommen :)

Grund dafür ist, dass ich manchmal SVN-Strukturen habe und somit der "programmname" nicht im letzten ordner steckt (dieser heist da trunk).sowas wie arrays sind mir in bath nicht bekannt...

//edit lässt sich das mit dem leerzeichen irgendwie umgehen? hab versucht das in der for-schleife mittels " zu kapseln, hat aber nicht geklappt (trotzdem nur letzter teil)

Gruß Frank

[Christian Seehase]

Zitat:

Zitat von Fussball-Robby

Hallo Christian,

bei deiner Variante bekomme ich den ganzen Pfad zum Ordner. Das wollte der TE aber nicht, er wollte doch nur den Ordnernamen..

Dann lässt man eben das %%~dI weg ;-)

Nachtrag:
Deine Fassung hat übrigens bei Ordnern mit Leerzeichen das gleiche Problem wie meine ... es wird nur der Anfang des Ordnernamens angezeigt ;-)

[Fussball-Robby]

Zitat:

Zitat von _frank_

was jetzt noch interesant wäre: ob es möglich ist, 2 ebenen weiter oben den Namen zu bekommen :)

Ja, das ist Möglich. Mittels pushd kannst du den Ordner wechseln, wobei .. der übergeordnete Ordner ist. Wenn du 2 Ordner nach oben wilst sähe der Code also so aus:

Code:

@echo off
pushd ..\..
for %%i in (%cd:\=,%) do set MyDir=%%i
echo %MyDir%
pause

Bei 3 Ordnern wäre es pushd ..\..\.. usw.

Zitat:

Zitat von _frank_

lässt sich das mit dem leerzeichen irgendwie umgehen? hab versucht das in der for-schleife mittels " zu kapseln, hat aber nicht geklappt (trotzdem nur letzter teil)

Ich habe es gestern auch noch ausprobiert, allerdings keine Lösung gefunden. Ich probier gleich nochmal ein wenig rum :wink:

[_frank_]

Zitat:

Zitat von Fussball-Robby

Ja, das ist Möglich. Mittels pushd kannst du den Ordner wechseln, wobei .. der übergeordnete Ordner ist.

ich glaube es war gestern ein wenig zu spät ;) hätte ja selber drauf kommen können, entsprechend das Workingdir zu wechseln per cd/pushd.

wär noch super, wenn es ne möglichkeit gäbe mit den leerzeichen...wie gesagt ich habs versucht mittels

Code:

for %%i in (%cd:\=,%) do set MyDir="%%i"
set MyDir=%MyDir:~1,-1%
echo %MyDir%

Gruß Frank

[Fussball-Robby]

Ich hab ne Lösung gefunden, ob sie elegant ist sei mal dahingestellt. Bei der Ausgabe sind dann aber noch Anführungszeichen drumrum.

Code:

@echo off
pushd ..\..
for %%i in (%cd: =#%) do set MyDir=%%i
for %%i in ("%MyDir:\=,%") do set MyDir=%%i
for %%i in ("%MyDir:#= %") do set MyDir=%%i
echo %MyDir%
pause

Erstmal habe ich alle Leerzeichen durch # ersetzt. Dann hole ich mir den Ordnernamen und ersetze die # wieder durch Leerzeichen.
Ist wohl ziemlich unsauber, aber so gut kenn ich mich mit Batch-Programmierung auch nichts aus und vielleicht hilft es dir ja.

[_frank_]

danke, du hast mich da auf eine idee gebracht, auch wenn man keine schleife dafür braucht ;)
hab auch festgestellt, dass ich auch nur 1 ebene hoch muss ;)

hier meine komplette batch, vielleicht nützt sie jemanden noch:

Code:

@echo off

cd %~dp0

rem removing backups
del /S *.~*
del /S *.dcu
del /S *.map
del /S *.drc
del /S _bak_\*.*
rmdir _bak_

goto getfoldername
:DirsUp
pushD ..
:getfoldername
rem getting name of current folder

rem replace spaces
set dir=%cd: =#%

rem parsing last foldername
for %%i in (%dir:\=,%) do set folder="%%i"

rem replace back to spaces
set folder=%folder:#= %
rem remove quotes
set folder=%folder:~1,-1%

rem echo %folder%
rem pause
if "%folder%"=="trunk" goto DirsUp

set zipname="%folder%.zip"
set _7za="D:\system\7-zip\7za.exe"
set exclude=-x!*.svn*

popd
%_7za% u -r -tzip %exclude% %zipname% .\

pause

Gruß Frank