Access violation bei der Auflistung von Dateien

[fdsgbla]

Warum kommt es bei der Funktion:

Delphi-Quellcode:

function VerzGroesse(Verzeichnis:string):longint;
var SR      : TSearchRec;
    Groesse : longint;
begin
  Groesse:=0;
  if Verzeichnis[length(Verzeichnis)]<>'\' then
    Verzeichnis:=Verzeichnis+'\';
  if FindFirst(Verzeichnis+'*.*',$3F,SR)=0 then begin
    repeat
      if ((SR.Attr and faDirectory)>0) and (SR.Name<>'.') and (SR.Name<>'..') then
        Groesse:=Groesse+VerzGroesse(Verzeichnis+SR.Name)
      else
        Groesse:=Groesse+SR.Size;
      if (SR.Name<>'.') and (SR.Name<>'..') then
        FileListArray.Add(Verzeichnis+SR.Name);
    until FindNext(SR)<>0;
    FindClose(SR);
  end;
  Result:=Groesse;
end;

(stammt von http://www.delphi-fundgrube.de/faq03.htm#topic0310)

zu "Access violation" - Fehler

sie wird mit: self.caption := IntToStr(VerzGroesse('C:\Program Files\'))+' Byte'; aufgerufen. Der Ordner "Program Files" existiert und ist nicht leer.

[SirThornberry]

die einzige Stelle wo der Fehler auftreten kann ist bei
FileListArray.Add(Verzeichnis+SR.Name); FileListArray ist vermutlich nicht initialisiert.

[fdsgbla]

Zitat von SirThornberry:

die einzige Stelle wo der Fehler auftreten kann ist bei
FileListArray.Add(Verzeichnis+SR.Name); FileListArray ist vermutlich nicht initialisiert.

so war es auch. Danke!!!!!!

[Hawkeye219]

Hallo,

du solltest auch beachten, daß die Routine bei Verzeichnisgrößen ab 2 GB falsche Werte liefert, weil sie alle Berechnungen mit dem Typ longint durchführt. Damit auch größere Verzeichnisse verarbeitet werden können, muß zunächst überall "longint" durch "int64" ersetzt werden. Wird der Code mit einer Delphi-Version vor Delphi 2006 übersetzt, muß eine weitere Zeile angepaßt werden:

Delphi-Quellcode:

// Groesse := Groesse + SR.Size; 
Groesse := Groesse + Int64(SR.FindData.nFileSizeHigh) shl 32 + SR.FindData.nFileSizeLow;

Gruß Hawkeye

[fdsgbla]

Zitat von Hawkeye219:

Hallo,

du solltest auch beachten, daß die Routine bei Verzeichnisgrößen ab 2 GB falsche Werte liefert, weil sie alle Berechnungen mit dem Typ longint durchführt. Damit auch größere Verzeichnisse verarbeitet werden können, muß zunächst überall "longint" durch "int64" ersetzt werden. Wird der Code mit einer Delphi-Version vor Delphi 2006 übersetzt, muß eine weitere Zeile angepaßt werden:

Delphi-Quellcode:

// Groesse := Groesse + SR.Size; 
Groesse := Groesse + Int64(SR.FindData.nFileSizeHigh) shl 32 + SR.FindData.nFileSizeLow;

Gruß Hawkeye

Auch Danke

Zählt TurboDelphi auch zu Delphi 2006?

[mkinzler]

Zitat:

Zählt TurboDelphi auch zu Delphi 2006?

Ja.

[Christian Seehase]

Moin fdsgbla,

mal abgesehen von dem 2GB Problem hat die Routine noch ein paar mehr:

Delphi-Quellcode:

function VerzGroesse(Verzeichnis:string):longint;
var SR      : TSearchRec;
    Groesse : longint;
begin
  Groesse:=0;
  // Wenn Verzeichnis = '' => AV
  if Verzeichnis[length(Verzeichnis)]<>'\' then
    Verzeichnis:=Verzeichnis+'\';
  // Warum $3F, wenn es dafür eine Konstante gibt (faAnyfile)
  if FindFirst(Verzeichnis+'*.*',$3F,SR)=0 then begin
   // Es fehlt try/finally um die Ausführung von FindClose abzusichern,
   // wenn FindFirst erfolgreich war
    repeat
      // > 0 funktioniert hier zwar, besser ist aber <> 0
      // oder = faDirectory. Der Wert könnte auch negativ sein
      if ((SR.Attr and faDirectory)>0) and (SR.Name<>'.') and (SR.Name<>'..') then
        Groesse:=Groesse+VerzGroesse(Verzeichnis+SR.Name)
      else
        Groesse:=Groesse+SR.Size;
      // Da . und .. immer Verzeichnisse sind gehört das auch in die
      // vorherige if-Abfrage
      if (SR.Name<>'.') and (SR.Name<>'..') then
        FileListArray.Add(Verzeichnis+SR.Name);
    until FindNext(SR)<>0;
    FindClose(SR);
  end;
  Result:=Groesse;
end;

Es sollte besser so (oder ähnlich aussehen):

Delphi-Quellcode:

function VerzGroesse(Verzeichnis:string):longint;
var SR      : TSearchRec;
    Groesse : longint;
begin
  Groesse:=0;
  if (Length(Verzeichnis) > 0) and Verzeichnis[length(Verzeichnis)]<>'\' then Verzeichnis:=Verzeichnis+'\';
  if FindFirst(Verzeichnis+'*.*',faAnyFile,SR) = 0 then begin
    try
      repeat
        if ((SR.Attr and faDirectory) <> 0) and (SR.Name <> '.') and (SR.Name <> '..') then begin
          Groesse:=Groesse+VerzGroesse(Verzeichnis+SR.Name);
          FileListArray.Add(Verzeichnis+SR.Name);
        end else begin
          Groesse:=Groesse+SR.Size;
        end;
      until FindNext(SR)<>0;
    finally
      FindClose(SR);
    end;
  end;
  Result:=Groesse;
end;

Wobei auch diese Variante möglich wäre

Delphi-Quellcode:

function VerzGroesse(Verzeichnis:string):longint;
var SR      : TSearchRec;
    Groesse : longint;
begin
  Groesse:=0;
  if FindFirst(Verzeichnis+'\*.*',faAnyFile,SR) = 0 then begin
    try
      repeat
        if ((SR.Attr and faDirectory) <> 0) and (SR.Name <> '.') and (SR.Name <> '..') then begin
          Groesse:=Groesse+VerzGroesse(Verzeichnis+SR.Name);
          FileListArray.Add(Verzeichnis+SR.Name);
        end else begin
          Groesse:=Groesse+SR.Size;
        end;
      until FindNext(SR)<>0;
    finally
      FindClose(SR);
    end;
  end;
  Result:=Groesse;
end;

da mehrere aufeinander folgende Pfadtrenner (\) nicht stören, so dass Verzeichnis auf \ enden, und man trotzdem die Suchmaske \*.* verwenden kann.

[Hawkeye219]

Moin Chris,

Zitat von Christian Seehase:

[...]da mehrere aufeinander folgende Pfadtrenner (\) nicht stören[...]

mehrere aufeinander folgende nicht, ein vergessener schon:

Delphi-Quellcode:

// Groesse:=Groesse+VerzGroesse(Verzeichnis+SR.Name);
// FileListArray.Add(Verzeichnis+SR.Name); 
Groesse:=Groesse+VerzGroesse(Verzeichnis+'\'+SR.Name);
FileListArray.Add(Verzeichnis+'\'+SR.Name);

Gruß Hawkeye

[Christian Seehase]

Moin Hawkeye,

da hast Du auch wieder recht.

[fdsgbla]

Nochmals Danke