Fernbedienung für Lautstärkeregelung

[toms]

Zitat:

Geht das auch, dass ich Strg und P schicken kann (also gleichzeitig)?

Geht. Aber bedingt. Dazu muss der MediaPlayer im Vordergrund sein.
Beispiel:

Delphi-Quellcode:

procedure PostKeyEx32(key: Word; const shift: TShiftState; specialkey: Boolean);
type
  TShiftKeyInfo = record
    shift: Byte;
    vkey: Byte;
  end;
  byteset = set of 0..7;
const
  shiftkeys: array [1..3] of TShiftKeyInfo =
    ((shift: Ord(ssCtrl); vkey: VK_CONTROL),
    (shift: Ord(ssShift); vkey: VK_SHIFT),
    (shift: Ord(ssAlt); vkey: VK_MENU));
var
  flag: DWORD;
  bShift: ByteSet absolute shift;
  i: Integer;
begin
  for i := 1 to 3 do
  begin 
    if shiftkeys[i].shift in bShift then
      keybd_event(shiftkeys[i].vkey, MapVirtualKey(shiftkeys[i].vkey, 0), 0, 0);
  end; { For } 
  if specialkey then 
    flag := KEYEVENTF_EXTENDEDKEY 
  else
    flag := 0;

  keybd_event(key, MapvirtualKey(key, 0), flag, 0); 
  flag := flag or KEYEVENTF_KEYUP;
  keybd_event(key, MapvirtualKey(key, 0), flag, 0); 

  for i := 3 downto 1 do
  begin 
    if shiftkeys[i].shift in bShift then
      keybd_event(shiftkeys[i].vkey, MapVirtualKey(shiftkeys[i].vkey, 0),
        KEYEVENTF_KEYUP, 0);
  end; { For }
end; { PostKeyEx32 }


procedure TForm1.Button1Click(Sender: TObject);
var
wnd: HWND;
begin
  wnd := FindWindow('WMPlayerApp',nil);
  SetForeGroundWindow(wnd);
  if IsWindow(wnd) then
   // Strg + P simulieren
   PostKeyEx32(Ord('P'), [ssctrl], False);
end;