Treeview rukursiv füllen?

[TriphunEM]

hallo, ich probier rum und rum bekomm es aber nicht gebacken, ein treeview rekursiv zu füllen.
ich hole mir die daten aus einer db.

die baustruktur wird mit id, parent_id definiert.
d.h. ist parent_id 0 ist es in der rootebene, ansonsten ein jeweiligen unterelement zur passenden id.

kann mir jemand helfen???

Danke

[HariboHunter]

benutze ein wenig die Suche - Funktion. Hilft bei Treeview sehr.

habe dort das hier gefunden:

Code:

Procedure SearchText1(ANode : TTreeNode; Const ASearchText : String; AOutPut : TStrings);
Begin
    // 1. Suchtext suchen
  If ( Pos(ASearchText, ANode.Text) > 0 ) Then
    AOutPut.Add('Node "' + ANode.Text + '" Level ' + IntToStr(ANode.Level) +
                ' Index ' + IntToStr(ANode.Index));

    // 2. Kinder durchsucehn
  If ( ANode.getFirstChild <> Nil ) Then
    SearchText1(ANode.GetFirstChild, ASearchText, AOutPut);

    // 3. Knoten auf gleicher Ebene durchsuchen
  If ( ANode.getNextSibling <> Nil ) Then
    SearchText1(ANode.getNextSibling, ASearchText, AOutPut);
End;          

 
Procedure SearchText2(ANode : TTreeNode; Const ASearchText : String; AOutPut : TStrings);
Begin
    // 1. Suchtext suchen
  If ( Pos(ASearchText, ANode.Text) > 0 ) Then
    AOutPut.Add('Node "' + ANode.Text + '" Level ' + IntToStr(ANode.Level) +
                ' Index ' + IntToStr(ANode.Index));

    // 2. nächsten Knoten holen
  If ( ANode.getNext <> Nil ) Then
    SearchText2(ANode.GetNext, ASearchText, AOutPut);
End;

ist von nem anderen, keine Ahnung von wem. Funktioniert aber (das 2., das erste hab ich net probiert.)


edit:
Urg ich bin doof, das ist da um das Treeview nach nem Eintrag zu durchsuchen.
Um es zu füllen benutze die Funktionen

addchild... mom hier etwas code.

Code:

  

             for i:= 1 to *INTEGER* do
                begin;
                      with form1.treeview1.Items.Addchild(  nil,  *STRING*  ) do  
            begin..

damit fügst Du dann die Children ein...

[TriphunEM]

naja, wie ich ein child einfüge weiß ich ja, ich komm aber mit der rekursiven sache nicht so auf den grünen zweig. irgendwie ist das ergebnis nicht wie ich will. die suchfunktion hab ich schon gequält, hab aber nix gefunden. den es geht ja um die angabe der id und parent_id!

[Pfoto]

Ich hatte dieses Problem auch...

Es werden mehrere Lösungen hier im Forum angeboten.


Ich poste hier eine Lösung, die ich in einem Demoprogramm der Datenbank TinyDB gefunden habe,
denn da ich den VirtuelStringTree benutze, ich die Umsetzung dort etwas anders.

Delphi-Quellcode:

procedure TMainForm.FillFolderTreeView;

  procedure FillTreeNode(TreeNode: TTreeNode);
  var
    I, FolderID: Integer;
    Node: TTreeNode;
  begin
    // Tabelle nach ID des aktuellen Nodes filtern (als ParentID), um dessen Childs zu finden
    FolderID := Integer(TreeNode.Data);
    FolderTinyTable.Filter := 'ParentID=' + IntToStr(FolderID);
    FolderTinyTable.Filtered := True;
    FolderTinyTable.First;
    // Gefundene Childs der gefilterten Tabelle als Nodes erstellen
    for I := 0 to FolderTinyTable.RecordCount - 1 do
    begin
      Node := TreeView.Items.AddChild(TreeNode, FolderTinyTable.FieldByName('Name').AsString);
      // Die ID des Eintrags dem Node mit auf den Weg geben
      Node.Data := Pointer(FolderTinyTable.FieldByName('ID').AsInteger);
      Node.ImageIndex := 1;
      Node.SelectedIndex := 1;
      FolderTinyTable.Next;
    end;
    // Rekursiv für jeden Unterknoten aufrufen
    for I := 0 to TreeNode.Count - 1 do
      FillTreeNode(TreeNode.Item[I]);
  end;

begin
  TreeView.Items.BeginUpdate;
  TreeView.Items.Clear;
  // Root-Knoten erstellen
  with TreeView.Items.Add(nil, SAddressBook) do
  begin
    Data := Pointer(0);
    ImageIndex := 0;
    SelectedIndex := 0;
  end;
  // Root-Knoten übergeben
  FillTreeNode(TreeView.Items[0]);
  TreeView.FullExpand;
  TreeView.Items.EndUpdate;
end;

Es wird hier auch gleich die ID mitgespeichert, so dass du diese beim Click auf einen Node auslesen und entsprechend an eine Tabelle oder Query übergeben kannst.


Für große Mengen kann die oben genannte Methode jedoch etwas langsam sein.
Andere Möglichkeiten wären z.B. nur die sichtbaren Knoten einzulesen und erst bei Bedarf weitere einzulesen (wie z.B. im Explorer)
Außerdem gibt es noch die Möglichkeit, erst eine Sortierung nach ParentID und ID vorzunehmen und dann dieser sortierten Abfrage nach alle Knoten zu erstellen (es muss dann darauf geachtet werden, dass ein Parent-Knoten bereits existiert, bevor ein Child-Knoten eingefügt wird).
Und noch eine Lösung habe ich in Erinnerung, bei der die Child-Knoten erst später entsprechend zu ihren Parent-Knoten verschoben worden sind.

Wenn du dazu Einzelheiten wissen willst, schau bitte nochmal in der Suche, da habe ich es auch her.