Problem beim auswerten eines Threadergebnisses

[Luckie]

Warum lässt du dich nicht über ein Ereignis vom Thread benachrichtigen, wenn er fertig ist udn gibst dem Ereignis die Ergebnisse als Parameter mit?

Kleines Demo.

Thread:

Delphi-Quellcode:

unit Unit2;

interface

uses
  Classes;

type
  TOnFinish = procedure(Sender: TObject; Value: Integer) of object;
  TMyThread = class(TThread)
  private
    FValue: Integer;
    FOnFinish: TOnFinish;
    procedure DoNotifyFinish;
  protected
    procedure Execute; override;
  public
    property OnFinish: TOnFinish read FOnFinish write FOnFinish;
  end;

implementation

{ TMyThread }

procedure TMyThread.DoNotifyFinish;
begin
  if Assigned(OnFinish) then
    OnFinish(Self, FValue);
end;

procedure TMyThread.Execute;
var
  i: Integer;
begin
  FValue := 0;
  for i := 0 to High(Integer) - 1 do
    Inc(FValue);
  Synchronize(DoNotifyFinish);
end;

end.

Hauptprogramm:

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
    procedure OnFinish(Sender: TObject; Value: Integer);
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

uses
  Unit2;

procedure TForm1.Button1Click(Sender: TObject);
var
  MyThread: TMyThread;
begin
  MyThread := TMyThread.Create(True);
  MyThread.FreeOnTerminate := True;
  MyThread.OnFinish := OnFinish;
  MyThread.Resume;
end;

procedure TForm1.OnFinish(Sender: TObject; Value: Integer);
begin
  ShowMessage(IntToStr(Value));
end;

end.