guter stil????

[Ultimator]

Zitat:

Zitat von xaromz

Ach ja,
in der Routine "Pruefen":

Delphi-Quellcode:

  if p = true then 
    pruefen := true 
  else 
    pruefen := false;

Wie wäre es hier mit

Delphi-Quellcode:

Result := p;

Gruß
xaromz

Wie gesagt, die Variable p kann man komplett rausoptimieren ;)

[c113plpbr]

Zitat:

Zitat von xaromz

Ach ja,
in der Routine "Pruefen":

Delphi-Quellcode:

  if p = true then 
    pruefen := true 
  else 
    pruefen := false;

Wie wäre es hier mit

Delphi-Quellcode:

Result := p;

Gruß
xaromz

Wie wäre es ganz ohne p? das is nämlich vollkommen überflüssig ...

mein vorschlag:

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Edit1: TEdit;
    Label1: TLabel;
    Label2: TLabel;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    function pruefen(n: int64): boolean;
    procedure zerlegen(n: Int64);
  end;

var
  m: int64;
  Form1: TForm1;

implementation

{$R *.dfm}

function TForm1.pruefen(n: int64): boolean;
var
  x: Int64;
begin
  Result := True;
  x := Round(n / 2);
  if(n >= 2)then
  begin
    while(x > 1)do
    begin
      if((n mod x) = 0)then
      begin
        Result := False;
        Break;
      end;
      Dec(x);
    end;
  end
  else
    Result := False;
end;

procedure TForm1.zerlegen(n: Int64);
var
  x: int64;
begin
  x := 2;
  while((n mod x) <> 0)do
    Inc(x);

  if(Length(Label2.Caption) > 0)then
    Label2.Caption := Label2.Caption + '*';

  Label2.Caption := Label2.Caption + IntToStr(x);

  if not(pruefen(n div x))then
    zerlegen(n div x);

  m := m * x;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  m := 1;
  Label2.Caption := '';

  if(pruefen(StrToInt(Edit1.Text)))then
    Label2.Caption := Edit1.Text + ' ist eine Primzahl!'
  else
  begin
    zerlegen(StrToInt(Edit1.Text));
    Label2.Caption := Label2.Caption + '*' + IntToStr(StrToInt(Edit1.Text) div m);
  end;
end;

end.

Allerdings gefällt mir an diesem Code grundsätzlich gesehen die globale variable "m" nicht ...

ciao, Philipp

[Rastaman]

Zitat:

Zitat von xaromz

Ach ja,
in der Routine "Pruefen":

Delphi-Quellcode:

  if p = true then 
    pruefen := true 
  else 
    pruefen := false;

Wie wäre es hier mit

Delphi-Quellcode:

Result := p;

Gruß
xaromz

Delphi-Quellcode:

pruefen := true; 
// ist das Gleiche wie
Result := true;
// einfacher wäre jedoch 
pruefen := p;
//oder halt P ganz wegzulassen

[tn249]

Zwei Sachen hab ich neben der Formatierung noch;

- Die Variablennamen sollten aussagekräftiger sein. ( Was zum Beispiel ist Label1 ? )

- Deine beiden selbstgeschriebenen Funktionen würde ich als Methoden deklarieren. Wenn du nicht weißt was ich damit meine, such mal unter Objectorientierter Programmierung (OOP) bzw dem Stichwort "class" nach.

Gruß
Thomas

[xaromz]

Hallo,

Zitat:

Zitat von Ultimator

Wie gesagt, die Variable p kann man komplett rausoptimieren ;)

An der Prozedur könnte man noch einiges optimieren ;). Aber darum ging es hier ja nicht.

Gruß
xaromz

[Christian Seehase]

Moin Zusammen,

dann möchte ich noch einmal meine Formatierung von if-then-else einwerfen.

Delphi-Quellcode:

// Wenn ich garantiert nur einen Ausdruck benötige, und kein else:
if <Bedingung> then <Ausdruck>;

// Wenn mehrere Ausdrücke benötigt werden, und kein else
if <Bedingung> then begin
  <Ausdruck1>;
  <Ausdruck2>;
  <...>;
end;

// Wenn else benötigt wird, unabhängig von der Anzahl der Ausdrücke (also auch bei nur einem)
if <Bedingung> then begin
  <Ausdruck1>;
end else begin 
  <Ausdruck1>;
end;

Das entspricht zwar nicht dem Borland Style-Guide, aber ich finde dieses Auftürmen von Zeilen

Delphi-Quellcode:

end
else
begin

ausgesprochen schlecht lesbar. Vor allem wird dadurch auch die jeweilige Routine in der Anzahl der Zeilen sehr aufgebläht, und dadurch, u.U., unübersichtlich (wenn ich da nur an geschachtelte if-then-else-Konstruktionen denke...).

[Thanatos81]

Hmm, mein Vorschlag für if..then..else-Konstrukte:

Delphi-Quellcode:

if a then
  begin
    //Anweisung1
    //Anweisung2
  end
else messageDlg('bla', mtError, [mbOK], 0);

bzw.

Delphi-Quellcode:

if a then
  begin
    //Anweisung1
    //Anweisung2
  end
else 
  begin
    //Anweisung1
    //Amweisung2
  end;

bzw.

Delphi-Quellcode:

if a
  then //Anweisung1
  else //Anweisung2

Hab zwar bisher nich niemand anders gesehen, der so einrückt, aber beschwert hat sich von den Kollegen auch noch keiner ;-)

//edit
Wiederholte Satzzeichen wie "????" oder "!!!!" sind für mich auch nicht gerade guter Stil. Google mal nach "Terry Pratchett" und Ausrufezeichen ;-)

[negaH]

Delphi-Quellcode:

function TForm1.pruefen(n: int64): boolean; 
var 
  x: Int64; 
begin 
  Result := True; 
  x := Round(n / 2); 
  if(n >= 2)then 
  begin 
    while(x > 1)do 
    begin 
      if((n mod x) = 0)then 
      begin 
        Result := False; 
        Break; 
      end; 
      Dec(x); 
    end; 
  end 
  else 
    Result := False; 
end;

so würde ich es machen, denn bevor man an der Formatierung arbeitet sollte man den Algorithmus richtig machen.

Delphi-Quellcode:

function TForm1.Pruefen(const N: Int64): Boolean; 
var 
  Root,Candidate: Int64; 
begin 
  Result := Odd(N) and (N > 2)
  if Result then
  begin
    Root := Trunc(Sqrt(N));
    Candidate := 3;
    while Result and (Candidate <= Root) do
    begin
      Result := N mod Candidate <> 0;
      Candidate := Candidate +2;
    end;   
  end else Result := N = 2;   
end;

Man muß für den einfachen Test einer Zahl auf Primzahl nur alle Zahlen kleiner Wurzel(N) die ungerade sind per Trialdivision testen. Desweiteren ist es sinnvoll bei der Trialdivision mit den kleinsten Zahlen beginnend zu testen da es von der Häufigkeitsverteilung der Primzahlfaktoren eher die kleinen Primzahlen sind die am meisten vorkommen. Die meisten zusammengesetzten Zahlen sind also zusammengesetzt aus kleinen Primzahlfaktoren. Die Laufzeit des Algorithmus ist also, wenn man die Trialdivision von unten nach oben laufen lässt, wesentlich besser.

Und wenn es sich vermeiden lässt dann Break/Continue/Exit auch vermeiden.
Desweiteren sollte der Pfad den man einen Source liest bei den Programverzweigungen den am meisten durchlaufenden Pfad folgen. Dh. im obigen Beispiel, das man zuerst im Source den Pfad hat der nun nicht auf 2 als einzigste gerade Primzahl testet.


Gruß Hagen

PS: sowas

Delphi-Quellcode:

  if x then begin
  end;

also das begin OHNE Zeilenumbruch empfinde ich als die übelste Mode die sich in den letzten 10 Jahren eingebürgert hat ! Das entspricht dem Stil eines C Programmieres der versucht 7 verschachtelte Schleife mit 10 Abfragen und Schleifenzählern in eine einzigste Zeile zu pressen.

[tigerman33]

Hi,

also ich empfinde das begin ohne Einrücken ganz im Gegenteil sogar als besser (schließlich mach ich's auch so :mrgreen: ). Die Zugehörigkeit des entsprechenden Blocks zur Schleife/if-Abfrage o.ä. wird durch die Einrückung bereits deutlich. Denn auf solche Konstruktionen wie dies

Delphi-Quellcode:

end
else
begin

kann ich genau wie Christian Seehase gerne verzichten. Auch den viel gepredigten begin-end Block um einzeilige then/else-Zweige oder Schleifen finde ich überflüssig. Das müllt mir bloß den Code zu.

Delphi-Quellcode:

while x > 0 do
  if x < 5 then
    inc(x) else
    dec(x);

halte ich denn doch für deutlich übersichtlicher als

Delphi-Quellcode:

while x > 0 do 
begin
  if x < 5 then
  begin
    inc(x);
  end
  else
  begin
    dec(x);
  end;
end;

Aber da das nur meine persönlichen 2 ct sind und Delphi zum Glück noch keinen zu seinem Glück zwingt kann's ja jeder so machen wie er selbst will.

Gruß
Christian

[Luckie]

Zitat:

Zitat von tigerman33

Auch den viel gepredigten begin-end Block um einzeilige then/else-Zweige oder Schleifen finde ich überflüssig.

Und wie schnell hat man vergessen ihn nachträglich einzufügen, wenn man den nicht vorhandenen Block erweitert. Und dann wundert man sich, warum das Programm aufeinmal nicht das macht, was es soll.