Bass aktuelle Aufnahmelautstärke

[igel457]

Hallo.
Mit folgendem Code versuche ich die akutelle Aufnahmelautstärke bei der Bass.dll zu ermitteln:

Delphi-Quellcode:

type TWaveSample = packed record
  l,r:smallint;
end;

type
  PWaveSample = ^TWaveSample;
  
// This is called while recording audio
function RecordingCallback(Handle: HRECORD; buffer: Pointer; length, user:
  DWord): boolean; stdcall;
var i:integer;
    maxl,minl,maxr,minr:smallint;
    sample:PWaveSample;
begin
  // Copy new buffer contents to the memory buffer
  WaveStream.Write(buffer^, length);

  //Calculate Peak
  sample := PWaveSample(buffer);
  for i := 0 to length div SizeOf(TWaveSample)-1 do
  begin
    if (sample^.l > maxl) or (i = 0) then maxl := sample^.l; // <--
    if (sample^.r > maxr) or (i = 0) then maxr := sample^.r;
    if (sample^.l < minl) or (i = 0) then minl := sample^.l;
    if (sample^.r < minr) or (i = 0) then maxr := sample^.r;    
    inc(sample,SizeOf(TWaveSample));
  end;
  RecordPeakLeft := abs(maxl - minl);
  RecordPeakRight := abs(maxr - minr);

  // Allow recording to continue
  Result := True;
end;

Leider bekomme ich nach einigen Sekunden an der makierten Stelle eine Zugriffsverletzung. Hat irgendjemand eine Ahnung woher die kommen könnte? "buffer" ist ein Zeiger auf 16 Bit signed PCM Daten (so steht es in der Bass Hilfe), length die Länge in Bytes.

Ich habe eigentlich jediglich die TBassPlayer Komponente von TurboPascal angepasst.

Schonmal Danke,
igel457

[igel457]

Ich stehe nun echt auf dem Schlauch:

Delphi-Quellcode:

// This is called while recording audio
function RecordingCallback(Handle: HRECORD; buffer: Pointer; length, user:
  DWord): boolean; stdcall;
var i:integer;
    maxl,minl,maxr,minr:smallint;
    sample:TWaveSample;
begin
  for i := 0 to length div 4 do
  begin
    sample.l := round(sin(i/10) * high(smallint)/2);
    sample.r := round(cos(i/10) * low(smallint)/2);
    WaveStream.Write(sample,4);
  end;

  // Allow recording to continue
  Result := True;
end;

Dieser Code erzeugt ein die von mir gewünschte Cos/Sin Wellenform. Warum kann ich die Daten mit meiner Struktur nicht richtig auslesen, aber schreiben?

[igel457]

Also ich habs...

So gehts es nun. Es waren ein paar kleinere Fehlerchen. Wer den Code gebrauchen kann, schaut hier:

Delphi-Quellcode:

type TWaveSample = record
  l,r:smallint;
end;

type
  PWaveSample = ^TWaveSample;

var
  RecordPeakLeft,RecordPeakRight:integer;
  
// This is called while recording audio
function RecordingCallback(Handle: HRECORD; buffer: Pointer; length, user:
  DWord): boolean; stdcall;
var i:integer;
    maxl,minl,maxr,minr:smallint;
    sample:PWaveSample;
begin
  // Copy new buffer contents to the memory buffer
  WaveStream.Write(buffer^, length);

  //Calculate Peak
  sample := buffer;
  for i := 0 to length div 4 - 1 do
  begin
    if (sample^.l > maxl) or (i = 0) then maxl := sample^.l;
    if (sample^.r > maxr) or (i = 0) then maxr := sample^.r;
    if (sample^.l < minl) or (i = 0) then minl := sample^.l;
    if (sample^.r < minr) or (i = 0) then minr := sample^.r;
    inc(sample,1);
  end;
  RecordPeakLeft := abs(maxl-minl);
  RecordPeakRight := abs(maxr-minr);

  // Allow recording to continue
  Result := True;
end;