StringReplace mit Tücken ... Lösung gesucht ...

[moelski]

Moin !

Ich bin da eben auf ein tückisches Problem gestossen ...

Gegeben sie diese Funktion:

Delphi-Quellcode:

function TLVELV_HET20.MakeCorrectString(const Data: String): String;
var Erg: String;
begin
  Erg := ReplaceStr(Data, #05#18, #02);
  Erg := ReplaceStr(Erg, #05#19, #03);
  Erg := ReplaceStr(Erg, #05#21, #05);   <---- 

  MakeCorrectString := Erg;
end;

Weiterhin nehmen wir mal diesen Hex String ...

Zitat:

02 05 15 15 07 B2 .....

Diesen Hexstring übergeben wir der Funktion mal und was kommt raus ... Mist
Denn ReplaceStr ersetzt 05 15 durch 05.
Dann haben wir den String 02 05 15 07 B2
Nun steht da aber abermals dummerweise 05 15 und schwupps macht ReplaceStr
daraus wieder ein 05. In dem Fall will ich das aber nicht.

Nu habe ich ein Problem ... Wie kann ich sowas vernindern? Ich möchte also in einem String Teile ersetzen, aber über das resultierenden Ergebnis soll nicht wieder ein ReplaceStr gemacht werden.

Was kann ich nun tun !?

[himitsu]

Wenn es nicht möglich ist die Reiheinfolge der StringReplace so zu ändern, daß sich gegenseitig keine Beeinträchtigungen ergeben,

dann mußt du wohl selber durch den String gehen und alles manuell ersetzen.
Also alles gleichzeitig und nicht nicht nacheinander.

z.B.:

Delphi-Quellcode:

For i := 1 to Length(S) do
  If Copy(S, i, 2) = #05#18 Then Begin
    Delete(S, i, 1);
    S[i] := #02;
  End Else If Copy(S, i, 2) = #05#19 Then Begin
    Delete(S, i, 1);
    S[i] := #03;
  End Else If Copy(S, i, 2) = #05#21 Then Begin
    Delete(S, i, 1);
    S[i] := #05;
  End;

oder

Delphi-Quellcode:

i1 := Pos(#05#18, S);
i2 := Pos(#05#19, S);
i3 := Pos(#05#21, S);
While (i1 > 0) or (i2 > 0) or (i3 > 0) do 
  i = der kleinste Wert(i1,i2,i3) der nicht 0 ist;
  If i = i1 Then ...
  Else If i = i2 Then ...
  Else If i = i3 Then ...
  i1 := PosEx(#05#18, S, i + 1);
  i2 := PosEx(#05#19, S, i + 1);
  i3 := PosEx(#05#21, S, i + 1);
End;

oder

Delphi-Quellcode:

i1 := Pos(#05#18, S);  If i1 = 0 Then i1 := MaxInt;
i2 := Pos(#05#19, S);  If i2 = 0 Then i2 := MaxInt;
i3 := Pos(#05#21, S);  If i3 = 0 Then i3 := MaxInt;
While (i1 <> MaxInt) or (i2 <> MaxInt) or (i3 <> MaxInt) do 
  i := Min(i1, Min(i2, i3);
  If i = i1 Then ...
  Else If i = i2 Then ...
  Else If i = i3 Then ...
  i1 := PosEx(#05#18, S, i + 1);  If i1 = 0 Then i1 := MaxInt;
  i2 := PosEx(#05#19, S, i + 1);  If i2 = 0 Then i2 := MaxInt;
  i3 := PosEx(#05#21, S, i + 1);  If i3 = 0 Then i3 := MaxInt;
End;

oder ...

(bei langen Strings werden die Pos/PosEx-Varianten mit Sicherheit schneller sein)

[moelski]

Delphi-Quellcode:

For i := 1 to Length(S) do 
  If Copy(S, i, 2) = #05#18 Then Begin 
    Delete(S, i, 1); 
    S[i] := #02; 
  End Else If Copy(S, i, 2) = #05#19 Then Begin 
    Delete(S, i, 1); 
    S[i] := #03; 
  End Else If Copy(S, i, 2) = #05#21 Then Begin 
    Delete(S, i, 1); 
    S[i] := #05; 
  End;

Many Thx! So gehts.

[Christian Seehase]

Moin Dominik,

eine Variante hätte ich auch noch anzubieten:

Delphi-Quellcode:

function MakeCorrectString(const Data: String): String;

var
  sResult : string;
  iLen    : Integer;
  iPos    : Integer;

begin
  SetLength(sResult,Length(Data));
  iPos := 1;
  iLen := 0;
  while (iPos <= Length(Data)) do begin
    inc(iLen);
    case Data[iPos] of
      #05 : begin
        Inc(iPos);
        if (iPos <= Length(Data)) then begin
          case Data[iPos] of
            #18 : sResult[iLen] := #02;
            #19 : sResult[iLen] := #03;
            #21 : sResult[iLen] := #05;
            else begin
              sResult[iLen] := #05;
              inc(iLen);
              sResult[iLen] := Data[iPos];
            end;
          end;
        end;
      end;
      else begin
        sResult[iLen] := Data[iPos];
      end;
    end;
    inc(iPos);
  end;
  Result := Copy(sResult,1,iLen);
end;

[FriFra]

So sollte es funktionieren. Vorausgesetzt, in deinen Stings kommt niemals wirklich einer der "temporären" strings vor

Delphi-Quellcode:

function TLVELV_HET20.MakeCorrectString(const Data: String): String; 
var Erg: String; 
begin 
  Erg := ReplaceStr(Data, #05#18, '~#02~'); 
  Erg := ReplaceStr(Erg, #05#19, '~#03~'); 
  Erg := ReplaceStr(Erg, #05#21, '~#05~');

  Erg := ReplaceStr(Erg, '~#02~', #02); 
  Erg := ReplaceStr(Erg, '~#03~', #03); 
  Erg := ReplaceStr(Erg, '~#05~', #05);

  MakeCorrectString := Erg; 
end;