LUA Codes auslesen und verstehen

[Sarahlin]

Für mein Anliegen braucht man keine sonderbaren Kentnisse in LUA aber dafür in einer anderen Angelegenheit.

Ich spiele das Spiel World of Warcraft, was es erlaubt das Interface per LUA-Schnittstelle anzupassen. Nun gibt es auch Addons (LUA Scripte) die im Spiel einen Notepad ermöglichen. Um sich im Spiel notizen zu machen oder etwas zu schreiben. Wenn man diese speichert, sehen sie am Ende in dem SavedVariables Ordner unter addonname.lua dann zum Beispiel wie folgt aus:

Code:

         ["Notes"] = {
            ["Briefvorlage"] = {
               ["description"] = "Hallo Sarah/n/n Ich wollte Fragen ob wir demnächst noch das Gildenevent ausführen wollen",
               ["date"] = "060823",
               ["author"] = "Sarahlin",
            },
            ["Nachnamen"] = {
               ["description"] = "Musterman/n/nFeuervogel/n/nTestnachnamen",
               ["date"] = "060827",
               ["author"] = "Natalie",
            },
            ["Gute Emotes"] = {
               ["description"] = "/me schließt die Augen und lässt den Kopf nach hinten fallen worauf langsam als sie die Hände ausbreitet ihr Körper samt Kleid sich in Energie auflösen zu scheint und sie vor den Augen aller sich auflöst.",
               ["date"] = "060827",
               ["author"] = "Natalie",
            },
            ["Schwert"] = {
               ["description"] = "10 Stück verzaubertes Thorium\n4 Essenzen des Feuers\n4 Herz des Feuers\n2 Azerothischer Dimanat\n2 verdichteter Schleifstein",
               ["date"] = "060820",
               ["author"] = "Runia",
            },

Nun erkennen wir bei genauerem Hinsehen wo genau die Titel gespeichert werden, der Text, das Datum und den Namen des Authors. Auch mit etwas überlegung fällt uns auf das /n einem Zeilenumbruch gleichkommen vermag.

Und genau hier kommt das Programm was ich schreiben will:

Es soll diese Daten ausslesen und korrekt verarbeiten können. (eventuell auch wieder zurückspielen) So das man auch außerhalb des Spiels schnell Inhalte kopieren (oder hinzufügen) könnte.

Somit sehe ich schon vor mir, ein ListBox-Element, RichEdit-Element (weil das loadfromfile einfacher ist), drei Edit-Elemente.

Doch die Frage ist jetzt, wie kann ich einem Delphi Programm beibringen den Code zu verstehen? Also die einzelnden Felder des Codes auszulesen und dann in die passenden Strings zu speichern?

[Khabarakh]

Wenn du es dir so einfach wie möglich machen willst, würde ich dir zum Auslesen Regular Expressions empfehlen. Das Schwierigste dabei ist noch, eine entsprechende Library herunterzuladen (http://regexpstudio.com/TRegExpr/TRegExpr.html), da Delphi Regexes nicht nativ unterstützt, und schnell noch ein Tutorial zum Thema durchzuarbeiten.

[Prototypjack]

Hallo!
Das sollte ganz einfach sein, du erkennst ja in dem "Text" wiederholungen, sprich, es steht immer das Tag am anfang und der Text in "", abgeschlossen wird das ganze durch ein Komma.

Du lädst den Text ganz einfach in eine TStringlist und parst das ganze per Pos / PosEx(StrUtils) durch.

Bin gerade in guter Laune(Auch wenn ich denke das ich mir vor 3 Stunden eine Lebensmittelvergiftung eingefangen habe), vielleicht schreibe ich dir eben so ein Ding. Mal sehen
Gruß,
Max

[Sarahlin]

Aber woran soll das Programm erkennen zum Beispiel das zum Beispiel der erste kein statischer string zum entfernen ist sondern, der titlename?

Aber ist sehr lieb, das du mir "vieleicht" ein Beispiel machen willst. Mit den Informationen die ihr mir gabt verstehe ich zu anfangst Bahnhof. Mit etwas Arbeit nach ein paar Stunden vieleicht AH. Doch ein Beispiel würde es am verständlichsten machen.

[Prototypjack]

Hallo,
Bin gerade dabei dir ein Beispiel zu schreiben. Gut dokumentiert und sollte leicht verständlich sein. Ich arbeite jedoch ohne Regular Expressions, was aber nicht minder zum Ziel führt

Den Ersten String erkenne ich zb. daran das er immer der Erste im { } Tag ist.

Ich muss noch 2 Tags implentieren und einen Beispielaufruf machen.
Bis gleich

Gruß,
Max

[Prototypjack]

Soo,
Fertig.
Mal vorweg: Du brauchst auf deiner Form diese Controls(Für den Beispielcode):
3 Edits
2 Memos
1 ListBox
1 Button

Der Button löst das ganze aus(OnClick)
Die Edits enthalten später Name, Datum und Author
Memo1 enthält den SourceText(Dein Beispiel oben)
Memo2 enthält die geladene Description
Und die Listbox enthält die geladenen Header

Jetzt zum Code:
Du musst alle erforderlichen Ereignisse in den Controls setzen und denen die spezifischen Codes zuweisen.

Hier mal der Code:

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, StrUtils;

type
  TEntry = record
    Name: String;
    Description: String;
    Author: String;
    Date: String;
  end;

type
  TFrmMain = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    ListBox1: TListBox;
    Memo2: TMemo;
    Edit1: TEdit;
    Edit2: TEdit;
    Edit3: TEdit;
    procedure ListBox1Click(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure LoadLuaFile(AFile: String);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  FrmMain: TFrmMain;
  FEntrys: Array of TEntry;

implementation

{$R *.dfm}


// Ersetzt einzelne Zeichen durch andere
function Replace(ASrc, ALookFor, AReplaceWith : string ):
  string;
var
  nPos: Integer;
  nLenLookFor: integer;
begin
  nPos := Pos(ALookFor, ASrc);
  nLenLookFor := Length(ALookFor);
  while (nPos > 0) do
  begin
    Delete(ASrc, nPos, nLenLookFor);
    Insert(AReplaceWith, ASrc, nPos);
    nPos := Pos(ALookFor, ASrc);
  end;
  Result := ASrc;
end;

// Löscht ungewollte Zeilenumrüche
function RemoveBreaks(AString: String): String;
var
  Str: TStringlist;
  I: Integer;
begin
  Str := TStringlist.Create;
  try
    Str.Text := AString;
    for I := 0 to Str.Count - 1 do
    begin
      Result := Result + Str.Strings[I];
    end;
  finally
    Str.Free;
  end;
end;

procedure TFrmMain.FormDestroy(Sender: TObject);
begin
  SetLength(FEntrys, 0);
end;

procedure TFrmMain.ListBox1Click(Sender: TObject);
begin
  if Length(FEntrys) > 0 then
  begin
    // Array hat Inhalt, laden...
    Memo2.Text := FEntrys[ListBox1.ItemIndex].Description;
    Edit1.Text := FEntrys[ListBox1.ItemIndex].Name;
    Edit2.Text := FEntrys[ListBox1.ItemIndex].Date;
    Edit3.Text := FEntrys[ListBox1.ItemIndex].Author;
  end;
end;

procedure TFrmMain.LoadLuaFile(AFile: String);
var
  lTags: String;
  lTagBegin: Integer;
  lTagEnd: Integer;
  lInnerTagBegin: Integer;
  lInnerTagEnd: Integer;
  I: Integer;
  lSearchIndex: Integer;
  lInnerTag: String;
begin
  // Als erstes wir nur der Inhalt des [Notes] Tags gefiltert..  (+1 weg. { )
  lTagBegin := Pos('{', AFile) + 1;
  lTagEnd := 0;
  for I := Length(AFile) downto 1 do
  begin
    // Das letzte } suchen und position speichern
    if AFile[I] = '}' then
    begin
      // Speichern ( -1 wegen dem } )
      lTagEnd := I - 1;
      // Schleife beenden.
      Break;
    end;
  end;
  // Jetzt haben wir alles in [Notes]
  // Und weiter, die einzelnen Tags durchgehen
  lTags := RemoveBreaks(copy(AFile, lTagBegin, lTagEnd - lTagBegin));
  lSearchIndex := 1;
  while PosEx('[', lTags, lSearchIndex) <> 0 do
  begin
    // Der ganze Eintrag
    lTagBegin := PosEx('[', lTags, lSearchIndex);
    lTagEnd := PosEx('}', lTags, lTagBegin);
    if lTagEnd = 0 then
    begin
      // Wenn PosEx nichts gefunden hat, ist der Text zuende, also richtiges
      // Value setzen
      lTagEnd := Length(lTags);
    end;
    lInnerTag := Copy(lTags, lTagBegin, lTagEnd - lTagBegin);
    // Der gesamte SubEintrag befindet sich nun in lInnerTag
    // Nun werden die einzelnen SubTags geparst
    SetLength(FEntrys, Succ(Length(FEntrys)));
    // Zuerst der Name
    lInnerTagBegin := Pos('[', lInnerTag) + 2;
    lInnerTagEnd := PosEx(']', lInnerTag, lInnerTagBegin) - 1;
    FEntrys[High(FEntrys)].Name := Copy(lInnerTag, lInnerTagBegin,
      lInnerTagEnd - lInnerTagBegin);
    // Beschreibung...
    // + 19 = ["description"] = "
    lInnerTagBegin := Pos('["description"] = "', lInnerTag) + 19;
    lInnerTagEnd := PosEx('",', lInnerTag, lInnerTagBegin);
    FEntrys[High(FEntrys)].Description := Copy(lInnerTag, lInnerTagBegin,
      lInnerTagEnd - lInnerTagBegin);
    // Noch die /n durch Zeilenumbrüche ersetzen
    FEntrys[High(FEntrys)].Description := Replace(Copy(lInnerTag, lInnerTagBegin,
      lInnerTagEnd - lInnerTagBegin), '/n', sLineBreak);
    // Datum kA welches Format das ist, also Plaintext
    lInnerTagBegin := Pos('["date"] = "', lInnerTag) + 12;
    lInnerTagEnd := PosEx('",', lInnerTag, lInnerTagBegin);
    FEntrys[High(FEntrys)].Date := Copy(lInnerTag, lInnerTagBegin,
      lInnerTagEnd - lInnerTagBegin);
    // Author
    lInnerTagBegin := Pos('["author"] = "', lInnerTag) + 14;
    lInnerTagEnd := PosEx('",', lInnerTag, lInnerTagBegin);
    FEntrys[High(FEntrys)].Author := Copy(lInnerTag, lInnerTagBegin,
      lInnerTagEnd - lInnerTagBegin);
    // Das wars. Alle essentiellen Daten befinden sich im array,
    // jetzt kann dieses verarbeitet werden...
    // Den SuchIndex anpassen
    lSearchIndex := lTagEnd;
  end;
end;

procedure TFrmMain.Button1Click(Sender: TObject);
var
  I: Integer;
begin
  LoadLuaFile(Memo1.Text);
  // Die Daten befinden sich nun im Array, dieses laden wir in eine Listbox
  for I := 0 to Length(FEntrys) - 1 do
  begin
    // Jeweils die Namen in die Listbox
    ListBox1.Items.Add(FEntrys[I].Name);
  end;
end;

end.

Sollte keine Fehler enthalten.

Falls es noch fragen gibt, ich bin noch ein bischen hier.

Gruß,
Max

[Sarahlin]

Kannst du mir vieleicht die Delphi Dateien dafür geben? Ich bekomm das bei mir irgendwie nicht hin, anscheinend sind einige Namen unterschiedlich und müssen erst bei mir festgelegt werden, ich weiß bloss nur nicht welche. Auch erkennt meiner nicht TFrmMain und so.

[Prototypjack]

Moin!
Achso, keine Problem, die Dateien findest du im Anhang.

Nochwas: Bitte kopieren den Code nicht einfach sondern versuche ihn zu verstehen, würde mich freuen
( Wie gesagt, bei Fragen stehe ich gerne zur Verfügung )

Gruß,
Max

[Sarahlin]

Ich hab das ausprobiert und es funktioniert wirklich *erstaunt*

Ich werde aber den Code nicht so kopieren, keine Sorge. Ich muss/will ihn verstehen lernen, darum wirst du sicherlich noch des öfteren hier hören. Denn es sollen noch weitere solcher Programme durch diese Technik entstehen. Und was ich bisher da oben gab ist nur ein Schnipsel aus der Code-Datei.

Somit vielen Dank und bis später, heut bin ich leider etwas kaputt. Aber morgen schau ich mir das genauer an. (nur 3 Stunden schlaf hatte)

[OregonGhost]

Wenn du vorhast, noch mehr Lua-Daten zu parsen und zu verwenden, kannst du dir auch überlegen, dir die Lua-API für Delphi zu besorgen (lua.org). Die SavedVariables sind ja keine Daten-Dateien, sondern ausführbarer Lua-Code, den du also auch einfach vom Interpreter ausführen lassen kannst und somit direkt die tables im Speicher hast.