Vista: Ein Programm mit Benutzerrechten starten

[Stephan]

Hallo,

Hm, ich hab nen interessanten Weg gefunden. Wenn ich einfach per ShellExecute nicht direkt die Programmdatei sondern einfach eine Verknüpfung zu dieser Programmdatei starte, dann erbt der neu gestartete Prozess NICHT die Adminrechte, sondern die normalen Benutzerrechte

Dies ist zwar ziemlich Dirty, scheint aber zu funktionieren ... (wobei ich hier über jede schönere Lösung dankbar bin)

[Stephan]

Ok, merkwürdigerweise scheint der Trick mit der Verknüpfung nicht mehr zu funktionieren - dabei hätte ich schwören können, dass das vorhin mehrmals erfolgreich ging

[ol1uw]

Folgendes habe ich mal verwendet um von einen Programm ,welches mit Systemrechten läuft, eine Anwendung
zustarten als aktueller User.
Keine Ahnung ob es unter Vista geht (nur unter XP getestet) und ob es in deinem Fall brauchbar ist.

Delphi-Quellcode:

program csfax;

uses
   Windows,  SysUtils, Dialogs,
   tlhelp32,registry;
{$R *.res}

var
  Reg: TRegistry;
  fax: string;
  prog: string;
  hToken, pToken: Cardinal;
  bResult: Boolean;
  pi: TProcessInformation;
  si: TStartupInfo;
  proctoken, Procid: Cardinal;

  function GetProcessID(Exename: string): DWORD;
  var
    hProcSnap: THandle;
    pe32: TProcessEntry32;
  begin
    result := 0;
    hProcSnap := CreateToolHelp32SnapShot(TH32CS_SNAPPROCESS, 0);
    if hProcSnap <> INVALID_HANDLE_VALUE then
    begin
      pe32.dwSize := SizeOf(ProcessEntry32);
      if Process32First(hProcSnap, pe32) = true then
      begin
        while Process32Next(hProcSnap, pe32) = true do
        begin
          if pos(UpperCase(Exename),Uppercase( pe32.szExeFile)) <> 0 then
            result := pe32.th32ProcessID;
        end;
      end;
      CloseHandle(hProcSnap);
    end;
  end;

begin
  reg := TRegistry.Create;
  reg.RootKey := LongWord($80000002);
  try
    reg.OpenKey('SYSTEM\CurrentControlSet\Control\Print\Monitors\CsFax Port Monitor', False);
    fax := ' FAX "';
    fax := fax + reg.ReadString('SpoolDatei');
    fax := fax + '"';
    reg.CloseKey;
    reg.OpenKey('SOFTWARE\Komclient\Fax', False);
    prog := reg.ReadString('InstallDir');
    reg.CloseKey;
  finally
    reg.Free;
  end;

  Procid := GetProcessID('EXPLORER.EXE');
  proctoken := OpenProcess(PROCESS_ALL_ACCESS, true, Procid);
  bResult := OpenProcessToken(proctoken, TOKEN_DUPLICATE or TOKEN_IMPERSONATE,hToken);
  if not bResult then 
    ShowMessage('Prozess Token :' + SysErrorMessage(GetLastError));
  bResult := DuplicateTokenEx(hToken, TOKEN_ALL_ACCESS, nil,SecurityImpersonation, TokenPrimary,pToken);
  if not bResult then
    ShowMessage('Duplicate Token : ' + SysErrorMessage(GetLastError));

  with si do
  begin
    cb := SizeOf(TStartupInfo);
    lpReserved := nil;
    lpDesktop := nil;
    dwX := 0;
    dwY := 0;
    dwXSize := 0;
    dwYSize := 0;
    dwXCountChars := 0;
    dwYCountChars := 0;
    dwFillAttribute := 0;
    dwFlags := 0;
    wShowWindow := SW_SHOWDEFAULT;
    cbReserved2 := 0;
    lpReserved2 := nil;
    hStdInput := 0;
    hStdOutput := 0;
    hStdError := 0;
  end;
  bResult := CreateProcessAsUser(
    pToken,
    nil,
    PChar(prog+fax),
    nil,
    nil,
    False,
    NORMAL_PRIORITY_CLASS,
    nil,
    nil,
    si,
    pi
    );
  if not bResult then
    ShowMessage('CreatProcessASUser : ' + SysErrorMessage(GetLastError));
  CloseHandle(ptoken);
end.

[Stephan]

Hallo,

Danke für deinen Code. Unter Vista erhalte ich leider (auch mit Adminrechten) folgenden Fehler:

CreatProcessASUser: Dem Client fehlt ein erforderliches Recht

[OregonGhost]

Das sieht mir nach einer "but the demo worked"-Lösung aus.
Im Oldnewthing von Raymond Chen müsste dazu mehr zu finden sein... Es gibt nicht den aktuellen Benutzer unter Vista

Mal eine andere Frage dazu... wenn man unter Vista Admin ist, starten die Programme dann nicht unter dem Namen des Benutzers, obwohl er keine Admin-Rechte hat?

[Stephan]

Ich hab mal bisschen im MSDN geschaut und folgendes gefunden: CreateProcessWithTokenW http://msdn2.microsoft.com/en-us/library/ms682434.aspx

Das klingt für mich irgendwie richtig. Weiß hier jemand, wie man das in Delphi implementieren muss?

Zitat:

Mal eine andere Frage dazu... wenn man unter Vista Admin ist, starten die Programme dann nicht unter dem Namen des Benutzers, obwohl er keine Admin-Rechte hat?

Die meisten Programme werden wohl auch unter einem Adminkonto nicht mit Adminrechten gestartet.

[ProgrammerJoe]

Zitat:

Delphi-Quellcode:

  function GetProcessID(Exename: string): DWORD;
  var
    hProcSnap: THandle;
    pe32: TProcessEntry32;
  begin
    result := 0;
    hProcSnap := CreateToolHelp32SnapShot(TH32CS_SNAPPROCESS, 0);
    if hProcSnap <> INVALID_HANDLE_VALUE then
    begin
      pe32.dwSize := SizeOf(ProcessEntry32);
      if Process32First(hProcSnap, pe32) = true then
      begin
        while Process32Next(hProcSnap, pe32) = true do
        begin
          if pos(UpperCase(Exename),Uppercase( pe32.szExeFile)) <> 0 then
            result := pe32.th32ProcessID;
        end;
      end;
      CloseHandle(hProcSnap);
    end;
  end;

An mehreren Stellen im Forum geistert immer wieder dieser Codeschnipsel durchs Forum, wenn es darum geht, die Prozess-ID anhand des exe-Namens zu ermitteln (z.B. Suche nach hProcSnap).

Dazu habe ich zwei Fragen:

1. Die Funktion verwendet eine kopfgesteuerte und keine fußgesteuerte Schleife. Das heißt, der erste Prozeß wird nie erfaßt. Ist das irgendein Systemprozeß, den man nicht haben will? Ist das Absicht? Habe ich irgendetwas nicht verstanden, oder ist das schlicht ein Bug?

2. Es wäre sinnvoll, im Erfolgsfall aus der Schleife auch auszusteigen. Ich würde die Funktion daher so schreiben:

Delphi-Quellcode:

  function GetProcessID(Exename: string): DWORD;
  var
    hProcSnap: THandle;
    pe32: TProcessEntry32;
  begin
    result := 0;
    hProcSnap := CreateToolHelp32SnapShot(TH32CS_SNAPPROCESS, 0);
    if hProcSnap <> INVALID_HANDLE_VALUE then begin
      pe32.dwSize := SizeOf(ProcessEntry32);
      if Process32First(hProcSnap, pe32) = true then begin
        repeat
          if pos(UpperCase(Exename),Uppercase( pe32.szExeFile)) <> 0 then begin
            result := pe32.th32ProcessID;
            break;
          end;
        until Process32Next(hProcSnap, pe32) = false;
      end;
      CloseHandle(hProcSnap);
    end;
  end;

Spricht irgendetwas gegen diese Version?

[Dezipaitor]

1. Für die Funktion gibts ein Beispiel :
http://msdn2.microsoft.com/en-us/library/ms686701.aspx
Die nutzen do while
2. natürlich

Übrigens gibt es seit XP die Funktion
WTSQueryUserToken um das Token zu erhalten.
Das funkz auch bei Leuten, die kein Explorer haben.



Noch was:
1. Bedenkt auch die Leute die noch kein Explorer.exe Prozess haben
Das kann passieren wenn:
a) der benutzer ne andere shell nutzt
b) der dienstcode vor der shell geladen wird
c) explorer wurde gekillt
2. wenn es mehrere Sessions gibt - in welche wird der prozess geöffnet? (Fast User Switching, Terminal Session)

[ProgrammerJoe]

Ist der erste Prozess, der zurückgegeben wird, denn tatsächlich immer die explorer.exe?

do while ist für mich in Delphi return until.

Demnach gehe ich von einem Bug aus, weil jemand die Funktion falsch nach Delphi übersetzt hat.

Es wundert mich, daß so viele Leute den Code nutzen und posten, aber niemandem das aufgefallen ist.

Ist er schon irgendwo in der Codelibrary? Vielleicht könnte man eine Anmerkung dort mit Verweis auf diesen Thread machen, wobei ich zugeben muss, dass der Titel zu diesem Problem vielleicht nur bedingt paßt.

[Dezipaitor]

Hmm

ich hab jetzt noch bei SwissDelphiCenter geguckt, und die scheinen korrekt zu sein.

http://www.swissdelphicenter.ch/de/showcode.php?id=593
http://www.swissdelphicenter.ch/de/showcode.php?id=266