Unterordner eines Ordners suchen

[Van HelF]

Ich habe ein problem, und zwar will ich ein programm schreiben, dass mir alle UNTERORDNER (und auch deren) anzeigt.
Ich möchte darauf hinweisen, dass ich sehr wohl die forumsuche und google dazu genutzt habe entsprechende beispiele zu finden, bisher jedoch ohne erfolg. Prinzipiell wurde dann immer auf "dateien in unterordnern suchen" verwiesen, aber das will ich ja nicht.
Ich bräuchte ein beispiel, wie man sich nur die unterordner(und deren) eines ordners in einer listbox ausgeben lassen kann.

[Khabarakh]

Du kannst mir nicht erzählen, dass dir die Suche nicht FindFirst ausgespuckt hat . Besonders der zweite Parameter dürfte interessant sein. Wie man die Funktion (+ FindNext und FindClose) verwendet, siehst du zum Beispiel bei FindAllFiles.

[St.Pauli]

Man muss sich ja nicht mit FindFirst / FindNext rumschlagen. In der Codelib sind ja auch Beiträge zum suchen von Dateien, die dann einfach ein bisschen umschreiben...

Delphi-Quellcode:

procedure GetFilesInDirectory(Directory: String; const Mask: String;
                              List: TStrings;
                              WithSubDirs, ClearList: Boolean);

procedure ScanDir(const Directory: String);
var
  SR: TSearchRec;
  Dir : string;
begin
  if FindFirst(Directory + Mask, faAnyFile, SR) = 0 then try
    repeat
      Application.ProcessMessages;
      IF (Dir <> Directory) THEN
        begin
          List.Add(Directory);
          Dir := Directory;
        end;
    until FindNext(SR) <> 0;
  finally
    FindClose(SR);
  end;

  if WithSubDirs then begin
    if FindFirst(Directory + '*.*', faAnyFile, SR) = 0 then try
      repeat
        Application.ProcessMessages;
        if ((SR.attr and faDirectory) = faDirectory) and
           (SR.Name <> '.') and (SR.Name <> '..') then
          ScanDir(Directory + SR.Name + '\');
      until FindNext(SR) <> 0;
    finally
      FindClose(SR);
    end;
  end;
end;

begin
  List.BeginUpdate;
  try
    if ClearList then
      List.Clear;
    if Directory = '' then Exit;
    if Directory[Length(Directory)] <> '\' then
      Directory := Directory + '\';
    ScanDir(Directory);
  finally
    List.EndUpdate;
  end;
end;

Aufruf:

GetFilesInDirectory('C:\', '*.*', ListBox1.Items, True, True); Natürlich ist die Methode etwas zeitintensiv....

Edit1: Application.ProcessMessages...

[marabu]

Wenn alle Stricke reißen - die DirectoryListBox aus der Palette "Win 3.1" kann vielleicht schon alles, was du willst.

Grüße vom marabu

[Van HelF]

Sicher kenne ich findfirst ich habe auch schon versucht eine function hier im forum umzubasteln (durch ändern von faanyfile, in fadirectory) hat jedoch nicht den gewünschten effekt erbracht. Hat mir trotzdem noch dateien angezeigt.

Zur directorylistbox: die verwende ich monentan, nur es haben sich einige probleme damit ergeben, deswegen suche ich einen anderen weg

[St.Pauli]

Zitat von Van HelF:

Sicher kenne ich findfirst ich habe auch schon versucht eine function hier im forum umzubasteln (durch ändern von faanyfile, in fadirectory) hat jedoch nicht den gewünschten effekt erbracht. Hat mir trotzdem noch dateien angezeigt.

Look @ meine Funktion. Einfach die Parameter Attribute belassen und mim String altes und neues Directory vergleichen...

[Van HelF]

Ich verstehe nicht ganz was du meinst, bzw damit bezweckst ...

[marabu]

Hier das ganze in Grün - aber mit TreeView zur Visualisierung:

Delphi-Quellcode:

procedure AllFolders(root: string; nodes: TTreeNodes; tnParent: TTreeNode);
var
  sr: TSearchRec;
  tn: TTreeNode;
begin
  root := IncludeTrailingPathDelimiter(root);
  if FindFirst(root + '*.*', faAnyFile, sr) = 0 then
  try
    repeat
      Application.ProcessMessages;
      if (sr.Name <> '.')
      and (sr.Name <> '..')
      and ((sr.Attr and faDirectory) = faDirectory) then
      begin
        tn := nodes.AddChild(tnParent, sr.Name);
        AllFolders(root + sr.Name, nodes, tn);
      end else
        Continue;
    until FindNext(sr) <> 0;
  finally
    FindClose(sr);
  end;
end;

procedure TDemoForm.ListButtonClick(Sender: TObject);
begin
  with TreeView do
  begin
    Items.Clear;
    Items.BeginUpdate;
    AllFolders('C:\DATEN', Items, nil);
    Items.EndUpdate;
  end;
end;

marabu

[Van HelF]

Ich danke, habe es auf eine listbox umgeschrieben und es funktioniert ...