bestimmte Wörter im Memo suchen

[delphiUser88]

Hallo ich möchte gerne bestimmte Datensätze in einem Memo suchen und diese dann gesondert an einer Variable weitergeben. Ich versuche es mal verständlich zu erklären.

Also ich habe eine Schleife in dieser möchte ich das Memo nach bestimmten Daten durchsuchen der erste Datensatz der ausgelesen werden muss ist immer zwischen 2 Klammern also (Datensatz1) der dazugehörige Datensatz steht direkt dahinter also (Datensatz1)dazugehöriger Datensatz und in diesem Datensatz möchte ich dann ein bestimmtes Wort suchen

Delphi-Quellcode:

for i := 0 to Memo1.Lines.Count -1 do
begin

// hier jeweils Memo1.Lines.Strings[i] auslesen was zwischen den beiden Klammern in dem Fall (Datensatz1)steht und an einer Variable //übergeben z.b. sDat dann weitersuchen also alles was dahinter steht nach der Klammer ) und darin dann zb das Wort "Konto" suchen //und dieses an der Variable sDat mit anhängen also sdat := ausgelesene Datensatz zwischen den Klammern + Freizeichen + gesuchte Wort //Konto

//danach könnte ich dann die Variable sDat weiterverarbeiten

end;

Ich hoffe ich hab mich einigermaßen verständlich ausgedrückt


MFG: DelphiUser

[s.h.a.r.k]

Du willst also das Wort in der Klammer haben und das Wort hinter den Klammern? Verstehe ich das so richtig???

[delphiUser88]

Hallo s.h.a.r.k ja genau das Wort in den Klammern und wenn hinter den Klammern z.b noch ein Satz steht un in diesem das Wort "Konto" auftaucht dann dieses ebenfalls mit ausgeben

[s.h.a.r.k]

Ein Anhaltspunkt wären sicherlich die Funktionen pos und copy. Kann dir an dieser Stelle leider keinen Quelltext liefern, da du erstens dabei ja lernen sollst und zweitens ich jetzt Vorlesung habe! Muss mich also beeilen

[zer00]

Könnte man das nicht mit einem PChar lösen?

Delphi-Quellcode:

function TForm1.invert(p: PChar): string;
var dummy: string;
begin
while p^ <> #0 do
begin
  dummy:= p^ + dummy;
  inc(p)
end;
  result:= dummy;
end;

Ist nur ein Beispiel löst also nicht dein Problem, mit ein paar Veränderungen kommst du sicher zum Ziel.

grz zer00

[delphiUser88]

Hallo

Ich habe es erstmal so gelöst zumindest wird der gesamte jeweilige Text des Memo.Lines.Strings[i] nach einem bestimmten Wort durchsucht und dieses dann ausgegeben Wie ich aber nun noch alles was in Klammern steht auslesen kann hab ich noch nicht rausgefunden

Delphi-Quellcode:

var
  i: Integer;
  sText: String;
  slDat: TStringList;

     try

        For i := 0 to Memo1.Lines.Count -1 do
        begin

        slDat := TStringList.Create;
        slDat.Clear();
        sText := '';
        sText := Memo1.Lines.Strings[i];


        while pos('Konto',sText) <> 0 do
        begin
        slDat.Add(copy(sText,1,pos('Konto',sText)-1));
        delete(sText,1,pos('Konto',sText));
        end;

        slDat.Add(sText);

                         if slDat.Strings[i] = Memo1.Lines.Strings[i] Then
                         begin
                         // nichts tun
                         end
                            else
                                begin
                                MessageDlg('gesuchte Wort gefunden',mtInformation, [mbOK], 0);
                                Exit;
                         end;//if



                                  
        end //schleife

                                  except
                                  Exit;

     end; //try


end;

[marabu]

Hier hast du etwas Code zum Studieren:

Delphi-Quellcode:

uses
  StrUtils; // PosEx(), AnsiContainsText()

function After(const s, subStr: String): String;
var
  i: Integer;
begin
  i := Pos(subStr, s);
  if i = 0
    then Result := ''
    else Result := Copy(s, i + Length(subStr), MaxInt);
end;

function Between(const s, sLeft, sRight: String): String;
var
  iLeft, iRight: Integer;
begin
  iLeft := Pos(sLeft, s);
  if iLeft > 0 then
  begin
    Inc(iLeft, Length(sLeft));
    iRight := PosEx(sRight, s, iLeft);
    if iRight > 0
      then Result := Copy(s, iLeft, iRight - iLeft)
      else Result := ''
  end else Result := '';
end;

procedure CustomExtract(sIn, sOut: TStrings; const keyword: String);
var
  i: Integer;
  s: String;
begin
  sOut.Clear;
  for i := 0 to Pred(sIn.Count) do
  begin
    s := Between(sIn[i], '(', ')');
    if s <> '' then
    begin
      if AnsiContainsText(After(sIn[i], ')'), keyword) then
        s := s + ' ' + keyword;
      sOut.Add(s);
    end;
  end;
end;

procedure TDemoForm.ButtonClick(Sender: TObject);
begin
  CustomExtract(Memo.Lines, ListBox.Items, 'Konto');
end;

Trage bei Gelegenheit mal deine Delphi-Version in dein DP-Profil ein.

Freundliche Grüße vom marabu

[delphiUser88]

Hallo marabu

PosEx und AnsiContainsText geht bei meinen Delphi nicht (D5 Standard) könnte aber auch (Firma) D5 Enterprise benutzen Ich habe die PosEx Funktion hier aus dem Forum schon eingebunden fehlt nur noch die AnsiContainsText

Delphi-Quellcode:

function PosEx(const SubStr, S: string; Offset: integer): integer;
begin
  Result := Pos(SubStr, Copy(S, OffSet, Succ(Length(S) - OffSet)));
  if Result > 0 then Result := Result + Pred(Offset);
end

MFG: DelphiUser

[marabu]

Guten Morgen.

So könnte es funktionieren:

Delphi-Quellcode:

function AnsiContainsText(const s, subStr: String): Boolean;
begin
  Result := AnsiPos(AnsiLowercase(subStr), AnsiLowercase(s)) > 0;
end;

marabu

[delphiUser88]

Hallo


In der Funktion CustomExtract wird ja wenn ich es richtig verstehe der Variable s das gesuchte Wort in den Klammern + ein Leerzeichen + das Schlüsselwort übergeben. Ich weis jetzt nur nicht so recht was der Aufruf der Funktion CustomExtract(Memo.Lines, ListBox.Items, 'Konto'); mit dem Memo und der listBox genau bewirkt. Marabu könntest du vielleicht wenn du mal Zeit hast die ganzen Funktionen erklären es bringt ja nichts wenn ich sie nicht verstehe


MFG: DelphiUser