Pfad für "Eigene Bilder"

[marlem]

Hallo,

ich suche eine zuverlässige Lösung, wie ich auf jedem (Windows)Betriebssystem den Pfad für "Eigene Bilder" herausfinden kann!
wer weiss rat?

[Sharky]

Hai marlem,

test doch mal diese Methode:

Delphi-Quellcode:

uses
  ShlObj;

const
  CSIDL_MYPICTURES = $0027;

function GetShellFolder(CSIDL: Integer): string;
var
  pidl: PItemIdList;
  FolderPath: string;
  SystemFolder: Integer;
begin
  SystemFolder := CSIDL;
  if SUCCEEDED(SHGetSpecialFolderLocation(0, SystemFolder, pidl)) then
  begin
    SetLength(FolderPath, max_path);
    if SHGetPathFromIDList(pidl, Pchar(FolderPath)) then
    begin
      SetLength(FolderPath, strlen(Pchar(FolderPath)));
    end;
  end;
  Result := FolderPath;
end;


procedure TDemoForm.Button1Click(Sender: TObject);
begin
  ShowMessage(GetShellFolder(CSIDL_MYPICTURES));
end;

[Gollum]

Hallo,

folgendes funktioniert unter W2K und XP:

Delphi-Quellcode:

uses 
  SHFolders, SysUtils;

...
// aID: CSIDL_PERSONAL   = My Documents
//      CSIDL_MYPICTURES = My Pictures 

function GetPfad(aID:Integer):String;
var p:PChar;
begin
  p:=nil;
  try
    p:=AllocMem(MAX_PATH);
    if (SHGetFolderPath(0, aID, 0, 0, p)=S_OK) then Result:=p
      else Result:=GetCurrentDir;
    Result:=IncludeTrailingPathDelimiter(Result);
  finally
    FreeMem(p);
  end; // try
end; // GetPfad

...
var bildPfad:String;
...
bildPfad:=GetPfad(CSIDL_MYPICTURES);
...

[marlem]

@Sharky
sieht gut aus danke!

[Robert Marquardt]

Unter jeder Windowsversion geht das nicht, da nicht jede Windowsversion diesen Pfad hat.
AFAIK erst ab Win 98 ME.