Alle BitBtn auf einem TTabSheet enabled = FALSE setzen

[HolgerCW]

Hallo zusammen,

wie kann ich alle BitBtn auf einem TTabSheet auf enabled := FALSE setzen ?

Gruss

Holger

[DeddyH]

Versuch es mal so:

Delphi-Quellcode:

var i: integer;
begin
  for i := 0 to ComponentCount - 1 do
    if (Components[i] is TBitBtn) and (TBitBtn(Components[i]).Parent = TabSheet1) then
      TBitBtn(Components[i]).Enabled := false;
end;

[HolgerCW]

Das sieht schon ganz gut aus. Nur ist das Problem, das auf dem TabSheet mehrere GroupBoxen sind und in diesen GroupBoxen dann die BitBtns.

Wie bekomme ich es nun hin, das alle BitBtns in den GroupBoxen enabled = TRUE werden ?

Gruss

Holger

[dominikkv]

Zitat:

Zitat von HolgerCW

Das sieht schon ganz gut aus. Nur ist das Problem, das auf dem TabSheet mehrere GroupBoxen sind und in diesen GroupBoxen dann die BitBtns.

Wie bekomme ich es nun hin, das alle BitBtns in den GroupBoxen enabled = TRUE werden ?

Gruss

Holger

Das wird kompliziert^^
Nimm dir doch nen Array und speicher bei Programmanfang alle Referenzen von den BitBtns in dem Array... dann brauchst du nur noch das Array duchzugehen

edit: oder so: :mrgreen:

Delphi-Quellcode:

var i: integer; 
begin 
  for i := 0 to ComponentCount - 1 do 
    if (Components[i] is TBitBtn) and (TBitBtn(Components[i]).Parent.Parent = TabSheet1) then 
      TBitBtn(Components[i]).Enabled := false; 
end;

[DeddyH]

Versteh ich nicht. Bist Du sicher, dass die BitBtns in den GroupBoxen liegen und nicht davor?

[HolgerCW]

Ja,

wenn ich die Struktur in Delphi oben links mir anschaue, sind die BitnBtns in der GroupBox. So habe ich das auch gewollt.

So funktionierts:

Delphi-Quellcode:

MeineGroupBox := TGroupBox(FindComponent('GB1'));

for I := 0 to Form1.ComponentCount - 1 do
begin

 if (Components[i] is TBitBtn) and (TBitBtn(Components[i]).Parent = MeineGroupBox) then
 begin

  TBitBtn(Components[i]).Enabled := TRUE;

 end;

end;

Nur wollte ich das TabSheet angeben, nicht die einzelnen GruopBoxen auf dem TabSheet.

Was ich bräuchte ist:

1. TabSheetname ist als String bekannt.
2. Auslesen der GroupBoxen durch Parent
3. Auslesen der BitBtns in den GroupBoxen durch Parent
4. Alle ausgelesenen BitBtns auf enabled = TRUE setzen

Ist das möglich ?

[DeddyH]

Nächster Versuch:

Delphi-Quellcode:

var i: integer;
begin
  for i := 0 to ComponentCount - 1 do
    if (Components[i] is TBitBtn) and (TBitBtn(Components[i]).Parent is TGroupBox) and
       Assigned(TBitBtn(Components[i]).Parent.Parent) and
       (TBitBtn(Components[i]).Parent.Parent = TabSheet1) then
      TBitBtn(Components[i]).Enabled := true;
end;

[Apollonius]

Zitat:

Assigned(TBitBtn(Components[i]).Parent.Parent) and
(TBitBtn(Components[i]).Parent.Parent = TabSheet1)

Die zweite Abfrage reicht, denn Assigned prüft ja nur auf <> nil.

[HolgerCW]

Hallo,

ich hätte mit einer Lösung ja nicht mehr gerechnet, aber das klappt nun einwandfrei.

Vielen dank für eure mühen.

Gruss und ein schönes Wochenende

Holger

[backdraft]

Du kannst auch einfach recursiv suchen.
Ein TabSheet oder eine Groupbox basieren auf TWinControl. Alle Objekte die auf TWinControl basieren können Controls aufnehmen.
Der Aufsetzpunkt ist das Tabsheet. Immer wenn du ein Control findest was auf TWinControl basiert, startest du deine Funktion mit dem neuen Aufsetzpunkt.

Alternativ könntest du auch für alle Buttons Actions vergeben mit einer Kategorie, und diese dann einfach deaktivieren.

[dominikkv]

Zitat:

Zitat von HolgerCW

ich hätte mit einer Lösung ja nicht mehr gerechnet, aber das klappt nun einwandfrei.

ich hab die Lösung doch gleich am Anfang gepostet -.-

[HolgerCW]

Hi dominikkv,

Du hast Recht. Habe das übersehen. Deine Lösung sah so gleich aus, aber hatte ja auch schon die "doppelten" parents.

Nochmals vielen dank an alle.

Nun kann ich mein "Berechtigungssystem" ganz variabel gestalten.

Mal nur einen BitBtn freischalten, mal alle BitBtns auf einem TabSheet, oder auch alle BitBtns auf einem TPageControl.

Gruss

Holger

[HolgerCW]

Hallo nochmal.

Geht das ganz auch mit TPageControl. Soll heissen, das alle BitBtns die sich auf dem PageControl befinden enabled = TRUE gesetzt werden sollen ?

So ist der Aufbau:

1. TPageControl mit einzelnen TTabSheets
2. Weitere TPageControl mit einzelnen TTabSheets auf den vorherigen TTabSheets
3. dann Groupboxen
4. dann die BitBtns

Gruss

Holger

[DeddyH]

Du musst doch nur wissen, wer wessen Parent ist. Das Prinzip kennst Du ja nun.

[HolgerCW]

Alles klar,
wollte nur wissen ob TPageControl auch Parent ist ...

Nun habe ich aber folgendes Problem:

Delphi-Quellcode:

for I := 0 to Form1.ComponentCount - 1 do
begin

 if (Components[i] is TBitBtn) then
 begin

  If Assigned(TBitBtn(Components[i]).Parent.Parent.Parent.Parent.Parent) then
  begin

   If (TBitBtn(Components[i]).Parent.Parent.Parent.Parent.Parent = MeinPageControl) then
   begin

    ...

Jetzt gibt es einige BitBtns die nicht 5 Parents bezitzen. Ich dachte die kann ich mit Assigned abfangen, aber dennoch kommt dort eine Zugriffsverletzung. Was kann ich tun ?

Gruss

Holger

[Meta777]

huhu,
über das "Controls" property kein problem. Hier mal 2 Varianten die ich benutze:
EDIT: Muss natürlich dahingehend angepasst werden das nur "TBitBtn" berücksichtigt wird...

Delphi-Quellcode:

procedure EnableDisalbeChildControls(const Enalbe: Boolean; ParentControl: TWinControl);
var
  i: Integer;
begin
  if Assigned(ParentControl) AND (ParentControl <> nil) then begin
    for i := 0 to ParentControl.ControlCount-1 do begin
      if not (ParentControl.Controls[i].InheritsFrom(TCustomPanel)
      OR ParentControl.Controls[i].InheritsFrom(TCustomGroupBox)) then
        ParentControl.Controls[i].Enabled := Enalbe;
      if ParentControl.Controls[i] is TWinControl then
        EnableDisalbeChildControls(Enalbe,
          TWinControl(ParentControl.Controls[i]));
    end;
  end;
end;

procedure EnableDisalbeChildControls(const Enable: Boolean; ParentControl: TWinControl; ExceptThese: Array of TControl); overload;
var
  i, j: Integer;
  inExceptArr: Boolean;
begin
  inExceptArr := False;
  if Assigned(ParentControl) AND (ParentControl <> nil) then begin
    for i := 0 to ParentControl.ControlCount-1 do begin
      inExceptArr := False;
      for j := Low(ExceptThese) to High(ExceptThese) do begin
        inExceptArr := (Assigned(ExceptThese[j])) AND (ParentControl.Controls[i] = ExceptThese[j]);
        if inExceptArr then
          Break;
      end;//check if in ExceptThese-Array
      if not (ParentControl.Controls[i].InheritsFrom(TCustomPanel)
        OR ParentControl.Controls[i].InheritsFrom(TCustomGroupBox))
        AND (not inExceptArr) then
      begin
        ParentControl.Controls[i].Enabled := Enable;
      end;
      if ParentControl.Controls[i] is TWinControl then
        EnableDisalbeChildControls(Enable,
          TWinControl(ParentControl.Controls[i]), ExceptThese);
    end;
  end;
end;