Eigene Komponete von TEdit ableiten?

[SirThornberry]

ich hatte bei mir unter delphi7 den Effekt wenn ich den Text ändere (im Designer) das die Farbe sich auch nicht geändert hat. Dementsprechend hab ich das ganze noch erweitert und jetzt funktionierts bei mir. Vielleicht behebt das auch den Effekt von dir:

Delphi-Quellcode:

type
  TEdit = class(StdCtrls.TEdit)
  protected
    fCheckEmpty: Boolean;
    fEmptyColor: TColor;
    fNonEmptyColor: TColor;
    procedure Change; override;
    procedure FCM_TextChanged(var AMsg: TMessage); message CM_TEXTCHANGED;
    procedure FSetCheckEmpty(AValue: Boolean);
    procedure FSetColor(AType: Integer; AColor: TColor);
    procedure FUpdateColor;
  public
    constructor Create(AOwner: TComponent); override;
  published
    property CheckEmpty: Boolean read fCheckEmpty write fSetCheckEmpty default True;
    property ColorEmpty: TColor Index 0 read fEmptyColor write FSetColor;
    property Color: TColor Index 1 read fNonEmptyColor write FSetColor;
  end;


implementation

constructor TEdit.Create(AOwner: TComponent);
begin
  fCheckEmpty := True;
  fEmptyColor := clBlue;
  inherited Create(AOwner);
  fNonEmptyColor := inherited Color;
  FUpdateColor;
end;

procedure TEdit.Change;
begin
  inherited;
  FUpdateColor;
end;

procedure TEdit.FCM_TextChanged(var AMsg: TMessage);
begin
  inherited;
  FUpdateColor;
end;

procedure TEdit.FSetCheckEmpty(AValue: Boolean);
begin
  if AValue <> fCheckEmpty then
  begin
    fCheckEmpty := AValue;
    FUpdateColor;
  end;
end;

procedure TEdit.FSetColor(AType: Integer; AColor: TColor);
  procedure LSetVal(var ACurrVal: TColor);
  begin
    if (ACurrVal <> AColor) then
    begin
      ACurrVal := AColor;
      if fCheckEmpty then
        FUpdateColor;
    end;
  end;
begin
  case AType of
    0: LSetVal(fEmptyColor);
    1: LSetVal(fNonEmptyColor);
  end;
end;

procedure TEdit.FUpdateColor;
var LColor: TColor;
begin
  if fCheckEmpty then
  begin
    if Self.Text = '' then
      LColor := fEmptyColor
    else
      LColor := fNonEmptyColor;
  end else
    LColor := fNonEmptyColor;
  if LColor <> inherited Color then
    inherited Color := LColor;
end;

Ich denke innerhalb des Designmode wurde einfach das ändern des Textes nicht wahrgenommen. Wenn also die Komponente bei dir kopiert wurde so war der Text leer. Dadurch dann auch die EmptyColor. Der Designer fügt dann den Standardnamen hinzu bzw. den aus der Zwischenablage (beim Create ist der Text ja noch leer) und dieses ändern wird nicht registriert.

[Sharky]

Jetzt geht es

Ich danke dir für die Mühe.