Hilfe!!! Programm um Dateinamen zu überprüfen.. nur wie ?

[DeddyH]

Hallo, evtl. hab ich wieder zu umständlich gedacht, aber versuch es mal hiermit:

Delphi-Quellcode:

uses DateUtils;

procedure ListMissingFiles(sPath: string;             //zu durchsuchender Pfad
                           const CountDays: integer;  //Anzahl der Tage
                           const FileList: TStrings); //Ergebnisliste
var sFile: string;
    i, j: integer;
    ActualTime: TDateTime;
    StartTime: TSystemTime;
begin
  if not Assigned(FileList) then
    raise Exception.Create('Es wurde keine Ergebnisliste übergeben.');
  sPath := IncludeTrailingPathDelimiter(sPath);
  FileList.BeginUpdate;
  try
    FileList.Clear;
    DateTimeToSystemTime(now,StartTime);
    StartTime.wHour := (StartTime.wHour div 6) * 6;
    ActualTime := SystemTimeToDateTime(StartTime);
    for I := 1 to CountDays do
      for j  := 0 to 3 do
        begin
          sFile := Format('%sworld_%s%s',
                          [sPath,
                           FormatDateTime('yyyymmddhh',ActualTime),
                           '.zip']);
          if not FileExists(sFile) then
            FileList.Add(sFile);
          ActualTime := IncHour(ActualTime, -6);
        end;
  finally
    FileList.EndUpdate;
  end;
end;

Beispielaufruf:

Delphi-Quellcode:

procedure TForm2.Button1Click(Sender: TObject);
begin
  ListMissingFiles('C:\Drivers',   //Pfad
                   1,              //1 Tag
                   ListBox1.Items);//in ListBox anzeigen
end;