Farbe von showmessage ändern

[Muetze1]

Moin!

So schwer ist das doch nicht...

Delphi-Quellcode:

procedure CustomMessage(Text: string; FormColor, LabelColor: TColor);
var
  Messagelabel: TLabel;
  MessageButton: TButton;
  MessageForm : TForm;
begin
  MessageForm := TForm.Create(nil);
  Messagelabel := TLabel.Create(MessageForm);
  MessageButton := TButton.Create(MessageForm);

  with  MessageForm do
   begin
    Color   := FormColor;
    Caption := application.Title;
    SetBounds((Screen.Width - MessageForm.Width) div
     2, (Screen.Height - MessageForm.Height) div 2,MessageForm.Width,
      MessageForm.Height);
    BorderIcons := [biSystemMenu];
    BorderStyle := bsdialog;
    Height      := 110;
   end;


  with Messagelabel do
   begin
    Caption    := Text;
    Font.Color := LabelColor;
    Parent     := MessageForm;
    Top        := 15;
   end;

  with MessageButton do
   begin
    Caption := 'OK';
    Parent  := MessageForm;
    Top     := 40;
    ModalResult := mrOk;
    Default := True;
    Cancel  := True;
   end;

  MessageForm.Width := 75 + MessageLabel.Width;
  MessageButton.Left := MessageForm.Width div 2 - Messagebutton.Width div 2;
  MessageLabel.Left := MessageForm.Width div 2 - MessageLabel.Width div 2;
  MessageForm.ShowModal;
  MessageForm.Free;
end;

Das ist alles.

MfG
Muetze1

[shmia]

Mit der Verwendung von CreateMessageDialog lässt sich viel einiges aus der VCL wiederverwenden:

Delphi-Quellcode:

function MessageDlgPosHelpWithColor(const Msg: string; DlgType: TMsgDlgType;
  Buttons: TMsgDlgButtons; HelpCtx: Longint; X, Y: Integer;
  const HelpFileName: string; DlgColor:TColor): Integer;
begin
  with CreateMessageDialog(Msg, DlgType, Buttons) do
    try
      Color := DlgColor;
      HelpContext := HelpCtx;
      HelpFile := HelpFileName;
      if X >= 0 then Left := X;
      if Y >= 0 then Top := Y;
      if (Y < 0) and (X < 0) then Position := poScreenCenter;
      Result := ShowModal;
    finally
      Free;
    end;
end;

[ReDoX]

@ Muetze1 :
Ok so schwere war das wirklich nicht :nerd:.
Danke

@ shmia :
das ist viel einfacher als meins danke!
Mfg ReDoX