Pfad+Name der aktuellen DLL aus DLL heraus ermitteln...

[Olli]

Zitat:

Zitat von FriFra

Delphi-Quellcode:

var
...
  DllName: array[0..MAX_PATH-1] of char;

Kleiner Tip: wenn du deine EXE nicht künstlich aufblähen willst, solltest du lieber auf String zurückgreifen und den Puffer des Strings mit SetLength() setzen um Platz für den Modulnamen zu schaffen (das landet dann auf dem Heap). So landet die entsprechende Variable selbst nicht auf dem Stack und die EXE/DLL bleibt kleiner (hier um 260 Zeichen).

[SirThornberry]

ok, ich hab das jetzt mal so probiert:

Delphi-Quellcode:

var a: TMemoryBasicInformation;
    LBuffer: String;
begin
  FillChar(a, SizeOf(a), 0);
  VirtualQuery(@a, a, SizeOf(a));
  SetLength(LBuffer, MAX_PATH);
  GetModuleFileName(Cardinal(a.AllocationBase), PChar(LBuffer), Length(LBuffer));
  showmessage(LBuffer);

was ist jetzt falsch?

[Luckie]

So war es gemeint:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  Path: String;
begin
  Setlength(Path, MAX_PATH+1);
  Setlength(Path, GetModuleFileName(HInstance, PChar(Path), MAX_PATH));
  ShowMessage(Path);
end;

[Olli]

Zitat:

Zitat von SirThornberry

was ist jetzt falsch?

Nix, sieht beim öberflächlichen Drüberschauen gut aus. Wenn du Standardunits benutzt, kannst du es mit hInstance vergleichen.

[SirThornberry]

a.AllocationBase weicht von HInstance ab.
a.AllocationBase ist immer $3000

[Olli]

Dann stimmt was an deinem Code nicht :-D
Ich gucke es mir morgen vielleicht mal an. Bin jetzt gerade dabei Luckie zu helfen.

[SirThornberry]

ich habs gefunden, wenn ich bei VirtualQuery als ersten Parameter die Adresse einer globalen Angebe funktioniert es, nur eben bei der lokalen Variablen nicht.

es sieht jetzt also wie folgt aus

Delphi-Quellcode:

[...]
implementation

{$R *.dfm}

var GlobalVar: Cardinal;

procedure TForm1.FormCreate(Sender: TObject);
var QueryRes: TMemoryBasicInformation;
    LBuffer: String;
begin
  VirtualQuery(@GlobalVar, QueryRes, SizeOf(QueryRes));
  SetLength(LBuffer, MAX_PATH);
  SetLength(LBuffer, GetModuleFileName(Cardinal(QueryRes.AllocationBase), PChar(LBuffer), Length(LBuffer)));
  showmessage(String(LBuffer));
end;

[Olli]

Zitat:

Zitat von SirThornberry

ich habs gefunden, wenn ich bei VirtualQuery als ersten Parameter die Adresse einer globalen Angebe funktioniert es, nur eben bei der lokalen Variablen nicht.

Irrtum. Aber danke für den Hinweis. Objekte in Delphi liegen auf dem Heap. Damit ist klar welche Adresse du bekommen hast, denn du hast die Funktion von innerhalb einer Methode aufgerufen. Daher bekamst du die Lage des Objektes im Speicher, nicht jedoch die einer Stackvariablen. Fazit: es muß sich um eine Stackvariable handeln ;)

[brechi]

schöner ist es vielleicht wenn man eine funktion draus macht:

Delphi-Quellcode:

function GetModulePath: String;
var QueryRes: TMemoryBasicInformation;
    LBuffer: String;
begin
  VirtualQuery(@GetModulePath, QueryRes, SizeOf(QueryRes));
  SetLength(LBuffer, MAX_PATH);
  SetLength(LBuffer, GetModuleFileName(Cardinal(QueryRes.AllocationBase), PChar(LBuffer), Length(LBuffer)));
  result := LBuffer;
end;