.dcu Datei aus .pas erstellen

[jbg]

Zitat von mkinzler:

Liegt die ToolsApi auch im Bibliothekspfad? (Darf nicht)
Vielleicht liegt es auch an Vista.

Das eigentliche Problem ist, dass das Package in ein Design- und ein Runtime-Package gesplittet werden muss. Man kann zur Laufzeit (eigenes Programm) keinen Designtime-Code (Code der in der IDE läuft) nutzen. Das untersage die Lizenz und Borland hat das auch technisch verhindert.

Zitat:

Aha, davon habe ich auch schonmal gehört. Leider habe ich es auch mit Anleitung nicht hinbekommen...könntest du mir da womöglich helfen?

• 1. Öffne die Projektoptionen des Packages und wähle unter "Verwenden für" den Eintrag "Laufzeit" aus. Dialog mit OK bestätigen.
• 2. Entferne "designide" aus der requires-Liste
• 3. Kopiere die SmartListView Unit und benenne die Kopie mit "SmartListViewReg.pas"
• 4. Öffne die original Unit und entferne den "DesignEditors" und "DesignIntf" (sofern verwendet) aus den Uses-Klauseln.
• 5. Entferne den PropertyEditor und die Register-Funktion
• 6. Kompiliere das Package (alles was Fehler meldet einfach entfernen)
  
• 6. Erzeuge ein neues Package (Datei/Neu/Package)
• 7. Öffne die Projektoptionen und wähle unter "Verwenden für" den Eintrag "Entwurfszeit" aus. Dialog mit OK bestätigen.
• 8. Füge "designide" zur requires-Liste hinzu
• 9. Füge das Laufzeit-Package zur requires-Liste hinzu
• 10. Füge die SmartListViewReg.pas zum Entwurfszeitpackage hinzu
• 11. Öffne die SmartListViewReg.pas und entferne die Komponente, behalte aber alles, was du vorhin aus der anderen Datei entfernt hast.
• 12. Füge die original-Unit in die uses-Klausel der SmartListViewReg.pas Datei hinzu.
• 13. (Kompiliere und) Installiere das Laufzeitpackage

Ach ja, und lösche alle .dcu Dateien die du aus dem ToolsAPI Ordner erzeugt hast.

[Yheeky]

Hi jbg,

wow, super Beschreibung...danke, dass du dir soviel Zeit genommen hast.
Klingt auch alles logisch, nur leider wird immer noch die Proxies.dcu vermisst

Habe dir mal einen Screenshot vom Aufbau meiner Packages gemacht. Das Package SmartLV ist das Laufzeit und SmartLV_D10 ist das Entwurfspackage, welches ich kompiliere/installiere.

[jbg]

Zitat von Yheeky:

nur leider wird immer noch die Proxies.dcu vermisst

Das tritt bei mir nicht auf.

[Yheeky]

Es ist vollbracht!
Nun geht´s! ABER!!!

Ich musste bei den beiden Packages die Einstellungen ändern. Ich musste das Entwurfspackage zum Laufzeitpackage machen und umgekehrt. Kannst du dir das erklären?
Nun funktioniert alles. Ich denke ich habe da nun auch etwas bei der Thematik durchgeblickt. Habe soeben auch noch eine eigene gestrickte Version OHNE DesignIntf und DesignEditors hinbekommen.

Danke nochmal an jbg und allen anderen, die mir hier geholfen haben!

[MaBuSE]

Zitat von Yheeky:

Hi jbg,
wow, super Beschreibung...danke, dass du dir soviel Zeit genommen hast.
Klingt auch alles logisch, nur leider wird immer noch die Proxies.dcu vermisst

Hallo, ich habe Deine PN erhalten und antworte hier:

jbg hat Recht! So wie er es beschrieben hat funktioniert es.

Es gibt nur eine kleine Tücke, die der Programmierer eingebaut hat.
Er verwendet den Property Editor in der Komponente.
So was macht man nicht !!!

Es gibt wie immer im Leben mehrere Lösungen.
Ich stelle hier 2 Lösungen vor.

1. Quick and Dirty
2. So wird's richtig gemacht

Beim Ansehen des Quelltextes sieht man es geht eigentlich "nur" um den About Box Dialog der Komponente.

Im Property Editor steht bei About nur ein "(About)", wenn man in die Property geht, erscheint ein Button mit 3 Punkten [...].
Wird auf diesen Button gedrückt, erscheint ein Dialog in dem die Versionsnummer und das Copyright des Autors zu lesen ist.

• Lösung 1: Quick and Dirty
  
  • Ansatz: "Wozu brauch ich einen About Dialog. Ist mir ja egal, wer die Komponente programmiert hat."
    
  • Vorgehensweise wie bei jbg:
    Entferne alles, was der Compiler anmeckert.
    Ich habe es durch Voranstellen eines "//" auskommentiert.
    
  • nur ein Package, das kann ein Entwurfs- und Laufzeitpackage sein.
    
  • -> Datei: "Quick and Dirty.zip" im Anhang
• Lösung 2: So wird's richtig gemacht
  
  • Ansatz: "Ich möchte die Funktion des About Dialogs erhalten."
    
  • Vorgehensweise wie bei jbg:
    Entferne alles, was der Compiler anmeckert.
    Ich habe es durch Voranstellen eines "//" auskommentiert.
    
  • Ausnahmen:
    
    Delphi-Quellcode:

    ...
    type
      TSmartListView = class(TListView)
      private
    //    FAbout: TAboutButtonProperty;
    // neues About Property
        FAbout: string;
    //--
    ...
    published
    ...
    //    property About: TAboutButtonProperty read FAbout write FAbout;
    // neues About Property
        property About: string read FAbout write FAbout;
    //--
      end;
    ...

    Zusätzlich wird die komplette Register Procedure entfernt.
    Das Ganze wird in ein Package gepackt, was in den Optionen als "Laufzeitpackage" gekennzeichnet wird.
    Das Package kompiliert -> fertig mit dem Laufzeitpackage.
    
  • Nun brauchen wir ein Entwurfszeitpackage.
    In das Entwurfszeitpackage fügen wir nun die auskommentierten Stellen des Quelltextes ein.
    
  • Wichtig: Die Unit mit der Komponente muss natürlich in der uses Zeile eingebunden werden.
    
  • Wichtig: Die Zeile mit dem RegisterPropertyEditor muss geändert werden.
    Da die Eigenschaft About in der Komponente nun vom Typ string ist, muss beim Zuweisen des PropertyEditor natürlich auch string angegeben werden. -> TypeInfo(string)
    
    Das Package wird als Entwurfszeitpackage gekennzeichnet und lässt sich nun kompilieren.
    
  • -> Datei: "So wirds richtig gemacht.zip" ist im Anhang
    
  • Installation:
    1. Laufzeitpackage kompilieren. (Installieren geht nicht, da es nix zu installieren gibt.)
    2. Entwurfszeitpackage kompilieren
    3. Entwurfszeitpackage installieren -> Fertig
  
  
  Delphi-Quellcode:

  ...
  unit SmartListView_AboutDialog;
  
  interface
  
  uses
    Forms, Classes, Windows, SysUtils, SmartListView, DesignIntf, DesignEditors;
  
  type
    TAboutButtonProperty = class(TPropertyEditor)
    public
      procedure Edit; override;
      function GetAttributes: TPropertyAttributes; override;
      function GetValue: string; override;
    end;
  
  procedure Register;
  
  implementation
  
  procedure Register;
  begin
    RegisterComponents('Samples', [TSmartListView]);
    RegisterPropertyEditor(TypeInfo(string), TSmartListView, 'ABOUT', TAboutButtonProperty);
  end;
  
  procedure TAboutButtonProperty.Edit;
  var
     AboutTitle,
     AboutDesc: String;
  begin
     AboutTitle := 'About TSmartListView';
     AboutDesc := 'TSmartListView (Version 1.01)'+
     ^M^M+'Copyright © 1999 by Fabio De Pasquale'+
     ^M+ '<[e-mail]>'+
     ^M+ '<[e-mail]>' +
     ^M+ 'Check "http://members.xoom.com/MadElectron"'+
     ^M+ 'for latest version.';
  
     Application.MessageBox(PChar(AboutDesc), PChar(AboutTitle), MB_OK+ MB_ICONINFORMATION);
  end;
  
  function TAboutButtonProperty.GetAttributes: TPropertyAttributes;
  begin
      Result := [paMultiSelect, paDialog, paReadOnly];
  end;
  
  function TAboutButtonProperty.GetValue: string;
  begin
     Result := '(About)';
  end;
  
  
  end.

[MaBuSE]

Zitat von Yheeky:

Es ist vollbracht!
Nun geht´s!

Glückwunsch.
Ich war mal wieder 5 Min. zu langsam

Trotzdem lies Dir mal meinen Beitrag durch, ich habe versucht es zu erklären.

In meinem Tutorial steht es ja eigentlich auch schon drinn.

Designtime Units (Property Editoren) haben in der Anwendung nichts zu suchen.
Deshalb muß man 2 Packages draus machen oder auf die Editoren verzichten.

mfg
MaBuSE

[Yheeky]

Danke auch dir für die Mühe, die du dir gemacht hast. Die Beschreibung ist super!
Ich denke du könntest das noch in dein Tutorial nehmen (wenn es das ist, worauf ich auch in der PN eingegangen bin), denn das ist hier noch besser erklärt, finde ich.

Besten Dank nochmal!