GetCommandLine für fremde Anwendung

[ringli]

In meiner eigenen Anwendung kann ich über GetCommandLine den kompletten Kommandozeilenaufruf (also Pfad zur Anwendung inkl. evtl. vorhandener Parameter) erhalten.

Wie kann ich den kompletten Kommandozeilenaufruf für eine fremde Anwendung erhalten deren Fensterhandle ich habe? Ich habe jetzt schon stundenlang hier im Forum und bei Google gesucht, bin aber leider nicht fündig geworden.

[bitsetter]

Hi,

mit Hilfe von der Funktion Windows.GetWindowThreadProcessID() und diesem Code müsste es gehen.

[ringli]

Danke für deine Antwort. Leider scheint der Code nicht zu funktionieren. Die Funktion gibt bei mir leider nur einen leeren String zurück. GetLastError gibt nur 0 (Der Vorgang wurde erfolgreich beendet) zurück.

[bitsetter]

:gruebel: Ich rufe die Funktion so auf:

Delphi-Quellcode:

var
  ProcId : DWORD;
begin
   GetWindowThreadProcessID(..., @ProcId);
   ShowMessage(AufrufParameter(ProcId));

und es wird kein leerer String zurückgegeben.

Was hast du denn eigentlich für ein OS?

[ringli]

Hmmm... genauso hab ich es auch aufgerufen. :gruebel:

Ich habe es hier unter Vista getestet und da geht es definitiv nicht.

Habe aber grade mal Tests in einer VM unter XP und XP64 durchgeführt. Unter XP funktioniert der Code, unter XP64 ist jedoch auch Fehlanzeige.

[OregonGhost]

Klingt so, als _sollte_ das nicht mehr funktionieren. Was passiert, wenn du deine Anwendung unter Vista mit Admin-Rechten startest und die fremde Anwendung mit normalen Rechten?

[ringli]

Funktioniert auch mit Admin-Rechten nicht. Folgendes habe ich ausprobiert:

- Meine Anwendung als Administrator gestartet, fremde Anwendung mit normalen Rechten.
- Meine Anwendung als Administrator gestartet, fremde Anwendung als Administrator gestartet.

[bitsetter]

Was noch gehen könnte wenn man mit Hilfe von Codeinjektion windows.GetCommandLine im fremden Prozess aufruft.

[ringli]

Wie funktioniert das denn mit Codeinjektion? Hast du da zufällig einen Codeschnippsel parat?

[bitsetter]

Parat wohl auch nicht gerade aber ich kann es ja heute mal ausprobieren ob es geht. Ansonsten kannst du mal nach createremotethread suchen.

[ringli]

Dank bitsetter's Hilfe konnte das Problem gelöst werden. :thumb:
Im Anhang die Lösung in Form einer kleinen Demoanwendung. Getestet wurde der Code unter den folgenden Betriebssytemen:

• XP32 --> funktioniert
• Vista32 --> funktioniert
• XP64 --> bei 32bit-Anwendungen funktioniert der Code, bei 64bit-Anwendungen funktioniert der Code allerdings nicht was vermutlich daran liegt das 32Bit-Anwendungen keinen Code in eine 64bit-Anwendung injizieren können. Oder hat jemand diesbezüglich einen anderen Wissensstand?

[iskywalker]

Vielleicht pointer größe?
(statt 32 64)

[wido]

32 Bit Prozesse können keine Remote Threads in 64 Bit Prozessen erstellen. Allerdings gibt es dennoch Möglichkeiten der Code Injection.

Ansonsten würde ich von Code Injection die Finger lassen, wenn immer es geht. Prinzipiell kannst Du allein mit ReadProcessMemory die Command Line auslesen. Bei Interesse, kann ichs Dir mal auscoden. Könnte sein, daß es auch mit 64 Bit Prozessen funktioniert. Habs aber nie probiert, daher keine Ahnung.

[wido]

Ich habs einfach mal ausgecodet. Funktioniert übrigens für 64bit Prozesse leider nicht, da die PebBaseAddress für solche Prozesse nil ist. Evtl. gibts ne 64bit PEB Struktur. Ich werd nachher mal nachschauen. Kommt übrigens wie Du siehst komplett ohne Code Injection aus ;).

Delphi-Quellcode:

program GetCommandLineExDemo;
{$APPTYPE CONSOLE}

uses
  JwaWinBase, JwaNative, JwaWinNt, JwaWinType, JwaPSAPI, JwaNtStatus;

type
  PROCESS_BASIC_INFORMATION = packed record
    ExitStatus:        DWORD;
    PebBaseAddress:    Pointer;
    AffinityMask:      DWORD;
    BasePriority:      DWORD;
    UniqueProcessId:   DWORD;
    InheritedUniquePID:DWORD;
  end;

// Funktioniert nur für Windows NT basierte Systeme
function GetCommandLineEx(PID : DWORD) : widestring;
var
  ProcessHandle     : THandle;
  ProcessBasicInfo  : PROCESS_BASIC_INFORMATION;
  PEB               : _PEB_W2K;
  ProcessParameters : RTL_USER_PROCESS_PARAMETERS;
  ReturnLength      : DWORD;
  CommandLine       : PWideChar;
begin
  result := '';
  ProcessHandle := OpenProcess(PROCESS_QUERY_INFORMATION or PROCESS_VM_READ, false, PID);
  if ProcessHandle <> 0 then
    begin
      // Schritt 1: Wir holen uns die PROCESS_BASIC_INFORMATION um den PEB zu lokalisieren
      if (NtQueryInformationProcess(ProcessHandle, ProcessBasicInformation, @ProcessBasicInfo, SizeOf(ProcessBasicInfo), @ReturnLength) = STATUS_SUCCESS) and (ReturnLength = SizeOf(ProcessBasicInfo)) then
        // Schritt 2: Wir lesen den PEB aus
        if ReadProcessMemory(ProcessHandle, ProcessBasicInfo.PebBaseAddress, @PEB, SizeOf(PEB), @ReturnLength) and (ReturnLength = SizeOf(PEB)) then
          // Schritt 3: Wir lesen die ProcessParameters aus
          if ReadProcessMemory(ProcessHandle, PEB.ProcessParameters, @ProcessParameters, SizeOf(ProcessParameters), @ReturnLength) and (ReturnLength = SizeOf(ProcessParameters)) then
            begin
              // Schritt 4: Wir lesen die Command Line aus
              GetMem(CommandLine, (ProcessParameters.CommandLine.Length + 1) * 2);
              if ReadProcessMemory(ProcessHandle, ProcessParameters.CommandLine.Buffer, CommandLine, ProcessParameters.CommandLine.Length * 2, @ReturnLength) then
                result := WideString(CommandLine);
              FreeMem(CommandLine);
            end;
      CloseHandle(ProcessHandle);
    end;
end;

var
  PIDs   : array[0..1000] of DWORD;
  Needed : DWORD;
  i      : Integer;
begin
  EnumProcesses(@PIDs[0], 1001, Needed);
  for i := 0 to (Needed div 4) - 1 do
    writeln(PIDs[i], ' --> ', GetCommandLineEx(PIDs[i]));
  readln;
end.