Objekte drehen

[Hawkeye219]

Hallo Tom,

ich habe den Code so abgeändert, daß er mit beliebigen TGraphic-Nachfolgern arbeiten sollte.

Delphi-Quellcode:

// uses Math (SinCos)

// zeichnet eine verdrehte Grafik auf einem Canvas
// aAngle ist der Drehwinkel im Uhrzeigersinn in Grad
// aOffsetX, aOffsetY gibt den Offset für das Zeichnen an

procedure DrawRotatedGraphic (aCanvas: TCanvas;  aGraphic: TGraphic;
                              aAngle: Double;  aOffsetX, aOffsetY: Integer);
var
  svMode: Integer;
  Mat, svMat: tagXFORM;
  si, co: Extended;
begin
  // aktuellen Zustand retten
  svMode := SetGraphicsMode(aCanvas.Handle, GM_ADVANCED);
  if (svMode = GM_ADVANCED) then
    GetWorldTransform(aCanvas.Handle, svMat);
  // Verschiebung in den Usprung
  FillChar (Mat, SizeOf(Mat), 0);
  Mat.em11 := 1.0;
  Mat.em22 := 1.0;
  Mat.eDx := -(aOffsetX + aGraphic.Width / 2);
  Mat.eDy := -(aOffsetY + aGraphic.Height / 2);
  SetWorldTransform(aCanvas.Handle, Mat);
  // Verdrehung
  SinCos (aAngle * Pi / 180, si, co);
  FillChar (Mat, SizeOf(Mat), 0);
  Mat.em11 := co;
  Mat.em12 := si;
  Mat.em21 := -si;
  Mat.em22 := co;
  ModifyWorldTransform(aCanvas.Handle, Mat, MWT_RIGHTMULTIPLY);
  // Zurückschieben
  FillChar (Mat, SizeOf(Mat), 0);
  Mat.em11 := 1.0;
  Mat.em22 := 1.0;
  Mat.eDx := (aOffsetX + aGraphic.Width / 2);
  Mat.eDy := (aOffsetY + aGraphic.Height / 2);
  ModifyWorldTransform(aCanvas.Handle, Mat, MWT_RIGHTMULTIPLY);
  // Bitmap zeichnen
  aCanvas.Draw(aOffsetX, aOffsetY, aGraphic);
  // alten Zustand wiederherstellen
  if (svMode = GM_ADVANCED) then
    SetWorldTransform(aCanvas.Handle, svMat)
  else
    SetGraphicsMode(aCanvas.Handle, svMode);
end;

Gruß Hawkeye

[torud]

Funzt schon ganz gut, aber das mit der Transparenz klappt leider nicht. Ich habe in Image2 ein Transparentes PNG, welches ich dann in Image1.Canvas gedreht zeichnen lasse, und danach sogar noch tranparent auf True stelle, aber er ignoriert das Ganze.

Im Anhang, ich hoffe, es klappt, mal das Projekt.

Upload geht bei mir heute schon den ganzen Tag nicht.

Der Download des Projektes

[Luckie]

Ich wende Hawkeyes Methode aus beitrag #9 an, um ein Bitmap zu drehen. Aufrufen tue ich die Prozedur folgendermaßen:

Delphi-Quellcode:

var
  BmpSrc, BmpDest   : TBitmap;
begin
  BmpSrc := TBitmap.Create;
  BmpDest := TBitmap.Create;
  try
    BmpSrc.Width := ImageEnVect1.layers[ImageEnVect1.LayersCurrent].Width;
    BmpSrc.Height := ImageEnVect1.layers[ImageEnVect1.LayersCurrent].Height;
    BmpDest.Width := ImageEnVect1.layers[ImageEnVect1.LayersCurrent].Width;
    BmpDest.Height := ImageEnVect1.layers[ImageEnVect1.LayersCurrent].Height;
    BmpSrc.Assign(ImageEnVect1.Bitmap);
    DrawRotatedBitmap(BmpSrc.Canvas, BmpDest, 10.0, , 0);
    ImageEnVect1.Bitmap.Assign(BmpDest);
    ImageEnVect1.Update;
  finally
    BmpSrc.Free;
    BmpDest.Free;
  end;
end;

Aber das Image innerhalb des Layers verschindet nur. Irgendwas mache ich da wohl noch falsch.

[Hawkeye219]

Hast du nicht Quelle und Ziel vertauscht?

Delphi-Quellcode:

procedure DrawRotatedBitmap (aCanvas: TCanvas;  aBitmap: TBitmap;
                             aAngle: Double;  aOffsetX, aOffsetY: Integer);

aCanvas ist der Ziel-Canvas, aBitmap das Quell-Bitmap.

Gruß Hawkeye

[Luckie]

So rum hatte ich es auch schon mal, das Resultat ist das gleiche.

[Cöster]

Zitat:

Zitat von Luckie

Delphi-Quellcode:

DrawRotatedBitmap(BmpSrc.Canvas, BmpDest, 10.0, , 0);

Zwischen den beiden letzten Kommata fehlt doch die Zahl für's X-Offset, oder ist das nur'n Copy'n'Paste-Fehler?

[x000x]

Moin Luckie,

Pixelformat vom Ziel auf 24 Bit setzen hat bei mir funktioniert. Ich kann nur nicht erklären warum:

Delphi-Quellcode:

var
  BmpSrc, BmpDest   : TBitmap;
begin
  BmpSrc := TBitmap.Create;
  BmpDest := TBitmap.Create;
  try
    BmpSrc.Assign(ImageEnVect1.Bitmap);

    BmpDest.Width       := ImageEnVect1.layers[ImageEnVect1.LayersCurrent].Width;
    BmpDest.Height      := ImageEnVect1.layers[ImageEnVect1.LayersCurrent].Height;
    BmpDest.PixelFormat := pf24bit;

    DrawRotatedBitmap(BmpDest.Canvas, BmpSrc, 10.0, 0, 0);

    ImageEnVect1.Bitmap.Assign(BmpDest);
    ImageEnVect1.Update;
  finally
    BmpSrc.Free;
    BmpDest.Free;
  end;
end;