Memo Inhalt in einem Stream abspeichern

[Nastarowje]

Hallo alle zusammen.

Ich mache mir gerade ein kleines Adressbuch.

Hier gibts die EditFelder Name, Vorname, Geburtstag usw. Außerdem gibts eine Memokomponente für Notizen.

Nun mein Problem, prinzipiell kann ich alle Editfelder in einem Stream ablegen. Das klappt hervorragend.

Wie aber speicher ich das Memo im selben Stream?
Ich benutze keine Records.

Ich speicher einfach nur meine Kontakte in ein Stringgrid und speichere die Inhalte dann in einer Datei. Die Strings kann ich größentechnisch begrenzen, so das ich immer die selbe Länge beim Speichern und demzufolge auch beim Laden kann. Beim Memo kann / will ich das nicht. Hat jeman eine Idee, wie ich das realisieren kann?



Vielen Dank

[marabu]

Herzlich willkommen in der Delphi-PRAXiS, Nastarowje.

Das Speichern ist genauso einfach wie bei einem Edit-Feld, das Memo besteht ja aus Lines[], auf die du mit einem Zeilenindex zugreifen kannst. Wichtig ist, dass du dir ein gescheites Speicherformat ausdenkst. Adressbuch-Einträge würde ich im Format VCARD speichern.

Freundliche Grüße vom marabu

[Nastarowje]

Also muss ich Zeile für Zeile das Memo abspeichern?

[alleinherrscher]

Zitat:

Also muss ich Zeile für Zeile das Memo abspeichern?

Ne, nimm einfach:

Delphi-Quellcode:

Memo1.text

//edit: Stimmt, Klaus01 Idee is noch besser...

[Klaus01]

Zitat:

Zitat von Nastarowje

Also muss ich Zeile für Zeile das Memo abspeichern?

Guten Morgen,

nein nicht einzeln.

Delphi-Quellcode:

memo1.lines.SaveToStream({dein Stream});

Grüße
Klaus

[Nastarowje]

achso -

also ungefähr so (Syntax wurde nur grob beachtet):

Block Beginn

Stream.erzeugen

stream.write(PChar(NameEdit)^, SizeOf(NameEdit.text));
Notiz.lines.savetostream(stream);

stream.freigeben;


BlockEnde


werde es gleich mal probieren

[Klaus01]

Zitat:

Block Beginn

Stream.erzeugen

stream.write(PChar(NameEdit)^, SizeOf(NameEdit.text)+1);
Notiz.lines.savetostream(stream);

stream.freigeben;


BlockEnde

Zum Abspeichern sollte es ungefähr so gehen.
Nur wie willst Du es wieder auslesen, wenn Du nicht weißt wie lang Dein Editfeld ist?


Grüße
Klaus

[Nastarowje]

So,

habe es jetzt so realisiert :

Delphi-Quellcode:

procedure AdressSave;
var StringLength : integer;      // Abspeichern der Länge des zu speichernden Streams
Begin
  AdressStream := TFileStream.Create('C:\Dokumente und Einstellungen\Michael\Desktop\Test.db',fmCreate);

    // Anrede speichern
    StringLength := Length(Form1.KAnrede.Text);
    AdressStream.Write(StringLength,SizeOf(StringLength));
    AdressStream.Write(PChar(Form1.KAnrede.Text)^,StringLength);

    // Notizen speichern
    Form1.KNotizen.Lines.SaveToStream(AdressStream);

    // Name speichern
    StringLength := Length(Form1.KName.Text);
    AdressStream.Write(StringLength,SizeOf(StringLength));
    AdressStream.Write(PChar(Form1.KName.Text)^,StringLength);

  AdressStream.Free;
End;



{---------------------------- Adressdaten laden -------------------------------}
procedure AdressLoad;
var StringLength : integer;       // Länge des Strings
    ZwischenString : string;      // Der String wird hier zwischengespeichert
Begin
  AdressStream := TFileStream.Create('C:\Dokumente und Einstellungen\Michael\Desktop\Test.db',fmOpenRead);

    // Anrede laden
    AdressStream.Read(StringLength,SizeOf(StringLength));
    //ShowMessage(IntToStr(StringLength));
    SetLength(ZwischenString,StringLength);
    AdressStream.Read(PChar(ZwischenString)^,StringLength);
    Form1.KAnrede.Text := ZwischenString;

    // Notizen laden
    Form1.KNotizen.Lines.LoadFromStream(KundenStream);

    // Name laden
    AdressStream.Read(StringLength,SizeOf(StringLength));
    //ShowMessage(IntToStr(StringLength));
    SetLength(Zwischenstring,StringLength);
    AdressStream.Read(PChar(ZwischenString)^,StringLength);
    Form1.KName.Text := ZwischenString;

  KundenStream.Free;
End;

Das Abspeichern funktioniert problemlos. Es wird die Länge vor den Stream gespeichert, um den Stream dann besser auslesen zu können.

Beim Laden funktionierts bis zu den Notizen. Hier trägt er alles in die Edit und Memofelder richtig ein. Im Namenfeld steht dann aber wieder die Anrede drin. (Die Reihenfolge des speicherns und ladens wurde bewusst so gewählt.)

[Klaus01]

Zitat:

Beim Laden funktionierts bis zu den Notizen. Hier trägt er alles in die Edit und Memofelder richtig ein. Im Namenfeld steht dann aber wieder die Anrede drin. (Die Reihenfolge des speicherns und ladens wurde bewusst so gewählt.)

Hallo,

meine Delphi Hilfe sagt dazu:

Zitat:

Zitat von DelphiHilfe

If the stream is a file stream, LoadFromStream does the same thing as LoadFromFile, except the application must create and destroy the file stream.

Daraus läßt sich schliessen, dass LoadFromStream immer bei Position 0 anfängt die Datei einzulesen.
Eventuell mußt Du vorher die Notizen in einen MemoryStream einlesen und diesen
dann dem TMemo übergeben.

Grüße
Klaus

[DP-Maintenance]

Dieses Thema wurde von "sakura" von "Programmieren allgemein" nach "VCL / WinForms / Controls" verschoben.

[Nastarowje]

Also bei POS 0 fängt der nicht an, da ich vornedran einen String eingelesen habe. Diese Konstellation funktioniert, er hält so auch die Reiehnfolge ein. Sobal ich aber 2 Memos hintereinander habe, dann läd er das 2te Memo mit.

Sobald ich nach einem Memo noch einen String habe, wird dieser nicht mitgelesen.



Hmmmm,

kann doch nicht so schwer sein :?

[Apollonius]

LoadFromStream liest alles bis zum Ende. Gehe doch einfach den selben Weg wie mit den Edits und speichere die Länge.

[marabu]

Hallo Michael,

LoadFromStream() liest von der aktuellen Position bis zum Ende des Streams. Du siehst nicht alles in deinem Memo, weil die internen Funktionen zur String-Verarbeitung beim Auftreten des ersten Zero Byte das Ende des Textes annehmen.

Möchtest du den Umgang mit Streams üben oder geht es wirklich ums Speichern von Adressdaten?

Im ersten Fall speichere wie schon beim Edit-Feld die Länge der Notizen im Stream. Im letzten Fall informiere dich über ein Standardformat, welches auch andere Adressbuchprogramme verstehen - VCARD:

Code:

BEGIN:VCARD
VERSION:2.1
N:Surname;GivenName
FN;QUOTED-PRINTABLE:GivenName Surname
TEL;HOME;VOICE:[phone]
TEL;CELL;VOICE:[phone]
EMAIL;PREF;INTERNET:[e-mail]
BDAY:1918-12-06
NOTE;QUOTED-PRINTABLE:This=0D=0Ais =0D=0Aa=0D=0Amulti-line=0D=0Anote
END:VCARD

Freundliche Grüße

[Nastarowje]

Eigentlich möchte ich die Streams austesten und alles mögliche üben. Habe sonst immer alles mit Mysql gemacht. Jetzt sind eigene Format dran :-)

Ich will auf alle Fälle ein eigenes Format erstellen.

Wie kann ich die Länge eines Memos bestimmen?

[Keldorn]

Hallo,

ich würde über Treader/Twrioter gehen, wenn du daten in den stream laden/speichern willst. Dort sind schon routinen für strings, integers etc dabei, über irgendwelchen Längenangaben brauchst du dir keinen Kopf zerbrechen.

als Bsp:

Delphi-Quellcode:

procedure TForm1.ButtonSpeichernClick(Sender: TObject);  
Var Stream:TFilestream;  
begin  
  Stream:=TFileStream.Create('D:\TestStream',fmcreate);  
  try  
    //TWriter objekt erstellen und Daten in den Stream speichern  
    with TWriter.create(Stream,1024) do  
      try  
        WriteString(Memo1.Text);  
        WriteString(Edit1.Text);  
        WriteInteger(SpinEdit1.Value);  
        WriteBoolean(CheckBox1.Checked);  
      finally  
        free;  
      end;  
   finally  
     Stream.free;  
   end;  
end;  

 
procedure TForm1.ButtonLadenClick(Sender: TObject);  
Var Stream:TFilestream;  
begin  
  Stream:=TFileStream.Create('D:\TestStream',fmOpenRead   or fmShareDenyNone);  
  try  
    //TReader objekt erstellen und Daten aus den Stream laden  
    with TReader.create(Stream,1024) do  
      try  
        Memo1.Text        := ReadString;  
        Edit1.Text        := ReadString;  
        SpinEdit1.Value   := ReadInteger;  
        CheckBox1.Checked := ReadBoolean;  
      finally  
        free;  
      end;  
   finally  
     Stream.free;  
   end;  
end;

Gruß Frank

[Nastarowje]

Das hört sich vielversprechend an,

Wofür brauche ich die 1024 im create des Streams? Ist die Größe des Puffers variabel?




Vielen Dank
Michael

[Keldorn]

Zitat:

Zitat von Nastarowje

Wofür brauche ich die 1024 im create des Streams? Ist die Größe des Puffers variabel?

ich weiß es nich :oops: .

Irgendwo in der DP gabs mal einen Thread zu optimalen Puffergröße, ich hab ihn aber nich wieder gefunden.

Du kannst dir so auch ein komplexen Dateiformat aufbauen, jedes Klasse hat eine saveto/loadfromstream-methode. Das sind bei mir in einem konkretem Fall recht viele. Ich hatte dort mal bissel mit der Puffergröße experimentiert, zeitliche Unterschiede waren zwar messbar, aber vernachlässigbar.

Gruß Frank

[Nastarowje]

Boh das ist ja richtig geil, das funktioniert tadellos.

Wo bekommt man solche Infos her?



Suppi

Ich danke dir

Michael