TCollection & TCollectionitem Tutorial

[MrBrown90]

Ok, ich hab hier ein Beispiel von embarcadero:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  PanelIndex : Integer;
begin
  with StatusBar1 do
  begin
    Panels.BeginUpdate;
    PanelIndex := StatusBar1.Panels.Count - 1;
    try
      Panels.Add;
      Inc(PanelIndex);
      Panels.Items[PanelIndex].Text := 
         'Panel' + IntToStr(PanelIndex);
    finally
      Panels.EndUpdate;
    end;
  end;
end;

Was ich nicht verstehe, wenn ich Panels.Add Aufrufe...muss ich da kein Parameter übergeben?

[MrBrown90]

@der schöne Günther...das ist die ganze aufgabenbeschreibung

[TiGü]

Zitat:

Zitat von MrBrown90 (Beitrag 1385604)

Was ich nicht verstehe, wenn ich Panels.Add Aufrufe...muss ich da kein Parameter übergeben?

Nein, das ist eine Methode, die ein Item erzeugt und in die Liste automatisch einträgt und wenn man lustig ist, kann man die entstandene Instanz auch nach als Rückgabewert haben.
Wie immer hilft ein Blick in den Quelltext:

Delphi-Quellcode:

function TCollection.Add: TCollectionItem;
begin
  Result := FItemClass.Create(Self);
  Added(Result);
end;

[TiGü]

Zitat:

Zitat von Der schöne Günther (Beitrag 1385603)

Wenn du Unterklassen bilden sollst die von TCollection und TCollectionItem ableiten sollen dann macht das natürlich Sinn, ist aber ehrlich gesagt auch nicht ganz trivial (finde ich). Ist dem so? Ich finde das aus

Zitat:

Die konkrete Aufgabe lautet:
A component that organized Tür Threads ans their outputs
a:Use TCollection with its methods "Changed" and "Update ".


Ich habe bereits eine Class von TCollection und Tcollectionitem erstellt.

immer noch etwas schwer herauszulesen.

Zitat:

Zitat von MrBrown90 (Beitrag 1385607)

@der schöne Günther...das ist die ganze aufgabenbeschreibung

Was der Schöne meint ist wohl eher, das so Sachen wie "Tür Threads ans" und "a:Use" irgendwie ein bisschen kryptisch sind.:shock:

[MrBrown90]

Oh habe ich übersehen, muss leider mit dem Handy tippen.

A component that organized the Threads and their Output

a: Use TCollection with its methods "Changed" and "Update"

[MrBrown90]

Also wird mit der Update Methode einfach ein neues Item erzeugt und an die letzte Stelle der Liste eingefügt?

[TiGü]

Zitat:

Zitat von MrBrown90 (Beitrag 1385611)

Also wird mit der Update Methode einfach ein neues Item erzeugt und an die letzte Stelle der Liste eingefügt?

Mit der ADD-Methode...sonst quasi ja!

[TiGü]

Zitat:

Zitat von MrBrown90 (Beitrag 1385610)

Oh habe ich übersehen, muss leider mit dem Handy tippen.

A component that organized the Threads and their Output

a: Use TCollection with its methods "Changed" and "Update"

Was denn für Threads und wie ist der Output definiert?

[TiGü]

Probiere das folgende Konsolenprogramm mal aus, vielleicht hilft dir das weiter:

Delphi-Quellcode:

program Project3;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils, System.Classes;

type
  TMyCollectionItem = class(TCollectionItem)
  private
    // hier kannst du auch eigene Felder und Methoden definieren
  protected
    function GetDisplayName: string; override;
  end;

  TMyCollection = class(TCollection)
  protected
    procedure Update(Item: TCollectionItem); override;
    procedure SetItemName(Item: TCollectionItem); override;
    procedure Notify(Item: TCollectionItem; Action: TCollectionNotification); override;
  public
    procedure BeginUpdate; override;
    procedure EndUpdate; override;
  end;

procedure TMyCollection.BeginUpdate;
begin
  inherited;
  Writeln('BeginUpdate');
end;

procedure TMyCollection.EndUpdate;
begin
  inherited;
  Writeln('EndUpdate');
end;

procedure TMyCollection.Notify(Item: TCollectionItem; Action: TCollectionNotification);
begin
  inherited;
  case Action of
    cnAdded: Writeln(Item.DisplayName + ' added');
    cnExtracting:
      Writeln(Item.DisplayName + ' extracing');
    cnDeleting:
      Writeln(Item.DisplayName + ' deleting');
  end;
end;

procedure TMyCollection.SetItemName(Item: TCollectionItem);
begin
  inherited;
   Writeln(Item.DisplayName + ' ItemName');
end;

procedure TMyCollection.Update(Item: TCollectionItem);
begin
  inherited;
  if Assigned(Item) then
  begin
    // Ein einzelnes Item wurde befummelt
    Writeln(Item.DisplayName + ' updated');
  end else
    // wenn Item = nil, dann ist die ganze Collection betroffen

end;

function TMyCollectionItem.GetDisplayName: string;
begin
  Result := 'HuiBui: ' + IntToStr(Self.ID);
end;

procedure Main;
var
  MyCollection: TMyCollection;
  MyItem: TCollectionItem;
  I: Integer;
  Something: string;
begin
  MyCollection := TMyCollection.Create(TMyCollectionItem);
  try
    MyCollection.BeginUpdate;
    try
      for I := 0 to 10 - 1 do
      begin
        MyItem := MyCollection.Add;
      end;
    finally
      MyCollection.EndUpdate;
    end;

    Something := '';
    for I := 0 to MyCollection.Count - 1 do
    begin
      MyItem := MyCollection.Items[I];
      Something := Something + MyItem.DisplayName + ' ';
    end;

    Writeln(Something);

    MyCollection.Items[5].DisplayName := 'asdf';

    MyCollection.Delete(5);
  finally
    MyCollection.Free;
  end;
end;

begin
  try
    Main;
    Readln;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

end.

[MrBrown90]

Okay super, vielen danke ..das nehm ich mir jetzt mal genau unter die Lupe.


Create and destroy Threads
Start and Stop Threads
Configure the thread interval
Print the Output of the Threads


Aber mit Threads hatte ich echt noch nie etwas zu tun, deswegen hab ich das erstmal hinten angestellt