Variablen zwischen 2 Formularen übermitteln

[sventeq]

Hallo, ich würde gerne wissen, wie man den Wert einer Variablen eines Formulares in ein anderes Formular übermittelt. Kann mir da jemand helfen? Habe es mit Editfeldern probiert. Das geht auch ganz gut, solange es kein Datum ist und gerade das muss ich im anderen Formular haben. Wäre für jede Hilfe echt dankbar.

[LoCrux]

Innerhalb der gleichen Applikation gibt es 'ne ganze Latte an Möglichkeiten.

Gib mal Code-Schnipsel....

Über mehrere Apllikationen hinweg --> z.B. Windows-Messages.

[mkinzler]

Am Besten über Methoden. Am Besten in eigene Unit, welche von allen Formularen eingebunden wird

[Xzeer]

Du könntest auch einfach eine Globale Variable deklarieren, das ist zwar eine ziemlich verrufene Art, funktioniert aber einwandfrei.

[DeddyH]

Dann doch besser eine Property.

[sventeq]

Code-Schnippsel gibt es da noch gar nicht, da ich ja noch keine Möglichkeit gefunden hatte und nur mit Editfelder herum experimentiert hab

[DeddyH]

Lies Dir mal diesen Thread durch, da wird die Möglichkeit mit Properties beschrieben.

[sventeq]

Zitat:

Zitat von mkinzler

Am Besten über Methoden. Am Besten in eigene Unit, welche von allen Formularen eingebunden wird

wie muss ich mir das vorstellen mit Methoden in einer Unit? Was müssen die Methoden können? Wie erfolgt dann der Zugriff auf die Variablen aus dem anderen Formular?

[sventeq]

Zitat:

Zitat von DeddyH

Lies Dir mal diesen Thread durch, da wird die Möglichkeit mit Properties beschrieben.

Danke, mach ich

[mkinzler]

Zitat:

Zitat von sventeq

Zitat:

Zitat von mkinzler

Am Besten über Methoden. Am Besten in eigene Unit, welche von allen Formularen eingebunden wird

wie muss ich mir das vorstellen mit Methoden in einer Unit? Was müssen die Methoden können? Wie erfolgt dann der Zugriff auf die Variablen aus dem anderen Formular?

Ich meinte eine Methode des Formulares oder über Unit um Kreuzverweise zu vermeiden

[LoCrux]

OK.. maybe not optimal but working.
Eine Loesungsmoeglichkeit ueber Events.

Deine "Main-FormA"

Delphi-Quellcode:

unit Unit_A;

interface

uses
  Unit_B,
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type

  TForm_A = class(TForm)
    editA: TEdit;
    procedure editAChange(Sender: TObject);
  private
    { Private-Deklarationen }
    Form_B: TForm_B;
    Procedure GotNotifyFromB(text:String);
  public
    { Public-Deklarationen }
    constructor create(AOwner:TComponent); override;
    destructor  destroy; override;
  end;

var
  Form_A: TForm_A;

implementation

{$R *.dfm}

constructor TForm_A.create(AOwner:TComponent);
begin
  inherited;
  Form_B := TForm_B.Create(Self);
  Form_B.DoNotifyA := GotNotifyFromB;
  Form_B.Constraints := Self.Constraints;
  Form_B.Top    := Self.Top;
  Form_B.Left   := Self.Left+Self.Width;
  Form_B.Show;
end;

destructor TForm_A.destroy;
begin
  if Assigned(Form_B) then Form_B.Free;
  inherited;
end;

Procedure TForm_A.GotNotifyFromB(text:String);
begin
  editA.Text := text;
end;

procedure TForm_A.editAChange(Sender: TObject);
begin
  if Assigned(Form_B) then Form_B.editB.Text := editA.Text;
end;

end.

Deine "FormB"

Delphi-Quellcode:

unit Unit_B;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TEditNotify = Procedure(text:String) of object;

  TForm_B = class(TForm)
    editB: TEdit;
    procedure editBChange(Sender: TObject);
    procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean);
  private
    { Private-Deklarationen }
    FDoNotifyA : TEditNotify;
  public
    { Public-Deklarationen }
    property DoNotifyA:TEditNotify read FDoNotifyA write FDoNotifyA;
  end;


implementation

{$R *.dfm}

procedure TForm_B.editBChange(Sender: TObject);
begin
  if Assigned(FDoNotifyA) then FDoNotifyA(editB.Text);
end;

procedure TForm_B.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
begin
  CanClose := False;
end;

end.