String in Stream speichern

[d1ng0d0gt0r]

Moinsen,

Ich möchte einen String in einem Stream speichern. Dazu hab ich mir jetzt etliche Tutorials angesehen, doch irgendetwas mache ich falsch.

Folgenden Code den ich geschrieben habe, möchte ich verwenden um einen beliebigen String (S) in einem Stream (Stream) zu speichern.

Delphi-Quellcode:

procedure TForm1.Button3Click(Sender: TObject);
var
  Stream: TStream;
  S:      String;
  N:      LongInt;
begin

S:= Edit1.Text;
N:= Length(S);

  if N > 0 then
  begin
    Stream:= TStream.Create;
    Stream.Write(N, SizeOf(N));
    Stream.Write(S[1], N);
  end;
//...                            // Stream über Socket versenden.
Stream.Free;
end;

Spätestens bei "Stream.Write(N, SizeOf(N));" bringt er mir den Fehler:

Zitat:

Erste Gelegenheit für Exception bei $75B83843. Exception-Klasse EAbstractError mit Meldung 'Abstract Error'. Prozess Project1.exe (2368)

Gruß

[Corpsman]

ich mach das immer mit

Delphi-Quellcode:

var
c:Char;
s:String;
i:Integer;
begin
  i := length(s);
  Stream.write(i,sizeof(i));
  for i := 1 to length(s) do begin
    c := s[i];
    stream.write(c,sizeof(c));
  end;
end;

[Luckie]

TStream ist eine abstrakte Klasse, deren Mthoden nicht implementiert sind. Benutze eine abgeleitete Klasse, die die Methoden implementiert, wie TMemoryStream oder TFileStream.

[sirius]

Oder TStringStream ;)

[Chemiker]

Hallo d1ng0d0gt0r,

was für ein Name.

Ich habe zufällig heute einen neuen Urlaubsplan gemacht und musste dafür die Daten aus einem StringGrid abspeichern.

Erst mal abspeichern:

Delphi-Quellcode:

procedure TMainFormUrlausPlaner.FileSaveAs1Accept(Sender: TObject);
var
  DateiName: TFileName;
  i, y : integer;
  f: TFileStream;
  buff: String;
  len: Word;
begin
  DateiName:= FileSaveAs1.Dialog.FileName;
  f:= TFileStream.Create(DateiName,fmCreate or fmOpenWrite);
  try
    if FileExists(DateiName) then
    begin
    // Speichern des StringGrid - Daten
      for I := 0 to coTage  do
      begin
        for y := 0 to coMitarbeiterAnzahl do
        begin
          buff:= strGridJahr.cells[i,y];
          len:= length(buff);
          f.WriteBuffer(len,SizeOF(Word));
          f.WriteBuffer(buff[1],len);
        end;
      end;
    end;
   finally
     f.free;
  end;
end;

Und jetzt die Daten wieder laden:

Delphi-Quellcode:

procedure TMainFormUrlausPlaner.FileOpen1Accept(Sender: TObject);
var
  DateiName: TFileName;
  i, y : integer;
  f: TFileStream;
  buff: String;
  len: word;
begin
  DateiName:= FileOpen1.Dialog.FileName;
  f:= TFileStream.Create(DateiName,fmOpenRead);
  try
    if FileExists(DateiName) then
    begin
       for I := 0 to coTage  do
       begin
         for y := 0 to coMitarbeiterAnzahl do
         begin
           f.ReadBuffer(len, SizeOf(Word));
           SetLength(buff,len);
           f.ReadBuffer(buff[1], len);
           strGridJahr.cells[i,y]:= buff;
         end;
       end;
    end;
  finally
    f.Free
  end;

end;

Vielleicht kannst Du da was mit anfangen.

Bis bald Chemiker

[d1ng0d0gt0r]

Ich danke für die schnellen Antworten!

^^Der Name entstammt noch den alten LeetSpeak Zeiten.
Mittlerweile kennen mich, einige, gewisse Leute, ganz gut unter dem Namen.
Naja und Nick's wechelt man ungern wenn man sich damit schon einen Namen verschafft hat.
Wenn auch nicht als Programmierer :).

[d1ng0d0gt0r]

Arrrrrrrrrrrrrrrrr.....

Folgender Code führt bei mir zu einem leeren String.

Delphi-Quellcode:

procedure TForm1.Button3Click(Sender: TObject);
var
  Stream: TMemoryStream;
  S:      String;
  S_S:    String;
  N:      LongInt;
begin

S:= Edit1.Text;
N:= Length(S);

  if N > 0 then
  begin
    // Stream -> String  String -> Stream
    Stream:= TMemoryStream.Create;
    Stream.Write(N, SizeOf(N));
    Stream.Write(S[1], N);

    // Stream -> String
    Stream.Read(S_S[1], Length(S_S));
  end;

  MessageBox(0, pchar(S_S), 'title', MB_OK);

end;

Isch versteh des net!

[Muetze1]

Wie wäre es denn den Dateizeiger wieder auf den Anfang der Datei zu setzen?

[Apollonius]

Erstens musst du die Stream-Position vor dem Lesen wieder auf Null setzen. Zweitens solltest du dir mal überlegen, warum du eigentlich N abgespeichert hast, wenn du es nicht ausliest.

[d1ng0d0gt0r]

Jetzt haut er mir nen Error raus.

Delphi-Quellcode:

procedure TForm1.Button3Click(Sender: TObject);
var
  S:      String;
  S_S:    String;
  N:      LongInt;
begin

S:= Edit1.Text;
N:= Length(S);

  if N > 0 then
  begin
    // Stream -> String
    Stream:= TMemoryStream.Create;
    Stream.Write(S[1], N));

    //Stream -> String
    Stream.Position:= 0;
    Stream.Read(S_S[1], N);
  end;

  Stream.SaveToFile(ExtractFilePath(Paramstr(0))+'test.txt');

  if Client.Socket.SendStream(Stream) then
    MessageBox(0, pchar(S_S), 'title', MB_OK);

end;

Noch nie mit Pointern gearbeitet, ich lern Delphi seit 2 Wochen-.-

[wicht]

Hi,

Zitat:

Zweitens solltest du dir mal überlegen, warum du eigentlich N abgespeichert hast, wenn du es nicht ausliest.

:wink: Also.. mehr so:

Delphi-Quellcode:

var
  len: integer;
  s: string
begin
  stream.read(len, sizeof(integer));   <<<----
  setlength(s, len);   <<<----
  stream.read(s[1], len);
end;

[d1ng0d0gt0r]

Danke so gehts. :love:
Übung macht den Meister.

[WS1976]

Hallo,

Ich würde folgende Änderung vorschlagen:
um die Länge des Strings nicht zwischenspeichern zu müssen (fürs zurücklesen) benutze einfach: Stream.Size für die Länge des Strings.
Das ist zwar die Gesamtlänge des Streams aber so bist du immer auf der sicheren Seite. In deinem Beispiel war die Länge immer = 0, deshalb der Empfangsstring leer.

Ans Ende des Codes gehört:
stream.free;
bitte nicht vergessen.

hier der geänderte Code:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var 
  Stream: TMemoryStream; 
  S:      String; 
  S_S:    String; 
  N:      LongInt; 
begin

S:= Edit1.Text; 
N:= Length(S); 

  if N > 0 then 
  begin 
    // Stream -> String  String -> Stream 
    Stream:= TMemoryStream.Create; 
//    Stream.Write(N, SizeOf(N));
    Stream.Write(S, N); 

    // Stream -> String
    Stream.Position:= 0;
    Stream.read(S_S,Stream.Size);
  end; 

  MessageBox(0, pchar(S_S), 'title', MB_OK);
  stream.free;
end;

Grüsse
Rainer

[alzaimar]

Ich hab mir das hier in meine Toolsammlung geschmissen.

Delphi-Quellcode:

Procedure WriteString (aStream : TStream; Const aString : String);
Var
  iLength : Integer;

Begin
  iLength := Length(aString);
  aStream.WriteBuffer(iLength, SizeOf(iLength));
  aStream.Write(Pchar(aString )^, iLength);
End;

Function ReadString (aStream : TSream);
Var
  iLength : Integer;

Begin
  aStream.ReadBuffer(iLength, SizeOf(iLength));
  SetString(Result, PChar(nil), iLength);
  aStream.ReadBuffer(Pointer(Result)^, iLength);
End;

Heute würde man das mit einem Class Helper erledigen, der die TStream-Klasse erweitert.

[Muetze1]

@WS1976:

- Wenn er den Stream per Socket verschickt (wie er es oben schon macht), dann weiss er ohne die Längenangabe wann der String komplett empfangen wurde.
- Dein Code gibt beim Schreiben wie auch beim Lesen den String direkt an und nicht das erste Zeichen mit [1], somit ist bei deinem Code wieder das Ausgangsproblem des Threads enthalten.
- Auch du setzt vor dem Auslesen in einen anderen String nicht dessen Länge und zerhackst dir damit deftig den Speicher.

Grüße,
Thomas