Explorer-Kontextmenü in eigener Anwendung?

[himitsu]

Also ich weiß nicht was du hast ... es steht doch fast alles in der Registry (es sei denn irgendein Programm hat Teile über einen Hook eingefügt, aber die grundlegenden Dinge steh drin)

Im Grunde steht nahezu alles im Zweig HKEY_CLASSES_ROOT.

und nein, es muß nicht sein das die angezeigten Namen in der Registry stehn, aber wo du die Namen herbekommst steht dann zumindestens dort.
OK, für die Standard-Menüs steht nur ein englischer, überall auf der Welt einheitlicher, Name und der angezeigte String steht in irgendeiner von Windows Ressouren-DLLs drin.

Für "Öffnen" (deutsches Windows) steht da z.B. "open".

als Beispiel schau dir mal die TXT-Dateien an
> HKEY_CLASSES_ROOT\.txt
und in dem Namen des darin enthaltenen Standardeintrags (meist "txtfile")
> HKEY_CLASSES_ROOT\txtfile
dazu dann noch HKEY_CLASSES_ROOT\* (für alle Datei-/Ordner-Typen)
und den Zweig HKEY_CLASSES_ROOT\file (für alle Dateien)

Interessant sind speziell die Unterordner "shell"
> z.B. HKEY_CLASSES_ROOT\txtfile\shell

Das Ganze mußt du dir dan nur noch zusammensuchen, kombinieren und anzeigen.



PS: die Standards kannst du dir auch ganz einfach machen
eine PopupMenü mit "Öffnen", "Drucken"... erstellen
und dann z.B. ShellExecute(Handle, 'open', Datei, ...
ShellExecute(Handle, 'print', Datei, ...
u.s.w. aufrufen.

[xZise]

Ich stehe aber z.Zt. vor dem Problem wie man das am besten Umsetzt

Und zwar muss ich irgendwie die .dll laden und dann irgendwie an das Menü heften Nur wie?

MfG
xZise

[TimonWorld]

Hallo!

Ich habe das gleiche das Problem: Ich möchte jeglich das System-Kontextmenü z.B. an ein Popup anbinden. Das hier fand ich interessant und wohl auch brauchbar:

Zitat von Flocke:

Sieh dir mal die Methode IShellFolder.GetUIObjectOf an. Mit IID_IContextMenu bzw. IID_IContextMenu2 solltest du ein Interface zum Kontextmenü bekommen. Mit IContextMenu.QueryContextMenu wird dir ein HMENU gefüllt.

Nur wie gehe ich damit um?

Und zur Methode die Kontextmenüs individuell herauszulesen (HKEY_CLASSES_ROOT usw.): Absolut umständlich. Andere Programme können das auch, das System-Kontext-Menü anhängen.

Im Anhang habe ich mal Screenshots von Programmen gemacht, die das originale Kontextmenü benutzen (und auch erweitern: Opera hat oben Einträge hinzugefügt, und RKLauncher unten)!

Ich hoffe duch die Screenshots wird einigen Bewusst, was gemeint ist.

LG,
Timon

[bitsetter]

Hi,

2 Beiträge dazu ContextMenuHandlers in eigene PopupMenüs einbinden und Explorer Popup . Es geht also auch ohne Registry, der Aufwand ist aber anscheinend ziemlich groß, vor allem wenn du es auch noch in ein TPopupmenu hinzufügen möchtest.

[Luckie]

Also das Kontextmenü vom Explorer für eine datei oder Ordner bekommt man so:

Delphi-Quellcode:

procedure ContextMenuForFile(FileName: TFileName; X, Y: Integer; Handle: HWND);
var
  aContextMenu : IContextMenu;
  aPrgOut      : Pointer;
  aPopup       : HMENU;
  aCmd         : Integer;
  aCmdInfo     : TCMInvokeCommandInfo;
  PIDL         : PItemIDList;
  ShellFolder  : IShellFolder;
begin
  PIDL := SHGetIDListFromPath(FileName, ShellFolder);
  if not Assigned(PIDL) then
    Exit;
  aPrgOut := nil;
  OLECheck(ShellFolder.GetUIObjectOf(0, 1, PIDL, IID_IContextMenu, aPrgOut,
    Pointer(aContextMenu)));
  aPopup := CreatePopUpMenu;
  if aPopup = 0 then
    Exit;
  try
    OLECheck(aContextMenu.QueryContextMenu(aPopup, 0, 1, $7FFF, CMF_NORMAL));
    aCmd := Integer(TrackPopupMenuEx(aPopup, TPM_LEFTALIGN or TPM_RETURNCMD or
      TPM_RIGHTBUTTON or TPM_HORIZONTAL or TPM_VERTICAL, X, Y, Handle, nil));
    if aCmd <> 0 then
    begin
      FillChar(aCmdInfo, Sizeof(aCmdInfo), 0);
      with aCmdInfo do
      begin
        cbSize := SizeOf(TCMInvokeCommandInfo);
        lpVerb := MakeIntResource(aCmd - 1);
        nShow := SW_SHOWNORMAL;
      end;
      try
        aContextMenu.InvokeCommand(aCmdInfo);
      except
      end;
    end;
  finally
    DestroyMenu(aPopup);
  end;
end;

Willst du das Kontextmenü erweiteren gibt es zwei Möglichkeiten: entweder über die Registry, dann kannst du aber nicht beeinflussen, dass der Eintrag nur bei betsimmten Dateien erscheinen soll oder du schreibst eine ShellExtension. Siehe dazu meinen Exif-Reader: http://www.michael-puff.de/Developer/Delphi/Programme/

[TimonWorld]

Zitat von Luckie:

Delphi-Quellcode:

procedure ContextMenuForFile(FileName: TFileName; X, Y: Integer; Handle: HWND);
var
  aContextMenu : IContextMenu;
  aPrgOut      : Pointer;
  aPopup       : HMENU;
  aCmd         : Integer;
  aCmdInfo     : TCMInvokeCommandInfo;
  PIDL         : PItemIDList;
  ShellFolder  : IShellFolder;
begin
  PIDL := SHGetIDListFromPath(FileName, ShellFolder);
  if not Assigned(PIDL) then
    Exit;
  aPrgOut := nil;
  OLECheck(ShellFolder.GetUIObjectOf(0, 1, PIDL, IID_IContextMenu, aPrgOut,
    Pointer(aContextMenu)));
  aPopup := CreatePopUpMenu;
  if aPopup = 0 then
    Exit;
  try
    OLECheck(aContextMenu.QueryContextMenu(aPopup, 0, 1, $7FFF, CMF_NORMAL));
    aCmd := Integer(TrackPopupMenuEx(aPopup, TPM_LEFTALIGN or TPM_RETURNCMD or
      TPM_RIGHTBUTTON or TPM_HORIZONTAL or TPM_VERTICAL, X, Y, Handle, nil));
    if aCmd <> 0 then
    begin
      FillChar(aCmdInfo, Sizeof(aCmdInfo), 0);
      with aCmdInfo do
      begin
        cbSize := SizeOf(TCMInvokeCommandInfo);
        lpVerb := MakeIntResource(aCmd - 1);
        nShow := SW_SHOWNORMAL;
      end;
      try
        aContextMenu.InvokeCommand(aCmdInfo);
      except
      end;
    end;
  finally
    DestroyMenu(aPopup);
  end;
end;

Muss man da noch irgendwelche Units einbinden, oder funktioniert das mal wieder unter Delphi 3 nicht!? =(

[bitsetter]

Zitat von TimonWorld:

Muss man da noch irgendwelche Units einbinden, oder funktioniert das mal wieder unter Delphi 3 nicht!? =(

Zitat von bitsetter:

Hi,

2 Beiträge dazu ... und Explorer Popup . Es geht also auch ohne Registry, der Aufwand ist aber anscheinend ziemlich groß, vor allem wenn du es auch noch in ein TPopupmenu hinzufügen möchtest.

Hallo,

das steht genau die gleiche Prozedur und die dazugehörenden Funktionen SHGetIDListFromPath() und SlashDirName() bloß nicht so schön formatiert:
Außerdem benötigst du zusätzlich noch

Delphi-Quellcode:

uses
  ShlObj, ComObj;