Laden und Speichern von Kommazahlen möglich?

[DeddyH]

Eine typisierte Datei ist eine Datei, die Elemente eines bestimmten Typs aufnimmt (wer hätte das gedacht? ). Mal ein Beispiel:

Delphi-Quellcode:

type TMyRecord = record
  einString: string[40];
  eineInteger: integer;
  eineDouble: Double;
end;

const sFileName = 'C:\test.rec';

procedure TFormMain.btnSpeichernClick(Sender: TObject);
var MyRec: TMyRecord;
    MyFile: file of TMyRecord; //das ist eine Deklaration einer typisierten Datei
begin
  FillChar(MyRec,SizeOf(MyRec),#0);
  with MyRec do
    begin
      einString := 'String';
      eineInteger := 123;
      eineDouble := 3.1415927;
    end;
  AssignFile(MyFile,sFileName);
  rewrite(MyFile);
  write(MyFile,MyRec);
  CloseFile(MyFile);
end;

procedure TFormMain.btnLesenClick(Sender: TObject);
var MyRec: TMyRecord;
    MyFile: file of TMyRecord; 
begin
  if not FileExists(sFileName) then exit;
  FillChar(MyRec,SizeOf(MyRec),#0);
  AssignFile(MyFile,sFileName);
  Reset(MyFile);
  read(MyFile,MyRec);
  CloseFile(MyFile);
  ShowMessage('Daten:'+#13#10+MyRec.einString+#13#10+
              inttostr(MyRec.eineInteger)+#13#10+
              FloatToStr(MyRec.eineDouble));
end;

Getippt und nicht getestet, aber alles Weitere zu Records und typisierten Dateien sollte sich in der Hilfe finden lassen.