Funktion mit eine Liste :TStrings

[Karstadt]

Delphi-Quellcode:

Function Tf_hauptfenster.GibLagerListe: TStrings;
var Lagerliste: TStrings;
begin
  Lagerliste := TStringList.Create;
  with dm.mqr_TEMP do
  begin
    Close;
    Sql.Clear;
    sql.Add('SELECT * FROM lager ORDER BY lg_bezeichnung ASC');
    open;
    While not Eof do
    begin
      Lagerliste.Add(Fieldbyname('lg_bezeichnung').asstring);
      next;
    end;
    close;
  end;
  Result := Lagerliste;
  //Lagerliste.Free;
end;

So lade ich die Lagerliste in eine TCombPox Componente. Wenn ich aber diese Zeile ( //Lagerliste.Free Ausdokumentiere um die Varialbe Lagerliste aus dem Speicher zu entfernen, bekomme ich beim Aufruf dieser Funktion eine Zugriffsverlestzung. Weil ich die Lagerliste aus dem Speicher entnommen haben. Aber Warum ich habe doch den Inhalt davor an ReSult übergeben..

[Angel4585]

nein du hast nicht den INHALT sondern den ZEIGER der Liste übergeben. probier das mal mit
Result.Assign(Lagerliste) Oder war das Append

denn wenn du den Zeiger übergibst und Lagerliste freigibst ist das Result auch futsch weil glaube ich auch freigegeben.

[TAC]

moin,

die Lagerliste wird eigentlich ja nicht benötigt da es ja ein result gibt und dann sollte es auch keine Zugriffsverletztung mehr geben.

[Keldorn]

Zitat von Angel4585:

Result.Assign(Lagerliste)

Hallo, dann soltest du in einer AV landen, da du Result nicht erzeugt hast.

Zitat von Karstadt:

Aber Warum ich habe doch den Inhalt davor an ReSult übergeben..

Hast du eben nicht . Durch Result := Lagerliste; hast du nicht den inhalt kopiert, sondern nur den zeiger verborgen, result und Lagerliste zeigen auf das gleiche. mit result.assign(lagerliste) würdest du den inhalt kopieren, bringt dir aber auch nichts. Das Rückgabe Ergebnis mußt du dann in der aufrufenenden Proc wieder freigeben. Ich persönlcih würde die Stringlist übergeben und nicht innerhalb der Func erzeugen.

Delphi-Quellcode:

Procedure Tf_hauptfenster.blablaLagerListe(Lagerliste: TStrings);  (edit: in Procedure geändert)
begin 
  Lagerliste.clear; 
  with dm.mqr_TEMP do 
  begin 
    Close; 
    Sql.Clear; 
    sql.Add('SELECT * FROM lager ORDER BY lg_bezeichnung ASC'); 
    open; 
    While not Eof do 
    begin 
      Lagerliste.Add(Fieldbyname('lg_bezeichnung').asstring); 
      next; 
    end; 
    close; 
  end; 
end;

Procedure Aufruf;
Var sl:tstings;
begin
sl:=tstringlist.create;
try 
  blablaLagerListe(sl);
  machnochwasmit(sl);
finally
  sl.free;
end;

Somit hast du das create und free der stringliste an einer Stelle und minimierst die Gefahr von Speicherlecks durhc das vergessen vom freigeben der Lagerliste.

Mfg Frank

[Angel4585]

so und jetzt machst du aus der Funktion noch eine Prozedur(keine Rückgabe) dann sollte es funktionieren

[Keldorn]

Zitat von Angel4585:

so und jetzt machst du aus der Funktion noch eine Prozedur(keine Rückgabe) dann sollte es funktionieren

blödes Copy&paste

[Thanatos81]

Und zusätzlich noch statt
Function Tf_hauptfenster.blablaLagerListe(Lagerliste: TStrings) folgendes:
Procedure Tf_hauptfenster.blablaLagerListe(var Lagerliste: TStringList) Denn ansonsten wird es nichts in die übergeben StringList geschrieben und du hast nach dem Aufruf der Procedure noch den gleichen Inhalt in der SL wie vorher

Falls ich mich da in Bezug auf TStringList irre und es nicht als var übergeben werden muss, steinigt mich bitte

[Keldorn]

du brauchst kein Var bei Objekten.

[Thanatos81]

Oh! Okay wieder was gelernt... DAnke für den Hinweis