Services(Dienste) auslesen EnumServicesStatusEx

[daPimP]

Alle Dienste auflisten (mit PID!!!)

Musste gerade feststellen, dass aller Anschein nach DELPHI 7 Enterprise nur über die alte Funktion EnumServicesStatus verfügt und NICHT über EnumServicesStatusEX , welche mehr Informationen abfragt.

Gibt es eine Möglichkeit, an die Funktion ranzukommen? Ich denke Sie sollte in der WINSVC.pas drinne stehen, aber AB welcher Delphi Version?

Oder kann man die Datei rechtefrei updaten - also auf den neuesten Stand bringen?


Für alle Nachfolgenden Suchenden:

Der Unterschied steht hier:
msdn

Die Lösung mit der einfachen Funktion EnumServicesStatus ist diese:

Code:

Unit winsvc

type
  // für selbstimportierte Funktion erforderlich
  PENUM_SERVICE_STATUS = ^TEnumServiceStatus;

  // Funktion selber importieren, da die Borland Version nur den ersten zugreifbar macht
  function EnumServicesStatus(
    const hSCManager         : DWord;                // handle to SCM database
    const dwServiceType      : DWord;                // service type
    const dwServiceState     : DWord;                // service state
    const lpServices         : PENUM_SERVICE_STATUS; // status buffer
    const cbBufSize          : DWord;                // size of status buffer
    const pcbBytesNeeded     : PDWORD;               // buffer size needed
    const lpServicesReturned : PDWord;               // number of entries returned
    const lpResumeHandle     : PDWord                // next entry
    ) : Boolean; stdcall; external 'advapi32.dll' name 'EnumServicesStatusA';

implementation

{$R *.DFM}

procedure EnumServices(const AsComputerName : string);

var
  hSCDB              : DWORD;
  pStatus            : PENUM_SERVICE_STATUS;
  pWork              : PENUM_SERVICE_STATUS;
  cbBufSize          : DWORD;
  pcbBytesNeeded     : DWORD;
  lpServicesReturned : DWORD;
  lpResumeHandle     : DWORD;
  iCount             : integer;

begin
  Form1.ListBox1.Items.Clear;
  hSCDB := OpenSCManager(
    PChar('\\'+AsComputerName),  // Dienste des angegebenen Rechners auslesen
    nil,                         // Standarddatenbank nehmen
    SC_MANAGER_ENUMERATE_SERVICE // Dienste aufzählen (alle durchgehen)
      or                         // ausserdem
    GENERIC_READ);               // genügt es die Daten nur zu lesen
  if hSCDB <> 0 then begin
    try
      // Erforderlichen Speicherplatz für alle Daten von der Funktion ermitteln lassen
      // ==> gezielt mit 0 Byte Buffer fehlschlagen lassen
      cbBufSize      := 0;
      pStatus        := nil;
      lpResumeHandle := 0;
      EnumServicesStatus(hSCDB,SERVICE_WIN32,SERVICE_STATE_ALL,pStatus,cbBufSize,@pcbBytesNeeded,@lpServicesReturned,@lpResumeHandle);
      lpResumeHandle := 0;

      // speicher reservieren
      pStatus   := AllocMem(pcbBytesNeeded);
      try
        cbBufSize := pcbBytesNeeded;
        EnumServicesStatus(
          hSCDB,             // Handle von OpenSCManager
          SERVICE_WIN32,     // Nur Dienste, keine Treiber
          SERVICE_STATE_ALL, // Alle installierten Dienste, egal ob sie laufen oder nicht
          pStatus,cbBufSize,@pcbBytesNeeded,@lpServicesReturned,@lpResumeHandle);
        // Adresse merken, damit der Speicher später wieder freigegeben werden kann, ohne den Pointer
        // wieder zurückrechnen zu müssen
        pWork := pStatus;
        // Alle Dienste in Listbox anzeigen (mit Namen und Anzeigenamen)
        for iCount := 1 to lpServicesReturned do  begin
          Form1.ListBox1.Items.Add(pWork.lpServiceName+'/'+pWork.lpDisplayName);
          inc(pWork);
        end;
      finally
        if Assigned(pStatus) then FreeMem(pStatus,pcbBytesNeeded);
      end;
    finally
      CloseServiceHandle(hSCDB);
    end;
  end;
end;

weitere Infos:
Thema

[Die Muhkuh]

Kannst Du die entsprechende Funktion nicht aus einer Windows DLL laden?

Hier im MSDN.

[daPimP]

Um das besser zu verstehen:

Ich ändere die zu importierende Funktion in EnumServicesStatusEx um, und benenne einfach alle EnumServicesStatus in EnumServicesStatusEx.

Dann arbeite ich die neuen Optionen von EnumServicesStatusEx ein.

Aber was

Delphi-Quellcode:

BOOL WINAPI EnumServicesStatusEx(
  SC_HANDLE hSCManager,
[b]  SC_ENUM_TYPE InfoLevel,[/b]
  DWORD dwServiceType,
  DWORD dwServiceState,
  LPBYTE lpServices,
  DWORD cbBufSize,
  LPDWORD pcbBytesNeeded,
  LPDWORD lpServicesReturned,
  LPDWORD lpResumeHandle,
[b]  LPCTSTR pszGroupName[/b]
);

Die dick markierten sind die neuen Optionen - aber welche Delphi
- const/var sind das nach Delphi übersetzt?

LPDWORD = Dword is klar aber
LPCTSTR = ?
SC_ENUM_TYPE = ?;

Oder hab ich einen Denkfehler?

[Christian Seehase]

Moin daPimP,

mir kam der Sourcecode doch gleich so bekannt vor

Dann will ich auch mal hier die Übersetzung erstellen:

Delphi-Quellcode:

type
  SC_ENUM_TYPE = (SC_ENUM_PROCESS_INFO = Cardinal(0));

  function EnumServicesStatusEx(
    const hSCManager         : SC_HANDLE;
    const InfoLevel          : SC_ENUM_TYPE;
    const dwServiceType      : DWORD;
    const dwServiceState     : DWORD;
    const lpServices         : PBYTE;
    const cbBufSize          : DWORD;
    const pcbBytesNeeded     : LPDWORD;
    const lpServicesReturned : LPDWORD;
    const lpResumeHandle     : LPDWORD;
    const pszGroupName       : LPCTSTR
  ) : LongBool; stdcall; external 'advapi32.dll' name 'EnumServicesStatusExA';

Nicht zu vergessen WinSvc in den Uses mit einzubinden.

Ich importiere die Funktionen immer mit const. An den Stellen, an denen ein Pointer übergeben werden soll, findet man oft auch var, aber dann muss man eine Variable angeben, auch wenn die Funktion durchaus nil als übergebenen Wert zulassen würde.
Durch die Verwendung von const fällt es mir leichter eventuelle Beispiele umzusetzen.

Statt LPCTSTR kann man auch PCHAR nehmen.

[Der_Unwissende]

Zitat von daPimP:

Um das besser zu verstehen:

Ich ändere die zu importierende Funktion in EnumServicesStatusEx um, und benenne einfach alle EnumServicesStatus in EnumServicesStatusEx.

Dann arbeite ich die neuen Optionen von EnumServicesStatusEx ein.

Hi,
es kommt ein wenig so rüber, als ob Du meinst, dass man die alte Funktion einfach ersetzen sollte, da dies hier eine neuere Version ist. Nur es noch mal deutlich zu sagen, es ist nur eine zweite (erweiterte) Funktion. Obwohl es wenig System noch betreffen dürfte, so sollte doch noch mal betont werden, dass es die alte Version noch gibt und Windows NT und die NT Server nur die Version ohne Ex unterstützen, erst ab Windows 2000 / Server 2000 wird auch die EnumServiceStatusEx unterstüzt.

Zitat von daPimP:

LPDWORD = Dword is klar aber

Oder hab ich einen Denkfehler?

Hier hat Christian Seehase Dir ja schon gezeigt, dass es diese Datentypen auch in Delphi gibt, aber an sich wäre ein LPDWORD ein Zeiger auf ein DWORD, nicht direkt ein DWORD (deswegen am besten die Datentypen nehmen, wie sie Delphi mitbringt).

Gruß Der Unwissende

[daPimP]

Danke euch Beiden.


@Der_Unwissende: EnumServicesStatusEx IST die neue erweiterte Funktion - selbstverständlich existiert EnumServicesStatus noch parallel. Doch da ich eh erst Windows 2000 aufwärts programmiere, ist die Kompatibilität mit alten Versionen zu vernachlässigen.
Ich sag nur:

Zitat:

EnumServicesStatus has been superseded by the EnumServicesStatusEx function.

@Christian Seehase: Den Code werde ich jetzt mal auf meine Funktion eingebaute Funktion zuschustern, da ich deinen Code nur als Beispiel reinkopiert habe. Aber mir gings auch mehr um das Verständnis des Imports und der Benennung der Datentypen.