Anfängerfrage wegen TStringList

[MaGe]

Moin, moin,

nachdem ich in Delphiforen immer wieder auf CD/Musik - Verwaltungsprogramme in Rahmen von Fragen gestossen bin, dachte ich mir probier ich halt auch mal das "Hello World"-Delphi Program.
Soweit so gut, nun stosse ich wohl gerade auf ein total triviales Problem wo ich - uhh- einfach nicht weiter weiss und meine versuche in meiner Delphi7 offline Hilfe, meine schlaues Buch und die Forensuche hier nicht weiter hilft. (Bestimmt steht hier die Lösung irgendwo aber ich finde die nicht )
Ich hab folgende Klasse:

Delphi-Quellcode:

type
  TCD = class(TObject)
    interpret : string;
    albumTitle  : string;
    genre       : string;
    songTitles  : TStringList;
public
// set values interpret, albumtitle, genere, songList
    procedure setValues(interpreter, album, musictype : string; songTitle : TStrings);
// gets the value of the actual selectet CD
    procedure getValues(var interpreter, album, musictype : string;var songTitle : TStringList);
  end;
var
  CD          : TCD;
  CDList      : TObjectList;  
...
procedure TCD.setValues(interpreter, album, musictype : string; songTitle : TStrings);
begin
      self.interpret := interpreter;
      self.albumTitle := album;
      self.genre := musictype;
      self.songTitles:= TStringList.Create;
      self.songTitles.assign(songTitle);
end; // end setValues
procedure TCD.getValues(var interpreter, album, musictype : string; var songTitle : TStringList);
var i : Integer;
begin
    interpreter := self.interpret;
    album := self.albumTitle;
    musictype := self.genre;
    songTitle.Assign(self.songTitles);
end; // end getValues

Mit folgendem Testbutton auf einer Form

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  s1,s2,s3,s4,s5,s6: String;
  slist1 :TStrings;
  slist2 :TStringList;
  mycd : TCD;
  cd1 : TCD;
begin
    mycd := TCD.Create;
    slist1 := TStringList.Create;
    slist1.add('Testsong');
    mycd.setValues('Inter','Album','MTyp',slist1);
  
    mycd.getValues(s1,s2,s3,slist2);
    ShowMessage(s1+' '+s2+' '+s3+' '+slist2.Text);

    CDList.Add(mycd);
    cd1:= TCD(CDList.First);
    cd1.getValues(s4,s5,s6,slist2);
    ShowMessage('aus der CDlist:'+s4+s5+s6+slist2);
    
end;

Wenn ich jetzt meine Testprozedur laufen lasse bekomme ich immer die Fehlermeldung dass ich auf Speicheradresse 000000 von Speicheradresse 000000 zugreife. Okay soweit ich es rausfinde fliegt die Exception beim letzen ShowMessage aufruf wenn ich slist2 drin habe, ergo läuft die Übergabe falsch, aber ich hab keine Ahnung was ich da falsch mache und mir raucht schon der Schädel.
Wäre einer so nett und kann mir helfen?

Gruß

Ma.Ge.

[mkinzler]

Wo erzeugst du CDList?

[Khabarakh]

Ich weiß nicht, ob CDList erstellt wurde, aber slist2 auf keinen Fall. Die var-Modifier in deinen Funktionsköpfen kannst/solltest du übrigens weglassen - oder noch besser statt der zwei Funktionen einfach vier Properties benutzen .

[MaGe]

@mKinzler
Also CDList wird via CDList := TObjectList.Create; in TForm1.FormCreate erzeugt.

@Khabarakh
slist2 auch via Create erzeugen nehme ich an, hab ich wohl total vergessen, oha.
Properties - hmm, da bin ich wohl noch nicht fit, wie müsste ich da vorgehen? Dachte ich Kapsel die Objektattribute via getter & setter Methoden, obwohl ich ja streng genommen meinen Programm die Attribute ja nicht unter privat deklariert habe. Ich mach mich mal schlau und werde wohl die Tage nochmals nachfragen.

Gruß

Ma.Ge

[Christian Seehase]

Moin MaGe,

ich schlage mal vor, dass Du Deine Klasse erst einmal ein wenig aufräumst

Daten die in der Klasse abgelegt werden gehören in private Felder, und der Zugriff darauf wird dann über Properties geregelt.
Und so etwas:
songTitles : TStringList; sollte über den Constructor initialisiert, und über den destructor wieder freigegeben werden.
Ansonsten erzeugst Du bei jedem SetValues ein neues StringList-Objekt und überschreibst den Pointer auf das vorherige, was dann zu "wunderbaren" Speicherlöchern führt.

Wichtig:
Innerhalb Deiner Klasse sprichst Du nur direkt die internen Felder an (daher, üblicher weise, mit F beginnend), und keinesfalls die Properties.
Wenn Du innerhalb der Klasse die Properties ansprichst könntest Du Dir, wenn Du mit Getter- und Setter-Methoden für read/write arbeitest, eine prima Endlosschleife einhandlen.

Delphi-Quellcode:

Einfachste Variante
TCD = class(TObject)
private
  FsInterpret   : string;
  FslSongtitles : TStringlist;
  //...
  function GetSongtitle(iIndex : integer);
  procedure SetSongtitle(iIndex : integer;Value : string);
public
  constructor Create;
  destructor Destroy; override;
  property Interpret : string read FsInterpret write FsInterpret;
  property Songtitle[iIndex : integer] : string read GetSongtitle write SetSongtitle;
end;


constructor TCD.Create;
begin
  inherited;
  FslSongtitles := TStringList.Create;
end;

destructor TCD.Destroy;
begin
  FslSongtitles.Free;
  inherited;
end;

function TCD.GetSongtitle(iIndex : integer);
begin
  Result := FslSongtitles[iIndex];
end;

procedure TCD.SetSongtitle(iIndex : integer;Value : string);
begin
  FslSongtitles[iIndex] := Value;
end;

[MaGe]

Danke erstmal für die Ausführliche Email!
Wo es bei mir nur hakt ist, die Stringliste. Ähm da blick ich gerade nix mehr im Quellcode, denn wenn ich das richtig kapiert habe häng ich via
 Delphi-Syntax: function Add(const S: string): Integer; override; einen String an. Wäre dann nicht in Funktion:

Delphi-Quellcode:

procedure TCD.SetSongtitle(iIndex : integer;Value : string);
begin
  FslSongtitles[iIndex] := Value;
end;

Sinniger:

Delphi-Quellcode:

procedure TCD.SetSongtitle(iIndex : integer;Value : string);
begin
  FslSongtitles.add(Value);
end;

zu schreiben?

Vielen Dank noch, hast mir schön die Properties nahegebracht, das konzept gefällt mir sehr!

[Thorben_K]

Das eine hat mit dem anderen nichts zu tun

Du hast eine List die sieht so aus


Index Wert
0 a
1 b
2 c
3 d

mit Add fügst du einen NEUEN dazu

also

4 e

mit der Setter methode Editierst du einen bestehenden eintrag, zum Beispiel machst du so aus

0 a

0 b

Add hinzufügen, also den Speicher erweiter, Setter methode einen bestehenden Eintrag ändern/bearbeiten

Gruss Thorben

[MaGe]

Vielen Dank für die Erklärung, ich habs hoffentlich endlich kapiert! Hab mich wohl als völliger Anfänger geoutet.