neue Komponente : "TlabeledLabel"

[Robert_G]

Warst du nichtmal so stolz auf dein labeled DB Edit?
Wenn wirklich du (und nicht etwa Motzi ;) ) das Ding geschrieben hast, sollte doch eine Adaption für ein Label kein Problem darstellen. :gruebel:

[Hansa]

Aha, der erste "Komponentenentwickler" ist aufgetaucht. 8) Nochmals, es geht nicht um ein Edit !!

Edit : wie siehts eigentlich mit konkreten Vorschlägen aus ?

[SirThornberry]

und hier ist das schmuckstück (sollte selbsterklärend sein):

Delphi-Quellcode:

  TLabelLabel = class(TGraphicControl)
  private
    fAlignment: TAlignment;
    fCaption: String;
    fLeftMargin: Integer;
    fText: String;
    procedure FSetAlignment(AValue: TAlignment);
    procedure FSetStr(AType: Integer; AValue: String);
  public
    constructor Create(AOwner: TComponent); override;
    procedure Paint; override;
  published
    property Alignment: TAlignment read fAlignment write FSetAlignment default taLeftJustify;
    property Caption: String Index 0 read fCaption write FSetStr;
    property Font;
    property Text: String Index 1 read fText write FSetStr;
  end;

[...]

constructor TLabelLabel.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  fAlignment := taLeftJustify;
  fCaption := 'Caption:';
  fLeftMargin := 5;
  fText := 'Text';
end;

procedure TLabelLabel.Paint;
var LCaptionWidth, LTextWidth, LLeft: Integer;
begin
  Canvas.Brush.Style := bsClear;
  Canvas.Font.Assign(Font);
  LCaptionWidth := Canvas.TextWidth(fCaption);
  LTextWidth := Canvas.TextWidth(fText);
  Canvas.TextOut(0, 0, fCaption);
  if (fAlignment = taLeftJustify) or
     (Width < LCaptionWidth + fLeftMargin + LTextWidth) then
    Canvas.TextOut(LCaptionWidth + fLeftMargin, 0, fText)
  else begin
    if fAlignment = taRightJustify then
      Canvas.TextOut(Width - LTextWidth, 0, fText)
    else begin
      LLeft := (Width - LCaptionWidth - fLeftMargin - LTextWidth) div 2;
      Canvas.TextOut(LCaptionWidth + fLeftMargin + LLeft, 0, fText);
    end;
  end;
end;

procedure TLabelLabel.FSetAlignment(AValue: TAlignment);
begin
  if AValue <> fAlignment then
  begin
    fAlignment := AValue;
    Repaint;
  end;
end;

procedure TLabelLabel.FSetStr(AType: Integer; AValue: String);
  procedure LSetVal(var LStr: String);
  begin
    if AValue <> LStr then
    begin
      LStr := AValue;
      Repaint;
    end;
  end;
begin
  if AType = 0 then
    LSetVal(fCaption)
  else if AType = 1 then
    LSetVal(fText);
end;

[sandraeberlein]

Zitat:

es geht nicht um ein Edit !!

Edit : wie siehts eigentlich mit konkreten Vorschlägen aus ?

Warum machst du dann ein Edit? :D

[SirThornberry]

@sandraeberlein: Er hat doch gar kein Edit gemacht!!! zumindest nicht für den zweck, und damals hat ?er? ein db-Edit-irgendwas gebaut weil er das damals brauchte, jetzt braucht er aber was anderes.

@Hansa: wozu hast du eigentli icq wenn du dann ni antwortest?

[mschaefer]

Moin, Spätmoin,

@SirThornberry: Danke das Du meinen Part schon übernommen hast. Die Sache mit dem Index hat sogar einige Raffinesse. Da kann Hansa gleich sein Package einrichten...

Grüße // Martin

[SirThornberry]

No Problem, hat ja nur paar minütschen gedauert... Hmm, Raffinesse würd ich das ni nennen, eher faulheit weil ich kein bock hatte 2 SetMethoden zu schreiben

[Hansa]

Da fehlt aber noch etliches. Muß mal noch mehr im Source gucken. Was geht ist folgendes : der Text innerhalb des Labels kann rumgeschoben werden.

[SirThornberry]

wenn dir was fehlt kannst du es ja anpassen, die anforderungen die du gestellt hast wurden erfüllt und falls nicht ist es eigentlich auch egal weil du ursprünglich nur einen gedankenanstoß brauchtest wie man sowas umsetzt, und den solltest du ja jetzt bekommen haben.

Desweiteren hatte ich ja versucht dir bei icq zu schreiben (eben um eventuell weitere wünsche gleich mit reinzupacken), hab aber leider keine antwort erhalten.

[mschaefer]

Moin, mon,

also Hansa, morgendlich knapp, erst mal ist nicht jeder in bestiz einer großen Glaskugel, das Hellsehen wird leider auch nur noch sehr selten vererbt. Du solltest uns schon veraten was Du willst. Aber vielleicht postet Du ja die nächste Version. Bin jedenfalls mal neugierig...

Grüße // Martin