Wie drucke ich eine Plottfile ?

[orion3000]

Hallo zusammen,

wie ist es möglich das ich eine Datei, die durch einen Druckertreiber,z.B. HP -Designjet als Datei erstellt wurde, eine PRN oder PLT, direkt ohne Umwege an einen Druckerport zu senden.

Das soll heissen ich erstelle mit Autocad eine Zeichnung und wähle dann Drucken/Plotten und lasse dann die Zeichnung als Plotfile auf die Festplatte speichern.

Nun möchte ich mit Delphi eine Anwendung stricken, wo man die Datei(en) auswählen kann und diese dann direkt, ohne Druckertreiber, an LPT1 oder LPT2 zu schicken.

Z.B: Früher ging das auch mit dem Befehl Copy Dateiname LPT1:
Aber bei den NT Versionen Funktioniert das nicht ohne Weiteres.

Daß dies möglich ist weiss ich aber der Quellcode ging dummer weise verloren.

Für Eure Mühe Danke estmal

Orion3000

[Christian Seehase]

Moin Orion,

nur so als Idee, ungetestet:

Wenn der Drucker freigegeben ist, könntest Du es ja mal mit

Copy Dateiname \\Rechner\Freigabename

versuchen.

[orion3000]

Hallo Christian,

erstmal Danke für deine Hilfe,
ich habe das schon versucht aber da bekomme ich nur Feherlmeldungen.

Ich weiß nicht genau ich glaube daß dies mit einem FileStream irgendwie zu bewerkstelligen ist.

Unter Basic,für DOS, ging das ähnlich,

Open "Dateiname" for Input as #1
///7

Code


////
Open "LPT1:" for Output As #1


Ich hatte mal einen Quellcode irgendwo gedownloadet,der dies konnte, aber der ist irgendwie verloren gegangen.


Gruß
Orion3000

[orion3000]

Hallo Zusammen,

nach langem Suchen habe ich nun endlich eine Funktion gefunden.
vielleicht kann der Eine oder Andere diese ja gebrauchen.

Mit dieser Funktion kann man Plotfiles oder PRN's direkt an einen Druckertreiber senden.

Delphi-Quellcode:

function SpoolFile(const FileName, PrinterName: string): Integer;
var
  Buffer: record
    JobInfo: record // ADDJOB_INFO_1
      Path: PChar;
      JobID: DWORD;
    end;
    PathBuffer: array[0..255] of Char;
  end;
  SizeNeeded: DWORD;
  Handle: THandle;
  PrtName: string;
  ok: Boolean;
begin
  // Flush job to printer
  PrtName := PrinterName;
  if PrtName = '' then
    PrtName := Printer.Printers[Printer.PrinterIndex]; // Default printer name
  ok := False;
  if OpenPrinter(PChar(PrtName), Handle, nil) then
    if AddJob(Handle, 1, @Buffer, SizeOf(Buffer), SizeNeeded) then
      if CopyFile(PChar(FileName), Buffer.JobInfo.Path, True) then
        if ScheduleJob(Handle, Buffer.JobInfo.JobID) then
          ok := True;
  if not ok then Result := GetLastError
  else
    Result := 0;
end;

Gruß
Orion3000

[AndreasZZZ]

Ich habe die gleiche Funktion gefunden und benötige so etwas dringend.

Allerdings habe ich das Problem, das der Aufruf von AddJob leider false zurückliefert und GetLastError=87, d.h. "falscher Parameter" zurückliefert.

Da ich von API-Programmierung nicht viel Ahnung habe, hoffe ich, dass vielleicht jemand helfen kann.

Ich drucke auf einen Netzwerkdrucker. Das handle von OpenPrinter ist <> 0 also sollte das funktioniert haben.

Bin für jede Hilfe dankbar.

Bye
AndraesZZZ

[ipworks]

Also Freunde,
die Systematik ist relativ einfach und eigentlich schon im ersten Beitrag erwähnt.
"copy blabla.ps lpt1"...nur bei Windows könnt ihr nicht auf den Anschluss kopieren (oder es ist alles andere als elegant). Ihr müsst den Printer-File in den Spooler (Druckerwarteschlange kopieren.


Das ganze basiert auf der Idee copy a file to a printer:

Hier der Quellcode für eine Unit:

Delphi-Quellcode:

//-------------------------------------------------------------------------
// Copyright (c) 2003 - PW&T <[e-mail]>
// All Rights Reserved
// web: [url]http://www.ipworks.de[/url]
//-------------------------------------------------------------------------

unit spoolps;  
interface

uses
  Forms,SysUtils,Graphics,Classes,CtlPanel,Windows,Printers,WinSpool;

procedure PrintPSFile(Const sFileName: PChar; PrIndex:Integer);
function IsPostScriptPrinter(dc : hdc) : integer;
// - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
// - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

implementation

function IsPostScriptPrinter(dc : hdc) : integer;  //Feststellung ob Drucker PS-Drucker
var
  TestInt : integer;
  a : array[0..255] of char;
  err : integer;
  s : string;
begin
  Result := 1;
  TestInt := GETTECHNOLOGY;
 {$IFDEF WIN32}
  if ExtEscape(Dc,
               QUERYESCSUPPORT,
               sizeof(TestInt),
               @TestInt,
               0,
               Nil) > 0 then begin
     Err := ExtEscape(Dc,
                      GETTECHNOLOGY,
                      0,
                      nil,
                      256,
                      @a);
 {$ELSE}
  if Escape(Dc,
            QUERYESCSUPPORT,
            sizeof(TestInt),
            @TestInt,
            Nil) > 0 then begin
     Err := Escape(Dc,
                   GetTechnology,
                   0,
                   nil,
                   @a);
  {$ENDIF}
     if Err > 0 then begin
       s := UpperCase(StrPas(a));
       if Pos('POSTSCRIPT', s) > 0  then
         result := 0;
     end;
  end;
end;

procedure PrintPSFile(Const sFileName: PChar; PrIndex:Integer);
{ Prints a text file directly to the default printer. }
Const
  cBUFSIZE = 16384;
Type
  TDoc_Info_1 = record
    pDocName: pChar;
    pOutputFile: pChar;
    pDataType: pChar;
  end;
Var
//  Count,
//  BytesWritten: Integer;  { Delphi 1, 2, 3 }
  Count       : Cardinal;
  BytesWritten: Cardinal;
  hPrinter    : THandle;
  hDeviceMode : THandle;
  Device      : Array[0..255] Of Char;
  Driver      : Array[0..255] Of Char;
  Port        : Array[0..255] Of Char;
  DocInfo     : TDoc_Info_1;
  f           : File;
  Buffer      : Pointer;
begin
  Printer.PrinterIndex := PrIndex;
  Printer.GetPrinter(Device, Driver, Port, hDeviceMode);
  If Not WinSpool.OpenPrinter(@Device, hPrinter, Nil) Then Exit;
  DocInfo.pDocName := sfilename;
  DocInfo.pOutputFile := Nil;
  DocInfo.pDatatype := 'RAW';

  If StartDocPrinter(hPrinter, 1, @DocInfo) = 0 Then
  begin
    WinSpool.ClosePrinter(hPrinter);
    Exit;
  end;

  If Not StartPagePrinter(hPrinter) Then
  begin
    EndDocPrinter(hPrinter);
    WinSpool.ClosePrinter(hPrinter);
    Exit;
  end;

  System.Assign(f, string(sFileName));
  try
    Reset(f, 1);
    GetMem(Buffer, cBUFSIZE);
    While Not Eof(f) Do
    begin
      Blockread(f, Buffer^, cBUFSIZE, Count);
      If Count > 0 Then
      begin
        If Not WritePrinter(hPrinter, Buffer, Count, BytesWritten) Then
        begin
          EndPagePrinter(hPrinter);
          EndDocPrinter(hPrinter);
          WinSpool.ClosePrinter(hPrinter);
          FreeMem(Buffer, cBUFSIZE);
          Exit;
        end;
      end;
    end;
    FreeMem(Buffer, cBUFSIZE);
    EndDocPrinter(hPrinter);
    WinSpool.ClosePrinter(hPrinter);
  finally
    System.CloseFile(f);
  end;
end;
end.