wer Programmiert mit Inno Setups ?

[Coder]

Hallo!

Ich wollte mal fragen, wer von Euch mit inno noch individuelle Setups erstellt.
Also richtig Code einfügt.

[FriFra]

Ich

[eddy]

Hallo FriFra,

das war ja eine superknappe Antwort. Da ich heute das erste Mal über InnoSetup gestolpert bin: Hast Du eine selbstgebastelte ISS-Datei für Anfänger zum Vergleichen, die Du hier zur Verfügung stellen kannst?

mfg
eddy

[FriFra]

Hier ist mal eine kleine iss-Datei:
[code=delphi]#define AppVersion GetFileVersion("..\MailAgent.exe")
#define AppDescription GetFileDescription("..\MailAgent.exe")
#define AppCopyright GetFileCopyright("..\MailAgent.exe")

[InstallRun]
Filename: {sys}\net.exe; Parameters: stop MailAgent;Flags: runhidden skipifdoesntexist;
Filename: {app}\MailAgent_svc.exe; Parameters: /uninstall /silent;Flags: skipifdoesntexist;

[Setup]
AppPublisher=FriFra Informatik eK
AppPublisherURL=http://www.frifra.de/
AppVersion=1
VersionInfoVersion={#AppVersion}
VersionInfoDescription=Setup - {#AppDescription}
VersionInfoCopyright={#AppCopyright}

AppName=MailAgent (BETA RC4)
AppVerName=MailAgent 1.0
DefaultDirName={pf}\MailAgent
DefaultGroupName=MailAgent
UninstallDisplayIcon={app}\MailAgent.exe
Compression=lzma/max
SolidCompression=yes
WizardImageFile=compiler:WizModernImage-IS.bmp
WizardSmallImageFile=compiler:WizModernSmallImage-IS.bmp
SetupIconFile=..\ico\MailAgent_Setup.ico
AppMutex=FriFraMailAgent

[Languages]
Name: en; MessagesFile: compilerefault.isl; LicenseFile: lizenz_en.rtf
Name: sp; MessagesFile: compiler:Languages\Serbian.isl; LicenseFile: lizenz_en.rtf
Name: de; MessagesFile: compiler:Languages\German.isl; LicenseFile: lizenz_de.rtf

[Messages]
sp.BeveledLabel=Srpski
en.BeveledLabel=English
de.BeveledLabel=Deutsch

[CustomMessages]
URL_HOME=http://www.frifra.de
URL_LANG=http://www.frifra.de/download/additional/MailAgent/language/
de.RemoveApp=MailAgent entfernen
en.RemoveApp=remove MailAgent
sp.RemoveApp=ukloni MailAgent
de.CreateDesktopShortcut=Verknüpfung auf dem Desktop erstellen
en.CreateDesktopShortcut=Create a Desktop shortcut
sp.CreateDesktopShortcut=Napravi precicu na Desktop
de.LaunchNow=MailAgent jetzt starten
en.LaunchNow=launch MailAgent
sp.LaunchNow=pokreni MailAgent
de.HomePageLink=Homepage besuchen
en.HomePageLink=visit homepage
sp.HomePageLink=poseti homepage

[Files]
Source: ..\MailAgent.exe; DestDir: {app}

[INI]
Filename: {app}\MailAgent.ini; Section: Language; Key: DllName; String: lang_eng.dll; Languages: en
Filename: {app}\MailAgent.ini; Section: Language; Key: DllName; String: lang_srp.dll; Languages: sp

[UninstallDelete]
Type: files; Name: {app}\*.exe
Type: files; Name: {app}\*.ini
Type: files; Name: {app}\*.txt
Type: files; Name: {app}\*.dll

[Icons]
Name: {group}\MailAgent; Filename: {app}\MailAgent.exe
Name: {group}\{cm:RemoveApp}; Filename: {uninstallexe}

[Tasks]
; zusätzliche Aufgaben
Name: desktopicon; Description: {cm:CreateDesktopShortcut}

[_ISToolDownload]
Source: {cm:URL_LANG}lang_eng.dll; DestDir: {app}; DestName: lang_eng.dll; Languages: en
Source: {cm:URL_LANG}lang_srp.dll; DestDir: {app}; DestName: lang_srp.dll; Languages: sp

[Run]
; nach der Installation ausführen
Filename: {app}\MailAgent.exe; Description: {cm:LaunchNow}; WorkingDir: {app}; Flags: postinstall nowait skipifsilent

[UninstallRun]
Filename: {sys}\net.exe; Parameters: stop MailAgent; Flags: runhidden skipifdoesntexist
Filename: {app}\MailAgent_svc.exe; Parameters: /uninstall /silent; Flags: skipifdoesntexist

Code:

const
  COLOR_HIGHLIGHT = 13;

function GetSysColor(nIndex: integer): cardinal;
  external '[e-mail] stdcall';

const
  szUrl = 'http://www.frifra.de';

procedure UrlLabelClick(Sender: TObject);
var
  ErrorCode: Integer;
begin
  ShellExec('open', szUrl, '', '', SW_SHOW, ewNoWait, ErrorCode);
end;

procedure InitializeWizard;
var
  CancelBtn: TButton;
  UrlLabel: TNewStaticText;
begin
  CancelBtn := WizardForm.CancelButton;
  UrlLabel := TNewStaticText.Create(WizardForm);
  UrlLabel.Top := CancelBtn.Top + (CancelBtn.Height div 2) - (UrlLabel.Height div 2);
  UrlLabel.Left := WizardForm.ClientWidth - CancelBtn.Left - CancelBtn.Width;
  UrlLabel.Caption := ExpandConstant('{cm:HomePageLink}');
  UrlLabel.Font.Style := UrlLabel.Font.Style + [fsUnderline];
  UrlLabel.Cursor := crHand;
  UrlLabel.Font.Color := GetSysColor(COLOR_HIGHLIGHT);
  UrlLabel.OnClick := @UrlLabelClick;
  UrlLabel.Parent := WizardForm;
end;

[Coder]

naja, meine Frage war deshalb, weil ich mit den Zusatztools auch nich ganz klar komme..
wollt mit dem
Formular Designer
eigene Formulare einbinden..
aber hab das dennoch nicht hinbekommen.
gibt zwar auch dieses komische inno board, aber die sind - hab ich das Gefühl - nicht so freundlich.


Formular Designer << arbeitet Ihr auch damit?
oder welche guten deutsche!! Anleitungen außer von Mathias Sammer gibt es noch?

[dfried]

Für die Erstellung der ISS-Dateien für Inno-Setup kann ich dir das Programm ISTool sehr empfehlen, das macht die ganze Sache doch etwas einfacher!

[FriFra]

Ich arbeite übrigens auch mit ISTool

[eddy]

Hallo Leute,

ich war gerade noch mal auf der Seite von jrsoftware, habe da aber nirgendwo ein Download für ein ISTool gefunden. Hat jemand mal ein Link?

@FriFra,

danke für die ISS-Datei. Da habe ich gleich noch ein Beispiel zum Anpassen und Probieren, sollte sich aber, wenn ich Eure Kommentare richtig interpretiere, wohl erledigt haben, wenn ich das ISTool verwende.

mfg
eddy

[Kevin]

istool = Der erste Eintrag...

[Coder]

ja, ISTool nehm ich auch
aber der Formdesigner macht doch das ganze interessanter...
nur: wie deklariere ich alle die Komponenten und schreib da den Code rein usw.?

das hat noch nicht ganz funktioniert