Programm beendet bei Windows Restart nicht

[Centrii]

Hi,

Hab da ein kleines Problem mit einem Programm von mir.
Wenn ich Windows neustarten, herunterfahren oder den User abmelden will, wird mein Programm nicht beendet.
Es kommt immer die "END NOW" Message, Windows schafft es aber nicht das Programm zu beenden.
Hab schon versucht die WM´s abzufangen und es selber zu beenden, leider komm ich erst dazu, wenn die "END NOW" schon aktiv ist.
Ich hab schon alles was im OnClose steht auskommentiert, leider ohne Erfolg.

Hat jemand eine Idee und kann mir einen Vorschlag machen wie ich das Problem lösen könnte??

Gruß Ruben

[Nuclear-Ping]

Ohne Code zu sehen wie du was machst, ist das ein Raten ins Blaue.

[Muetze1]

Ist das Programm in den Tray minimiert?

[Semmel]

gibt es in CloseQuery eine Abfrage (Ja/Nein) war bei mir schon mal eine Möglichkeit ?

[Centrii]

Zitat:

Zitat von Muetze1

Ist das Programm in den Tray minimiert?

nein, ist es nicht.

Zitat:

Zitat von Semmel

gibt es in CloseQuery eine Abfrage (Ja/Nein) war bei mir schon mal eine Möglichkeit ?

in der CloseQuery gibt es keine abfragen, ich hab nichts in die OnCloseQuery geschrieben. Da Delphi beim aufruf der CloseQuery das CanClose standardmäßig auf CanClose := true setzt, habe ich darin nichts gemacht.
Alles was im OnClose Event steht, ist auskommentiert. Wenn ich die WM´s abhandeln will, bin ich immer zu spät dran. Beim Neustart von windows kommt erst das END NOW, wenn ich das weg clicke (mit "X"), komme ich in eine Abhandlungen der WM´s. Das ist aber zu spät. Gibts da eine Lösung?

Danke Euch :thumb:

[Nuclear-Ping]

Hallo? Code? Oder sollen wir 5 Seiten lang raten?

[Centrii]

Delphi-Quellcode:

procedure Tfmain.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
begin
 CanClose := true;
end;

Delphi-Quellcode:

procedure Tfmain.FormDestroy(Sender: TObject);
begin
  DeleteThread.Terminate;
  try
    DeleteThread.WaitFor;
  except
  end;
  DeleteThread.Free;
  Lock_Draw.Free;
  Lock_Query.Free;
  Lock_ClientCheck.Free;
  Lock_UpdateList.Free;
  Lock_NameCheck.Free;
end;

Delphi-Quellcode:

procedure Tfmain.WMEndSession(var Msg: TWMEndSession);
begin
  if msg.Unused = 0 then //d.h. es ist ein reboot/shutdown
  begin
   Statusbar1.Panels[2].Text:='Windowsmessage: reboot or shutdown required';
   Statusbar1.Update;
   Application.ProcessMessages;
   close;
  end
  else                  //d.h. es ist ein logoff
  begin
   Statusbar1.Panels[2].Text:='Windowsmessage: logoff required';
   Statusbar1.Update;
   Application.ProcessMessages;
   close;
  end;
end;

procedure Tfmain.WMQUERYENDSESSION(var Msg: TMessage);
begin
  msg.Result := Integer(true);
end;

so das ist alles was meiner Meinung nach relevand ist. Wie gesagt, alles im FormClose ist auskommentiert.

[Jelly]

Warum fängst du denn überhaupt die Windowsbotschaften ab?

[Centrii]

weil sich mein Programm bei einem Windows neustart nicht beendet
und ich die Hoffnung hatte das so in den Griff zu bekommen.
Leider komm ich aber erst zum Abfangen wenn die END NOW Meldung schon da ist.

[NormanNG]

Hi,

Delphi-Quellcode:

procedure Tfmain.FormDestroy(Sender: TObject);
begin
  DeleteThread.Terminate;
  try
    DeleteThread.WaitFor;
  except
  end;
  DeleteThread.Free;
  Lock_Draw.Free;
  Lock_Query.Free;
  Lock_ClientCheck.Free;
  Lock_UpdateList.Free;
  Lock_NameCheck.Free;
end;

Das liegt sicher daran, das DeleteThread nicht beendet. Kommentier mal den Thread aus. Wenns dann beendet, dann wars der Thread...

[generic]

du musst auf die Nachricht "WM_QUERYENDSESSION" reagieren:

Delphi-Quellcode:

type
  TForm1 = class(TForm)
    [...]
  private
    procedure WMQueryEndSession(var Message: TWMQueryEndSession); message WM_QUERYENDSESSION;
    [...]
  end;

procedure TForm1.WMQueryEndSession(var Message: TWMQueryEndSession);
begin
  Message.Result := 1;
end;

[NormanNG]

Hi,

Zitat:

du musst auf die Nachricht "WM_QUERYENDSESSION" reagieren:

das mag zwar funktionieren, löst aber doch die Ursache des Problems nicht. Der Thread sollte sich sauber beenden lassen, dann klappts auch mit dem Programmende.

[Centrii]

Delphi-Quellcode:

unit DeleteThread;

interface

uses
  Classes, SysUtils, ActiveX, ADODB;

type
  TDeleteThread = class(TThread)
  private
    Conn: TADOConnection;
    Query: TADOQuery;
  protected
    procedure Execute; override;
  public
  end;

implementation

uses
  Main;

{ Wichtig: Methoden und Eigenschaften von Objekten in visuellen Komponenten dürfen
  nur in einer Methode namens Synchronize aufgerufen werden, z.B.

      Synchronize(UpdateCaption);

  und UpdateCaption könnte folgendermaßen aussehen:

    procedure TDeleteThread.UpdateCaption;
    begin
      Form1.Caption := 'Aktualisiert in einem Thread';
    end; }

{ TDeleteThread }

procedure TDeleteThread.Execute;
var
  Loop: Integer;
begin
  CoInitialize(Nil);
  Conn:=TAdoConnection.Create(Nil);
  Conn.ConnectionString:=fMain.ADOConnection1.ConnectionString;
  Query:=TAdoQuery.Create(Nil);
  Query.Connection:=Conn;
  Conn.ConnectionTimeout := 15;
  Query.CommandTimeout := 40;
  Loop:=0;
  while not Terminated do
  begin
    if Loop = (fmain.FDeleteInterval*10) then begin   // Interval-Zeit
      if Conn.ConnectionString <> fMain.ADOConnection1.ConnectionString then
      try
        Conn.Close;
        Conn.ConnectionString:=fMain.ADOConnection1.ConnectionString;
      except
      end;
      if (fmain.FDeleteInterval * 2) > 40
        then Query.CommandTimeout := fmain.FDeleteInterval*2;   // doppelte Interval-Zeit in Sekunden
      if fMain.FmaxEntries = true then
      begin
        if (fMain.FautoDelete = true) then
        begin
          fmain.Tracer.Logdebug('DeleteThread, maxEntries: '+IntToStr(fmain.FDBmaxEntries)+', autodelete: '+IntToStr(fmain.FDBAutoDelete));
          Query.SQL.Text := 'If (Select Count(*) from GsfOPCLog) > ' + IntToStr(fMain.FDBmaxEntries + fMain.FDBAutoDelete) + ' begin'#13#10 +
                            '  Delete top(' + IntToStr(fMain.FDBAutoDelete) + ') from GsfOPCLog'#13#10 +
                            '  where ID not in (Select top ' + IntToStr(fMain.FDBmaxEntries) + ' ID from GsfOpcLog order by Timestamp desc)'#13#10 +
                            'end';
          try
            Query.ExecSQL;
            fmain.Tracer.LogDebug('Query.SQL.Text: '+query.SQL.Text);
          except
            on E:Exception do fmain.AddToLog('DeleteThread','Error in DeleteThread.Execute: '+E.Message,1,7);
          end;
        end;
      end;
      Loop:=0;
    end;
    Sleep(100);
    Inc(Loop);
  end;
  Query.Free;
  Conn.Free;
  CoUninitialize;
end;

end.

ok, jetzt bin ich ein wenig ratlos, kann mir jemand sagen warum der sich nicht beenden lassen soll?

[NormanNG]

Hi,

alle Zugriffe aus dem Thread auf Objekte von fMain müssen synchronisiert erfolgen.

[edit]steht ja sogar auch im Quelltext:

Delphi-Quellcode:

{ Wichtig: Methoden und Eigenschaften von Objekten in visuellen Komponenten dürfen
  nur in einer Methode namens Synchronize aufgerufen werden, z.B.

      Synchronize(UpdateCaption);

  und UpdateCaption könnte folgendermaßen aussehen:

    procedure TDeleteThread.UpdateCaption;
    begin
      Form1.Caption := 'Aktualisiert in einem Thread';
    end; }

[DeddyH]

Hast Du Dir den großen Kommentar mal durchgelesen?

[Centrii]

:wall: ich bin auch der beste :-D

kann ich dann die Anweisungen aus dem Execute in ne extra Procedure schreiben und die synchronisieren?

blöde frage, wirkt sich das dann nicht auch auf ein normales Schließen des Programms aus? :?:

[NormanNG]

Hi,

Zitat:

kann ich dann die Anweisungen aus dem Execute in ne extra Procedure schreiben und die synchronisieren?

Klar, kannst du. Aber dann läuft das alles im Hauptthread ab und damit ist der Thread an sich nutzlos. Alle statischen Werte kannst du dem Thread als Parameter übergeben, alles dynamische muss synchronisiert werden. Damit der Thread aber den Hauptthread nicht bremst, sollte so wenig wie möglich im synchnoize gemacht werden.

[Centrii]

Hi,

habs jetzt hinbekommen, alle Werte aus dem HauptThread übergebe ich im Thread.create.
Soweit auch klar, was ich nicht verstehe ist, das ich im Execute keine AdoConnection erzeugen darf, das geht auch nur im create.
Die war nämlich der Hauptauslöser für mein Problem. Sollte mir das jemand erklären können würde ich mich sehr freuen :-D

Gruß und Danke

Ruben

[generic]

WM_QUERYENDSESSION ist die erste msg die eintriff, welche dafür sorgen soll das alles beendet wird.
Zum Beenden hat das Programm 10 Sekunden.
Danach kommt dann die andere MSG bzw. der harte Abschuss vom System.