Edit-Felder während der Laufzeit erstellen... wie?

[tiller]

Hallöchen!

Ich würde gerne anhand einiger Angaben, die der Anwender in meinem Programm machen kann, eine sich daraus ergebende Anzahl an Edit-Feldern an bestimmten Stellen meines Formulars erstellen. Kann mir jemand sagen, wie das funktioniert. Kann leider die Hilfe nicht aufrufen, da diese unter Vista nicht funktioniert.

Gruß, tiller

[sirius]

Delphi-Quellcode:

Editx:=TEdit.create(owner) //owner kann das Formular sein, eine andere Komponente oder nil
//wenn owner gelöscht wird, dann wird auch dein Edit automatisch mit gelöscht
Editx.left:=...
Editx.right:=...
//usw usf.
//Ereignisse legsst du genauso fest; zuweisen tust du eben eine Methode die die entsprechende Deklaration hat

[mkinzler]

Wenn die Komponente sichtbar sein soll fehlt noch der Parent:

Delphi-Quellcode:

Editx.parent := <Parent>;

[tiller]

Bekomme die Meldung: "undefinierter Bezeichner: 'editx'"
Kann sein, dass ich mich blöd dranstelle, ihr könnt mir bestimmt sagen, was ich falsch mach :-)

[mkinzler]

War auch nur ein Platzhalter für die Instanzvariable.

Kannst natürlich auch auf eine verichten:

Delphi-Quellcode:

with TEdit.create(owner) do
begin
    Parent := self;
    Left := ...
    Top := ...
   //usw usf.
end;

[sirius]

Ja, EditX ist ein Zeiger auf das Objekt. (Das ist ein Beispiel und nicht zum kopieren gedacht; Wie auch? ich kenne ja dein Programm nicht)

Und denn solltest du an geeigneter Stelle aml als TEdit deklarieren. Aber wo das für dich ist, weis ich nicht. Wenn du mehrere TEdits erstellen willst, würde ich über eine TObjectList nachdenken:

Delphi-Quellcode:

type Form1=class(TForm)
      ...
      myEdits:TObjectList //an geeigneter Stelle erstellen

procedure createEdits;
var Edit:TEdit;
begin
  Edit:=TEdit.create(self);
  Edit.parent:=self;
  Edit.top:=10;
  Edit.left:=100;
  ...
  myEdits.add(Edit);
end;

Nur ein Beispiel.

[tiller]

Danke für eure Hilfe, es hat jetzt geklappt!
Die Edits werden doch einfach durchnummeriert beim generieren oder?

[sirius]

Nö.
Kommt drauf an, was du gemacht hast.

[mkinzler]

Wenn du dies so als namen bei der Erzeugung angibst, ja.

[tiller]

Ja, das mit der Namensgebung funzt ganz gut so. Könnt ihr mir sagen, wie ich mein Programm resetten kann? Also auf Knopfdruck einfach neu starten; jedes Edit einzeln löschen ist nämlich eher unnötig...

[API]

Zitat:

Zitat von tiller

Ja, das mit der Namensgebung funzt ganz gut so. Könnt ihr mir sagen, wie ich mein Programm resetten kann? Also auf
Knopfdruck einfach neu starten; jedes Edit einzeln löschen ist nämlich eher unnötig...

Hallo, so kannst du alle Edits löschen:

Delphi-Quellcode:

var 
  i: Word; 
  cmp: TComponent; 
  Ed: TEdit; 
begin 
  for i := 0 to ComponentCount - 1 do 
  begin 
    cmp := Components[i]; 
    if cmp is TEdit then begin 
      Ed := (cmp as TEdit); 
      Ed.Clear;
    end; 
  end;

[tiller]

Hi API,

das Ganze funktioniert leider nicht so wie es soll :-) Bei dieser Prozedur werden lediglich die Eingaben der Edits gelöscht, allerdings nur die derjenigen, die bereits im Formular erstellt wurden, bevor das Programm gestartet wurde, die derjenigen, die ich während der Laufzeit generiert habe, bleiben erhalten :?:

[Helmi]

Hallo,

Zitat:

Zitat von tiller

Kann leider die Hilfe nicht aufrufen, da diese unter Vista nicht funktioniert.

auch wenns offtopic ist, aber hier gibts die alte WinHelp32-Version für Vista zum download

[tiller]

Helmi, danke für den Link, das kann ich gut gebrauchen :-)
Kann mit jemand sagen, wie ich ein Programm resetten kann? Der Vorschlag von API funktioniert leider nicht.

[mkinzler]

Einfach den Owner freigeben.

[dominikkv]

versuch mal beim Create das Formular als Owner an zugeben.

[tiller]

Delphi-Quellcode:

with TEdit.create(owner) do
          begin
            Parent:=self;
            ...
          end;

Hab die Edits so erzeugt. Wie geb ich denn den Besitzer frei? Hier ist das doch Form1 (mein Formular) oder? Geht das überhaupt?

[mkinzler]

Zitat:

Hier ist das doch Form1

Ja.

Zitat:

Geht das überhaupt?

Warum sollte das nicht gehen?
Oder erzeuge ein panel, welches du als Owner für die Edits nimmst und gebe dann das frei.

[tiller]

Zitat:

Zitat von tiller

Wie geb ich denn den Besitzer frei?

[mkinzler]

Delphi-Quellcode:

<Kompo>.Free;

[tiller]

Hab deinen Rat befolgt und ein Panel als Owner deklariert. Dieses kann ich auch freigeben und die Edits löschen aber was mache ich wenn ich nochmal Edits erzeugt habe und diese wiederum löschen will? Mein Panel existiert ja dann nicht mehr.

[mkinzler]

Vor dem Erzeugen neuer Edits wieder ein Panel erzeugen.

[tiller]

Ok, hab's jetzt so gemacht. Panel wird freigegeben und Edits gelöscht (Panel bereits vor Laufzeit erstellt). Neues Panel wird erstellt (gleicher Name wie zuvor), Edits generiert. Will ich nun wiederum dieses generierte Panel freigeben um die Edits zu löschen, bekomme ich die Meldung, dass bereits eine Komponente mit dem Namen Panel1 existiert.

Löscht der Befehl

Delphi-Quellcode:

Panel1.free

dieses nicht vollständig? Wieso klappt das Ganze genau ein Mal?

[mkinzler]

Versuch es mal mit

Delphi-Quellcode:

FreeAndNil( Panel1);

[tiller]

Funktioniert leider auch nicht, bekomme die gleiche Fehlermeldung...

[sirius]

Ich glaube durch die Tipps und mit deinen noch etwas lückenhaften Kentnissen ist jetzt totales Chaos in deinen Code gekommen.
Vielleicht solltest du mal genauer erklären, was du machst. Wo kommen die Edits hin, wann erstellst du sie, wann löschst du sie.
Wahrscheinlich muss man die Edits besser in eine Liste packen.

Edit: Und gibt es noch andere Komponenten, die mit dem Löschen der Edits auch gelöscht werden (z.B. ein Formular, ein Panel). Denn extra dafür ein Panel zu erstellen ist nicht wirklich sinnvoll.

[tiller]

Ein wahres Wort, sirius :-)

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Edit1: TEdit;
    Edit2: TEdit;
    Label1: TLabel;
    Label2: TLabel;
    Button2: TButton;
    Button3: TButton;
    label_error: TLabel;
    Panel1: TPanel;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

type TMatrix = array[1..10, 1..10] of Real;

var rows, lines, i, j: integer;

procedure TForm1.FormCreate(Sender: TObject);
begin
Form1.width:=368;
Form1.Height:=95;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
rows:=strtoint(edit1.text);
lines:=strtoint(edit2.Text);
if ((lines>10) or (rows>10)) then label_error.Caption:='Matrix ist auf eine Größe von 10,10 limitiert. Eingaben wurden korrigiert.';
if rows>10 then
  begin
    edit1.text:='10';
    rows:=10;
  end;
if lines>10 then
  begin
    edit2.text:='10';
    lines:=10;
  end;
if rows>4 then Form1.width:=25+(rows+1)*(57+8);
Form1.Height:=110+lines*(21+8)-8;
for i:=1 to lines do
  begin
    for j:=1 to rows do
      begin
        with TEdit.create(Panel1) do  //vorher 'owner' -> Form1
          begin
            Parent:=self;
            Left:=16+(j-1)*64;
            Top:=72+(i-1)*24;
            width:=57;
            Name:='e'+inttostr(j)+inttostr(i);
            //caption:='';
          end;
      end;
    with TEdit.create(Panel1) do
      begin
        Parent:=self;
        Left:=16+(j-1)*64;
        Top:=72+(i-1)*24;
        width:=57;
        Name:='l'+inttostr(i);
        //caption:='';
      end;
  end;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
label_error.caption:='';
FreeAndNil(Panel1);
with TPanel.create(owner) do
  begin
    Parent:=self;
    Left:=280;
    Top:=40;
    width:=57;
    height:=25;
    Name:='Panel1';
    visible:=false;
  end;
end;

procedure TForm1.Button3Click(Sender: TObject);
begin
label_error.Caption:='';
end;

end.

Hier mal der komplette Code. Das Ganze soll ein LGS nach dem Gaußschen Algorithmus lösen, allerdings Schritt für Schritt.

Button1 erzeugt die Matrix und den Lösungsvektor, Button2 soll das Programm resetten und Button 3 wird später immer einen Lösungsschritt durchführen.

[sirius]

So, ich habe mal den wichtigen Änderungen gemacht. Sieht aber sonst sehr gut aus ;)

Deine Edits werden alle erstellt und in einer Liste gespeichert/verwaltet (EditList)

Delphi-Quellcode:

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Contnrs; //Unit hinzugefügt für die Liste

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Edit1: TEdit;
    Edit2: TEdit;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private-Deklarationen }
    lines,rows:integer;  //Die Variablen gehören zur Form (nicht global)
    EditList:TComponentList;
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  EditList:=TComponentList.create;
  EditList.OwnsObjects:=true; //wird dadurch Komponenten und Inhalt zusammen löschen

  Width:=368; //nicht auf die Form1-Variable zugreifen
  Height:=95; //kann man auch im OI einstellen
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  EditList.Free;
end;

procedure TForm1.Button1Click(Sender: TObject);
var Edit:TEdit;
    i,j:integer;
begin
  if (trystrtoint(edit1.Text,rows))and(trystrtoint(edit2.Text,lines))and
     (rows>0)and(lines>0) then
  begin
    if rows>10 then rows:=10;
    if lines>10 then lines:=10;
    Editlist.Clear; //Liste und alle Edits löschen

    if rows>4 then Width:=25+(rows+1)*(57+8);
    Height:=110+lines*(21+8)-8;


    for i:=1 to lines do
    begin
      for j:=1 to rows do
      begin
        Edit:=TEdit.Create(self);
        EditList.Add(Edit);
        with Edit do
        begin
          Parent:=self;
          Left:=16+(j-1)*64;
          Top:=72+(i-1)*24;
          width:=57;
          Name:='e'+inttostr(j)+inttostr(i);
          //caption:='';
        end;
      end;
      Edit:=TEdit.Create(self);
      EditList.Add(Edit);
      with Edit do
      begin
        Parent:=self;
        Left:=16+(rows-1)*64;
        Top:=72+(i-1)*24;
        width:=57;
        Name:='l'+inttostr(i);
        //caption:='';
      end;
    end;
  end;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  EditList.Clear;
end;

Da die Edits als Owner jetzt das Formular haben (self), kannst du sie über FindComponent im Formular finden, oder du gehst die Liste durch. Beispiel: "TEdit(EditList[x]).caption....."

[tiller]

Danke für deine tatkräftige Hilfe. Habe das Programm insofern abgeändert, dass nun nur noch symmetrische Matrizen erzeugt werden können. Außerdem habe ich für die Labels, in die ich nachher die Lösungen eintragen will, ebenfalls eine Liste erzeugt, alles andere habe ich Analog gemacht.
Funktioniert auch alle super, aber nachdem ich resettet habe (Button2) und daraufhin eine neue Matrix erstellen will, bekomme ich weiterhin eine Fehlermeldung. Diesmal warnt diese vor einer Zugriffsverletzung. Kannst du dir das erklären? Hier nochmal der editierte Code:

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Contnrs, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Edit1: TEdit;
    Label2: TLabel;
    label_error: TLabel;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
  private
    { Private-Deklarationen }
    n: integer;
    EditList: TComponentList;
    LabelList: TComponentList;
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

type TMatrix = array[1..10, 1..10] of Real;

var n: integer;

procedure TForm1.FormCreate(Sender: TObject);
begin
  EditList:=TComponentList.create;
  EditList.OwnsObjects:=true;
  LabelList:=TComponentList.create;
  LabelList.OwnsObjects:=true;
  Width:=368;
  Height:=95;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  EditList.Free;
  LabelList.Free;
end;

procedure TForm1.Button1Click(Sender: TObject);
var Edit: TEdit;
    Label_: TLabel;
    i, j: integer;
begin
  n:=strtoint(edit1.text);
  if (trystrtoint(edit1.Text,n))and (n>0) then
  begin
    if n>10 then
    begin
      n:=10;
      edit1.Text:='10';
      label_error.Caption:='Matrix ist auf eine Größe von 10,10 limitiert. Eingaben wurden korrigiert.';
    end;
    Editlist.Clear;
    LabelList.Clear;

    if n>4 then Width:=25+(n+1)*(57+8);
    Height:=110+n*49-8;

    for i:=1 to n do
    begin
      for j:=1 to n do
      begin
        Edit:=TEdit.Create(self);
        EditList.Add(Edit);
        with Edit do
        begin
          Parent:=self;
          Left:=16+(j-1)*64;
          Top:=72+(i-1)*24;
          width:=57;
          Name:='e'+inttostr(j)+inttostr(i);
          //text:='';
        end;
      end;
      Edit:=TEdit.Create(self);
      EditList.Add(Edit);
      with Edit do
      begin
        Parent:=self;
        Left:=16+(j-1)*64;
        Top:=72+(i-1)*24;
        width:=57;
        Name:='l'+inttostr(i);
        //text:='';
      end;
    end;
    for i:=1 to n do
    begin
      Label_:=TLabel.Create(self);
      LabelList.Add(Label_);
      with Label_ do
      begin
        Parent:=self;
        Left:=16;
        Top:=72+n*(27)+(i-1)*(20);
        Name:='label_l'+inttostr(i);
        caption:='v'+inttostr(i)+' = ';
      end;
    end;
  end;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  label_error.caption:='';
  EditList.Free;
  LabelList.Free;
end;

procedure TForm1.Button3Click(Sender: TObject);
var step, steps: integer;
begin
label_error.Caption:='';
steps:=n-1;
end;

end.

http://home.arcor.de/highlaenden/error.jpg

[sirius]

Ja. Das liegt daran, dass du bei Button2 die Liste aus dem Speicher löschst. Nutze Clear in Button2click
-Free löscht die Komplette Liste und du müsstest wieder create aufrufen, um die Liste zu erstellen
-Clear löscht nur den Inhalt der Liste und du kannst problemlos neue Elemente der Liste hinzufügen.

Das Konzept ist, dass ich/du diese Liste mit dem Formular erstelle und wenn das Formular gelöscht wird auch die Liste wieder lösche (free). Unabhängig davon kann ich aber immer den Inhalt der Liste löschen (clear) und die Liste dann wieder neu füllen. Das Clear mache ich ja auch in Button1click, falls jemand vergessen hat Button2 vorher zu drücken. Und falls die Liste schon leer war, passiert eben nix.

Noch etwas:

Delphi-Quellcode:

n:=strtoint(edit1.text); 
  if (trystrtoint(edit1.Text,n))and (n>0) then

Das ist doppelt. Ich habe nur aus dem strtoint ein trystrtoint gemacht, weil dadurch kein Fehler auftritt, wenn keine Zahl im Edit steht. Denn dann liefert trystrtoint false zurück und die IF-Bedingung ist nicht erfüllt. Schau dir mal die Hilfe dazu an.

Noch ein weiteres:

Delphi-Quellcode:

with Edit do 
begin 
  Parent:=self; 
  Left:=16+(j-1)*64; 
  Top:=72+(i-1)*24; 
  width:=57; 
  Name:='e'+inttostr(j)+inttostr(i); 
  //text:=''; 
end; 

//geht auch so:
Edit.Parent:=self; 
Edit.Left:=16+(j-1)*64; 
Edit.Top:=72+(i-1)*24; 
Edit.width:=57; 
Edit.Name:='e'+inttostr(j)+inttostr(i); 
//Edit.text:='';

Es gibt Programmierer (ich auch) die mögen das with nicht, da besonders, wenn es länger wird eine gewisse Unübersichtlichkeit entstehen kann. Deswegen hatte ich die Variable Edit eingeführt, aber es nicht konsequent durchgezogen (Copy&Paste ging schneller). Ich wollte es nur noch einmal erwähnen ;)

[tiller]

Achja, das hab ich garnicht gemerkt, hab's wohl falsch abgetippt... ich danke dir!
Eine letzte Frage hätte ich da noch :-) Meine Edits sind ja nach ihren Koordinaten in der Matrix benannt; ich will nun in einer for Schleife vom Schleifenindex abhängige Komponenten aufrufen, kannst du mir sagen, ob/wie das funktioniert? Ich will also z.B. eine for-Schleife bauen, die die Texte der Edits e11 bis e15 ändert. Will das Ganze dann schreiben als e1[i] oder sowas, weiß nur nicht wie^^

[mkinzler]

Du musst die Referenzen in einem Array verwalten.

[sirius]

(Ich hoffe ich sehe, das richtig, dass du bei iengabe von z.B. 5 -> 5x6 Edit-Felder hast)
(Hattest du eigentlich lines und rows eingefügt und ich habe es übernommen --> besser rows und columns ;) )

Also es gibt ja für ein Konzept ganz viele Möglichkeiten.
In deiner EditList sind ja alle Felder gespeichert. Die kannst du dir mit Editlist[x] rausholen. Die sind da auch der Reihe nach reingerutscht. Also müsste man die mit

Delphi-Quellcode:

EditList[(zeile-1)*(n+1)+spalte-1]

bekommen.
Das geht am schnellsten. Da wir aber auch die Edits bei dem Formular als owner angemeldet haben, können wir sie auch über das Formular und den Namen der Edits finden:

Delphi-Quellcode:

findcomponent(e+inttostr(Zeile)+inttostr(spalte))

Das kann allerdings etwas länger dauern (aber keinesfalls merklich länger)

Egal welchen Ausdruck du wählst. Du machst darum eine Klammer und setzt TEdit davor:

Delphi-Quellcode:

TEdit(EditList[(zeile-1)*(n+1)+spalte-1])

Und den Wert kannst du jetzt in einer Variable speichern, in With verwenden oder direkt nutzen:

Delphi-Quellcode:

//3 Beispiele
//1.
TEdit(EditList[(zeile-1)*(n+1)+spalte-1]).text:='Hallo';
TEdit(EditList[(zeile-1)*(n+1)+spalte-1]).visible:=false;
...

//2.
with TEdit(EditList[(zeile-1)*(n+1)+spalte-1]) do
begin
  text:=' ':
  visible:=false;
  ...
end;

//3.
var Edit:TEdit;
begin
  Edit:=TEdit(EditList[(zeile-1)*(n+1)+spalte-1]);
  Edit.text:='';
  Edit.visible:=true;
  ...
end;

Und nur um dir die Möglichkeiten aufzuzeigen, die es beim Programmieren so gibt. In deinem Fall könnte man das Konzept mit der Liste auch übern Haufen werfen und:
1. Ohne die Liste die Edits nach wie vor bei dem Formular anmelden (das führt ja auch eine Liste) und über FindComponent suchen. Da geht dann das Löschen nicht so einfach. Könnte man aber auch über FindComponent und dann x.free machen. Da spart man sich die Liste. Aber ein einfaches Clear aufzurufen anstatt mit einer Schleife alle Edits zu suchen ist etwas comfortabler.
2. Die Liste in einem Array speichern (Array of Array of TEdit). Die größe des Arrays der Matrix anpassen und jedes Element bekommt ein Objekt (create)
3....

[tiller]

Delphi-Quellcode:

TEdit[findcomponent(e+inttostr(Zeile)+inttostr(spalte))]

Genau danach habe ich gesucht, danke. Erscheint mir für das Auffinden der Edits bei diesem Zweck am einfachsten, da ich da immer schön mit n (Zeilen, Spalten entfallen wie gesagt, Matrix wird als symmetrisch vorausgesetzt) arbeiten kann :-)

Tausend Dank für deine Hilfe, den Rest bekomm ich in einem Rutsch hin, denke ich.

Gruß, tiller

[sirius]

Wie gesagt, wenn du findcomponent benutzt, kannst du dir wahrscheinlich auch die Liste sparen.
Ausser das Löschen. Das machst du dann eben anstatt Clear mit TEdit(Findcomponent()).free.

Gut ist auch, wenn du wirklich das Ergebnis von findcomponent in einer lokalen Variable speicherst und überprüfst, ob überhaupt etwas gefunden wurde.

[tiller]

Stimmt, mal sehen, vllt nehm ich sie raus, wenn das Progrmm mal läuft :-)
Hab mich nämlich zu früh gefreut...

Delphi-Quellcode:

procedure TForm1.Button3Click(Sender: TObject);
var fac: real;
begin
  label_error.Caption:='';
  if stepstogo>0 then
  begin
    for i:=(n-(stepstogo-1)) to n do
    begin
      fac:=strtofloat(TEdit[findcomponent(e+'1'+inttostr(i))].text)/strtofloat(TEdit[findcomponent(e+'1'+inttostr(i-1))].text);
      for j:=(n-stepstogo) to n do
      begin
        TEdit[findcomponent(e+inttostr(j)+inttostr(i))].text:=inttostr(strtofloat(TEdit[findcomponent(e+inttostr(j)+inttostr(i))].text)-strtofloat(TEdit[findcomponent(e+inttostr(j)+inttostr(i-1))].text)*fac);
      end;
    end;
  stepstogo:=stepstogo-1;
  end;
end;

Das ist die Prozedur, die immer einen Lösungsschritt machen soll. Es scheint allerdings Probleme mit dem Zugriff auf die Edits per findcompopnent zu geben. Ich bekomme die Meldung 'Inkompatible Typen', 'Arraytyp erforderlich'. Keine Ahnung wo das herkommt, arebite ich denn irgendwo mit Arrays?

[sirius]

Achte auf die Klammern.
Ein TypeCast geht mit runden Klammern. FindComponent liefert eigentlich ein TComponent zurück. MEhr weis FindComponent nicht. wir wissen aber, dass es ein Edit sein muss. also können wir problemlos TEdit(xxx) machen. Du hast da eckige Klammern genommen.


Edit: Und speichere das, was aus Findcomponent kommt.. zwischen.

Delphi-Quellcode:

//Beispiel
var Edit:TEdit;
...
      for j:=(n-stepstogo) to n do 
      begin 
        Edit:=TEdit(findcomponent(e+inttostr(j)+inttostr(i))); //sonst rufst du findcomponent zweimal auf
        Edit.text:=inttostr(strtofloat(Edit.text)-strtofloat(TEdit[findcomponent(e+inttostr(j)+inttostr(i-1))].text)*fac); 
      end; 
...
end;

Wichtige Sachen in dem Zusammenhang wären noch der Operator "is" --> if findcomponent(xxx) is TEdit then ...
Da kannst du halt überprüfen ob, der Zeiger, den du gefunden hast wirklich auf ein TEdit zeigt.
Und dann wäre noch assigned(xxx) (hier: assigned(Edit)) damit kannst du im obigen Beispiel noch testen, ob du überhaupt etwas gefunden hast.

[dominikkv]

Mache aus den eckigen Llammern [] runde ()
Und sollte man statt TEdit(bla) nicht besser (bla as TEdit) verwenden, da man hier bei einem inkompatiblen Typcast eine aussagekräftige Fehlermeldung bekommt?

[sirius]

Zitat:

Zitat von dominikkv

Und sollte man statt TEdit(bla) nicht besser (bla as TEdit) verwenden, da man hier bei einem inkompatiblen Typcast eine aussagekräftige Fehlermeldung bekommt?

"As" ist eher etwas für Interfaces.
Aber auch für Klassen genauso möglich.
Bei "x:=TEdit(myComponent)" kommt ein Fehler erst, wenn ich x verwende bei "x:=mycomponent as TEdit" kommt die Exception sofort.
Tja, was ist besser. Entweder man ist sich sicher, dass es nur ein Edit sein kann (wie hier), dann ist es eh egal. Ansonsten, ..weis nicht.

[tiller]

Das Ändern der eckigen in runde Klammern hilft leider nicht, Fehlermeldung bleibt die gleiche.