DBgrid in csv - Problem

[deralexc]

Moin!
Ich hab da ein Problem.
Ich soll einzelne Spalten verschiedener DB-Tabellen in eine csv schreiben um diese dann anschließend via php in mySQL einzufügen.

Ich bin hier eigentlich schon fündig geworden - einziges Problem:
die daten werden wie folgt gespeichert:

2,"LS Stochastik",1
6,"LS Analysis",1
8,Mathematik,1
10,Mathematik,1

sollte aber eigentlich so aussehen
"2","LS Stochastik","1"
"6","LS Analysis","1"
"8","Mathematik","1"
"10","Mathematik","1"

Hier mein Quelltext:

Delphi-Quellcode:

function Tmainform.buch:boolean;
var
  s, csv: TStrings;
  i: integer;
begin
  csv := TStringList.Create;
  s := TStringList.Create;
  with ADOQuery1 do
  begin
   begin
   ADOQuery1.Close;
   DataSource1.DataSet := ADOQuery1;
   ADOQuery1.SQL.Text:='select bookid,title,mediumid from bookstab';
   ADOQuery1.Open;
      while not Eof do
    begin
      s.Clear;
      for i := 0 to Pred(FieldCount) do
        s.Add(Fields[i].AsString);
      csv.add(s.CommaText);
      Next;
    end;
    Close;
  end;
  s.Free;
  csv.SaveToFile(ExtractFilePath(Application.Exename)+'\dbtxt\buch.txt');
  csv.Free;
  result:=true;
  end;
end;

Ich danke schonmal im voraus!

Mfg

Deralex

[mkinzler]

Vom Jediprojekt gibt es eine Komponente CSVDataSet.

[deralexc]

Ist das der einzige Weg? ist es nicht möglich mit ein wenig "feintuning" an der Variante die ich bisher gewählt habe das Problem zu lösen?

Jedi müsste ich auch erst installieren.

Gruß
Alex

PS: Beispiel-Code wäre echt hilfreich....

[marabu]

Herzlich willkommen in der Delphi-PRAXiS, Alex.

Hier ein Nachrüst-Kit für dich:

Delphi-Quellcode:

function DelimitedText(s: TStrings; const cDelimiter: Char = ',';
  const cQuote: Char = '"'): String;
var
  i, iPos, iLength: Integer;
  line: String;
begin
  if s.Count = 0 then Result := '' else
  // calculate resulting length
  begin
    // account for delimiters
    iLength := Pred(s.Count);
    for i := 0 to Pred(s.Count) do
    begin
      line := s[i];
      // account for outer quotes
      Inc(iLength, Length(line) + 2);
      for iPos := 1 to Length(line) do
        // account for escape chars
        Inc(iLength, Ord(line[iPos] = cQuote));
    end;
    // dimension result
    SetLength(Result, iLength);
    iPos := 1;
    for i := 0 to Pred(s.Count) do
    begin
      if i > 0 then
      begin
        Result[iPos] := cDelimiter;
        Inc(iPos);
      end;
      line := AnsiQuotedStr(s[i], cQuote);
      Move(line[1], Result[iPos], Length(line));
      Inc(iPos, Length(line));
    end;
  end;
end;

Freundliche Grüße vom marabu

[deralexc]

Danke! Prog läuft jetzt so wie's soll! Dickes Danke!