Wenn Exe läuft, dann in den Vordergrund

[patti]

Habe leider über die Suche nichts gefunden, was mir hilft.
Ich möchte in meinem Programm überprüfen, ob ein bestimmtes Programm läuft. Von diesem Programm kenne ich allerdings nur den EXE-Namen (mit Pfad). Anschließend möchte ich - falls die EXE läuft - über ein Handle dessen Fenster in den Vordergrund holen. Wie kann ich denn das alles realisieren?

Hoffe, ihr könnt mich verstehen...
Danke, P@Tti

[Mazel]

Hallo,

hast du von dem Programm wirklich nur den Pfad oder kennst du auch den Titel? Wenn ja könntest du folgendermaßen einfach das Programm in den Vordergrund holen:
SetForeGroundWindow(FindWindow(nil, 'Programmtitel')); Wenn nicht, ist es schwierig eine Exe in den Vordergrund zu bringen, da eine Exe mehrere Fenster, was heißt das eine Exe mehrere Handles haben kann. Außerdem ist es möglich, dass das Programm mehrfach gestartet wurde und so doppelte Fensterhandles der selben Exe existieren.
Man müsste sich die die ganzen Prozesse auflisten und dann vergleiche anstellen.

Gruß
Mazel

[bitsetter]

Hallo,

kannst ja mal meinen Code testen:

Delphi-Quellcode:

uses TLHelp32;

procedure SetForeGround(ExeName: AnsiString);
type
  ProcIdList = array of cardinal;
  PProcIdList = ^ProcIdList;
    
  function EnumWin(hWnd: THandle; PIdList: PProcIdList): Boolean; stdcall;
    var
    i: integer;
    ProcId: cardinal;
  begin
    Result := True;
    if IsWindowVisible(hWnd) then//and boolean(GetWindowLong(hWnd, GWL_HWNDPARENT)) then
    begin
      for i := low(PIdList^) to high(PIdList^) do
      begin
        GetWindowThreadProcessID(hWnd, ProcId);
        if PIdList^[i] = ProcId then
           SetForeGroundWindow(hWnd);
      end;
    end;
  end;

var
  hSnapShot: THandle;
  ProcEntry: TProcessEntry32;
  ProcList: ProcIdList;
begin
  ExeName := UpperCase(ExeName);
  hSnapShot := CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0);
  try
    ProcEntry.dwSize := SizeOf(ProcEntry);
    if Process32First(hSnapShot, ProcEntry) then
      repeat
        if UpperCase(ExtractFileName(ProcEntry.szExeFile)) = ExeName then
        begin
          SetLength(ProcList,length(ProcList) + 1);
          ProcList[high(ProcList)] := ProcEntry.th32ProcessID;
        end;
      until not Process32Next(hSnapShot, ProcEntry);
  finally
    CloseHandle(hSnapShot);
  end;
  EnumWindows(@EnumWin, integer(@ProcList));
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  SetForeGround('notepad.exe');//Fenster vom Editor nach vorne bringen
end;

Wie Mazel es schon gesagt hat, kann eine Anwendung mehrere Fenster haben und das Programm kann mehrmals gestartet worden sein. Dann kann es sein, dass es dann nicht so funktioniert wie mann es möchte.

[patti]

Danke euch beiden
Werde den Code mal testen und mich dann noch mal hier melden.

P@Tti

[patti]

Hab jetzt den Code von bitsetter probiert und der klappt wunderbar. Allerdings bleibt ein Fenster, wenn es minimiert ist, auch minimiert. In der Taskleiste wird zwar dieses Programm aktiv dargestellt, allerdings wird es halt nicht selber angezeigt. Kann man das auch noch mit einbauen und wenn ja - wie?

Danke schonmal
P@Tti

[bitsetter]

Hallo,

die Function EnumWin() habe ich dazu abgeändert, diese müsstest du dann austauschen:

Delphi-Quellcode:

  ...
  function EnumWin(hWnd: THandle; PIdList: PProcIdList): Boolean; stdcall;
    var
    i: integer;
    ProcId: cardinal;
  begin
    Result := True;
    if IsWindowVisible(hWnd) then//and boolean(GetWindowLong(hWnd, GWL_HWNDPARENT)) then
    begin
      for i := low(PIdList^) to high(PIdList^) do
      begin
        GetWindowThreadProcessID(hWnd, ProcId);
          if PIdList^[i] = ProcId then
          begin//<--
            if IsIconic(hWnd) then//diese Zeile
              showWindow(hWnd, SW_RESTORE);//und diese hier
            SetForeGroundWindow(hWnd);
          end;//<--
      end;
    end;
  end;
...

Bei mir jedenfalls, funktionierte es dann.

[patti]

DANKE!!!!
Funktioniert wunderbar.
Danke, du hast mir wirklich weitergeholfen

P@Tti

[patti]

Nach etwas längerer Zeit noch eine Frage dazu:
Manche Programme minimieren sich in den Tray-Bereich der Task-Leiste. In so einem Fall funktioniert der Code leider nicht. Gibts da auch ne Lösung? Ich hab schon "rumprobiert", aber es hat nichts geklappt.

P@Tti

[Kalli]

Hi,

ich kämpfe mit einem ähnlichen Probnlem.

ich möchte das Programm in den Vordergund holen, wenn es bereits geöffnet ist.

Delphi-Quellcode:

Unit1 ....

....

Initialization
  wnd := FindWindow('TForm1','VD-Office - Antragserfassung');
  if wnd <> 0 then
  begin
    showWindow(Wnd, SW_RESTORE);
    SetForeGroundWindow(Wnd);
    halt;
  end;

end.

Das geht auch recht gut. Nur, wenn das Programm in der Tasleiste war, kann man es nicht mehr minimieren. Finde ich irgendwie nicht so gut.

Kalli