ShowMessage auf bestimmten Bildschirm

[DevilsCamp]

Ich arbeite z.Z. an einem PC mit mehreren Bildschirmen.

In einem Projekt erstelle ich bei einer bestimmten Situation im OnCreate-Ereignis ein Ausgabe mit ShowMessage. Nun musste ich feststellen, dass diese IMMER auf dem Primär-Bildschirm angezeigt wird.
Gibt es eine Möglichkeit, ShowMessage auf einem bestimmten Bildschirm darstellen zu lassen?



Hier mein Code:

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
begin
  MRSetForm := TSetForm.Create(Self, true);
  MRSetForm.Free;

  ShowMessage('Hallo');
end;

Create von TSetForm:

Delphi-Quellcode:

constructor TSetForm.Create(AOwner: TComponent; const docenter: Boolean = false);
var
  x   : Integer;
  y   : Integer;
  i   : Integer;
  mo  : TPoint;

  p : TPoint;
  m : TMonitor;
  n : TMonitor;
  a : Integer;
begin
  inherited Create(AOwner);

  if (AOwner is TForm) then
    myOwner := TForm(AOwner)
  else
    myOwner := nil;

  if (Assigned(myOwner)) then
  begin
    x := myOwner.Left;
    y := myOwner.Top;
    mo.X  := x;
    mo.Y  := y;

    GetCursorPos(p);

    m := Screen.MonitorFromPoint(mo);
    n := Screen.MonitorFromPoint(p);

    if (not docenter) then
    begin
      x := x-m.Left+n.Left;
      y := y-m.Top+n.Top;
    end
    else
    begin
      x := n.Left+(n.Width div 2)-(myOwner.Width div 2);
      y := n.Top+(n.Height div 2)-(myOwner.Height div 2);
    end;

    myOwner.Left  := x;
    myOwner.Top   := y;
  end;
end;

MRSetForm ist also nur dazu da, die Form, die als Owner angegeben wurde, auf dem Bildschirm darzustellen, auf dem der Mauszeiger sich gerade befindet.
Nur leider hält sich ShowMessage da nicht dran

[RavenIV]

versuche es doch mal mit MessageDlg(...).

Zitat:

aus der Delphi-Hilfe:
...
Die Parameter X und Y sind die Bildschirmkoordinaten des Meldungsfensters. Der Wert -1 bedeutet, dass das Meldungsfenster an keiner bestimmten Position angezeigt wird.
...

[DevilsCamp]

Funktioniert leider nur solange die Koordinaten POSITIV sind. Sobald eine Negativ ist, funktioniert das ganze nicht mehr.

Und da ich bei mir Bildschirme habe, die Negative Koordinaten haben, muss ich einen anderen Weg finden (zumal Anwender des Programms ebenfalls negative Koordinaten besitzen könnten).

BTW:
Sobald das Fenster angezeigt wurde, wird der ShowMessage-Dialog auf dem Bildschirm angezeigt, auf dem sich das Formular befindet, durch das ShowMEssage aufgerufen wurde.

[ringli]

Also ich löse das bei mir folgendermassen:

Delphi-Quellcode:

function MessageDialog(const Msg: string; 
                       DlgType: TMsgDlgType; 
                       Buttons: TMsgDlgButtons;
                       const HelpFileName: String; 
                       HelpCtx: Longint; 
                       Default: String): Integer;
var
  ActForm : TCustomForm;
begin
  with CreateMessageDialog(Msg, DlgType, Buttons) do
    try
      Font.Name   := 'MS Shell Dlg';
      HelpContext := HelpCtx;
      HelpFile    := HelpFileName;
      ActForm     := Screen.ActiveForm;
      If ActForm = nil then
        begin
          Position := poMainFormCenter;
        end
      else
        begin
          Left := Round (ActForm.Left + ((ActForm.Width div 2) - (Width div 2)));
          Top := Round (ActForm.Top + ((ActForm.Height div 2) - (Height div 2)));
        end;
      ActiveControl := TButton(FindComponent(Default));
      Result := ShowModal;
    finally
      Free;
    end;
end;

Dadurch zentriert sich die Hinweisbox immer auf dem Fenster meiner Anwendung. Und ich kann einen bestimmten Button als Default deklarieren.

[DevilsCamp]

Zitat von ringli:

Also ich löse das bei mir folgendermassen: [...]

Ich habe den Code so abgeändert, dass ich die Koordinaten angeben kann, wo der Dialog angezeigt werden soll:

Delphi-Quellcode:

function MessageDialog(const Msg: string;
                       Titel: PChar;
                       DlgType: TMsgDlgType;
                       Buttons: TMsgDlgButtons;
                       const HelpFileName: String;
                       HelpCtx: Longint;
                       Default: String;
                       const X, Y: Integer): Integer;
var
  ActForm : TCustomForm;
  DlgForm : TForm;
  SetForm : TSetForm;
begin
  DlgForm := CreateMessageDialog(Msg, DlgType, Buttons);
  with DlgForm do
    try
      if (Titel<>nil) then
        DlgForm.Caption := Titel;
        
      Font.Name   := 'MS Shell Dlg';
      HelpContext := HelpCtx;
      HelpFile    := HelpFileName;
      ActForm     := Screen.ActiveForm;
      Left  := X;
      Top   := Y;
      ActiveControl := TButton(FindComponent(Default));
      Beep;
      Result := ShowModal;
    finally
      Free;
    end;
end;

Der Code funktioniert auch gut, allerdings habe ich da noch ein Problem. Sobald die Form die Aktive ist, die diese Funktion aufruft passiert folgendes:
Left hat zwar den Wert X, angezeigt wird der Dialog allerdings immer auf dem Bildschirm, auf dem sich die aktive Form befindet. Left hat dann scheinbar den Wert

Code:

Left = (Left MOD (Bildschirmbreite))+(Linker Rand des Monitors, auf dem aktive Form liegt)

D.h. ich kann den Dialog NICHT auf einem anderen Bildschirm anzeigen lassen, wie die aktive Form (z.B. auf dem Monitor, auf dem sich gerade der Mauszeiger befindet).