Wörter kombinieren

[marabu]

Hallo Sarah,

die Eingabe der Wörter kann man interaktiv wunderbar in einer TMemo-Komponente erledigen. Du kannst aber die Wörterliste auch beim Start aus einer Textdatei in das Memo laden - Memo.LoadFromFile('Wörterliste.txt').

Beim Verbinden zweier Wörter zu einer neuen Wortschöpfung wirst du feststellen, dass Katze und Klo zu KatzeKlo wird. Du wirst dich also darum kümmern müssen, dass das angehängte Wort der Verbindung immer klein geschrieben ist und für das vorangestellte Wort eine Flexionsform angegeben wird.

Versuche den Algorithmus zuerst in deiner Muttersprache zu formulieren, bevor du es mit Pascal angehst.

Delphi-Quellcode:

procedure TrimLines(s: TStrings);
var
  i: Integer;
begin
  s.BeginUpdate;
  for i := Pred(s.Count) downto 0 do
    if Trim(s[i]) = ''
      then s.Delete(i)
      else s[i] := Trim(s[i]);
  s.EndUpdate;
end;

function CombinedWords(s: TStrings): string;
var
  index1, index2: Integer;
  name, value: string;
begin
  s.BeginUpdate;
  index1 := Random(s.Count);
  name := s.Names[index1];
  value := s.ValueFromIndex[index1];
  s.Exchange(index1, Pred(s.Count));
  index2 := Random(Pred(s.Count));
  Result := StringReplace(value, '~', name, []) + AnsiLowercase(s.Names[index2]);
  s.Exchange(index1, Pred(s.Count));
  s.EndUpdate;
end;

procedure TDemoForm.TrimButtonClick(Sender: TObject);
begin
  TrimLines(Memo.Lines);
end;

procedure TDemoForm.TestButtonClick(Sender: TObject);
begin
  with Memo do
    if Lines.Count > 1
      then ShowMessage(CombinedWords(Memo.Lines))
      else ShowMessage('nice try!');
end;

procedure TDemoForm.InitButtonClick(Sender: TObject);
begin
  with Memo.Lines do
  begin
    Clear;
    Values['Katze'] := '~n';
    Values['Klo'] := '~';
    Values['Haar'] := '~';
    Values['Bürste'] := '~n';
  end;
end;

Freundliche Grüße