Ableitung von TObject muss Windows Messages Empfangen...

[Kedariodakon]

So Jungens hier hab ich mal ein etwas kniffliges Problem (Zu mindest fuer mich)!
Ich habe eine Klasse welche Windowsmessages empfangen muß...

Die Kommunikation über Messages habe ich mir nicht einfallen lassen und kann sie daher nicht entfernen...
Das Object initalisiert später eine dll, welche das Handle und die Messages bekommt welche sie später zurücksendet...

Hier seh ich nun 2 Möglichkeiten:
1. Globale Windowsmessages...
2. Die Möglichkeit direkt Messages mit dem TObject zu empfangen...

Entschieden habe ich mich fuer Variante 2, da Globale Messages Das ganze System belasten würden... (Vor allem wo ich nicht genau sagen kann in welchem Umfang die Messages gesendet werden...)
TObject deshalb, da das Object universell einsetzbar sein muss/soll, (Programm, Konsolenanwendung, Dll...)

Nun meine Frage hat jemand eine Ahnung wie ich das anstelle?
Es muss doch eine Möglichkeit geben Irgendwas, Irgendwo, Irgendwie in Windows zu regestrieren um ein Handle zu haben und natuerlich auch die Möglichkeit dies zu deregestrieren...

Bin jetzt konnte ich nichts Sinvolles finden...

Wie das TApplication macht, bin ich auch nicht wirklich dahintergestiegen
Scheinbar hat das aber mit der Funktion RegisterClass zu tun, aber was da noch alles mitspielt konnt ich nicht erkennen/finden

Hat schonmal jemand sowas in der Art gemacht und kann mir da weiterhelfen?

Bye

[BenjaminH]

Dein TObject muss einObject muss ganz einfach ein Nachfahre von TWinControl sein, dann hat es ein Handle..

[Dax]

Mit TObject Messages empfangen? Viel Spass Um sowas tun zu können, brauchst du ein Fenster.. also mindestens mal ein TWinControl, dann dürfte das schon eher gehen..

Hier im Forum gabs glaube ich auch mal ein paar Fragen und Antworten zu dem Thema. Kann mich leider nicht entsinnen wo

[Kedariodakon]

Zitat von BenjaminH:

Dein TObject muss einObject muss ganz einfach ein Nachfahre von TWinControl sein, dann hat es ein Handle..

TwinControl setzt einen Owner vooraus, und einer der Owner is dann die Form mit Handle ein eigegenes hat es IMHO nicht...

Bye

[Jens Schumann]

Hallo,
und hier hätten wir die Lösung

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;


const

  PM_MyMessage = WM_USER+1000;

type
  TMessageObject = class(TObject)
  private
    FWindowHandle: THandle;
    FOnMessage: TNotifyEvent;
  protected
     procedure DoMessage; virtual;
     procedure WndProc(var Msg: TMessage);
  public
    constructor Create;
    destructor Destroy; override;
    property Handle : THandle read FWindowHandle;
    property OnMessage : TNotifyEvent read FOnMessage write FOnMessage;
  end;

  TForm1 = class(TForm)
    Button1: TButton;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
    FMessageObject : TMessageObject;
    procedure OnMessage(Sender : TObject);
  public
    { Public-Deklarationen }
  end;


var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TMessageObject }

constructor TMessageObject.Create;
begin
  inherited Create;
  FWindowHandle:=AllocateHWnd(WndProc);
end;

destructor TMessageObject.Destroy;
begin
  DeallocateHWnd(FWindowHandle);
  inherited Destroy;
end;

procedure TMessageObject.DoMessage;
begin
  If Assigned(FOnMessage) then
    FOnMessage(Self);
end;

procedure TMessageObject.WndProc(var Msg: TMessage);
begin
  With Msg do
    If Msg = PM_MyMessage then
      Try
        DoMessage;
      Except
        Application.HandleException(Self);
      end
    else
      Result := DefWindowProc(FWindowHandle, Msg, wParam, lParam);
end;

{ TForm1 }

procedure TForm1.OnMessage(Sender: TObject);
begin
  ShowMessage('Yes');
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  FMessageObject:=TMessageObject.Create;
  FMessageObject.OnMessage:=OnMessage;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  FMessageObject.Free;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  SendMessage(FMessageObject.Handle,PM_MyMessage,0,0);
end;

end.

Ich habe etwas bei TTimer abgeguckt

[SirThornberry]

du kannst auch TObject nehmen und mit AllocateHWnd ein unsichtbares Fenster erzeugen, und die Nachrichten dafür dann an deine Procedure schicken. Allerdings funktioniert das nicht in einer Consolenanwendung wenn du dort die Windowmessages nicht verarbeitest (Nachrichtenschleife). Also in einer standardconsolenanwendung kannst du dein Object mit den Messages vergessen (außer du machst es in nem Thread, oder machst dem Programmierer begreiflich warum er in einer Konsolenanwendung jedesmal eine Nachrichtenschleife braucht)
Hier findest du den Ansatz:
http://www.delphipraxis.net/internal...=391495#391495

da war Jens wohl schneller, aber das Problem mit der Konsolenanwendung besteht und wird auch nicht einfach so verschwinden.

[Kedariodakon]

Danke an die letzten beiden Poster (Jens Schumann, SirThornberry) Das hilft mir schon mal sehr weiter!
Wuerde sowas in einem Dienst laufen, falls es dort anwendung finden sollte?

Bye

[SirThornberry]

in einem Dienst sollte es laufen, allerdings braucht der Dienst dann auch eine Nachrichtenschleife. Um die kommst du nicht herum wenn du mit windowmessages arbeiten willst/musst.

[Kedariodakon]

Ein paar sachen sind mir noch unklar:

1.

Delphi-Quellcode:

//...
  Application.HandleException(Self); 
//...

Was macht das genau? die Exception weiterreichen? Warum? Zweck?

2.

Delphi-Quellcode:

//...
  Result := DefWindowProc(FWindowHandle, Msg, wParam, lParam); 
//...

Ich nehme mal an Result ist das Msg.Result Richtig?
DefWindowProc reicht die Message weiter da sie nicht bearbeitet wurde oder?

Bye

[SirThornberry]

DefWindowProc ist die Windowprocedure von Windows. Wenn man also sich nicht um die Abarbeitung einer bestimmten Message kümmern will im Programm leitet man die Message dort hinn weiter und somit wird das Standardzeugs ausgeführt (zum Beispiel wenn man wm_paint nicht selbst verarbeiten will malt windows das Fenster standardmäßig). Ja, result ist Msg.Result
Dadurch das im Beispielquelltext ganz oben " With Msg do" steht braucht man später nicht mehr das "msg." davor schreiben.