GetTempFileName with FileExt

[himitsu]

Tja, FILE_FLAG_DELETE_ON_CLOSE konnte ich ja doch nicht verwenden denn dazu muß die datei ja geöffnet bleiben, aber da diese Funktion ja die datei wieder schließt, würde demnach diese Datei sofort von Windows wieder gelöscht, was sie ja nicht soll -.-''

Also sieht es jetzt so aus (nachdem der andere Fehler auch noch raus ist )

Delphi-Quellcode:

Function GetTempPath: String;
  Var i: Integer;

  Begin
    SetLength(Result, MAX_PATH);
    i := Windows.GetTempPath(MAX_PATH, @Result[1]);
    SetLength(Result, i);
    If (Result <> '') and (Result[i] <> '\') Then Result := Result + '\';
  End;

Function GetTempFileName(FileName: String): String;
  Var i, i2: Integer;
    F: THandle;

  Begin
    If Pos('\', FileName) = 0 Then FileName := GetTempPath + FileName;
    If Pos('*', FileName) = 0 Then FileName := ChangeFileExt(FileName,
      '*.' + Copy(ExtractFileExt(FileName), 2, MAX_PATH));
    i := GetTickCount;
    i2 := i;
    Repeat
      If i - i2 > 10000 Then
        Raise Exception.CreateFmt('Temporäre Datei "%s" konnte nicht erstellt werden.',
          [StringReplace(FileName, '*', '{UniqueID}', [])]);
      Result := StringReplace(FileName, '*', IntToHex(i, 8), []);
      F := CreateFile(PChar(Result), GENERIC_WRITE, 0, nil, CREATE_NEW,
        FILE_ATTRIBUTE_TEMPORARY or FILE_ATTRIBUTE_NOT_CONTENT_INDEXED, 0);
      Inc(i);
    Until F <> INVALID_HANDLE_VALUE;
    CloseHandle(F);
  End;

Aber jetzt funktioniert es endlich, was ja die Hauptsache ist ^_^


Und wer dennoch möchte, das die Datei automatisch gelöscht wird, der kann die Datei z.B. so öffnen:

Code:

FileName := GetTempFileName('Programmname*.tmp');
F := CreateFile(PChar(FileName), GENERIC_READ or GENERIC_WRITE, 0, nil, OPEN_ALWAYS,
  [color=#ff0000]FILE_ATTRIBUTE_TEMPORARY or FILE_ATTRIBUTE_NOT_CONTENT_INDEXED or
  FILE_FLAG_DELETE_ON_CLOSE[/color] or FILE_FLAG_RANDOM_ACCESS, 0);