Mehrere Fragen zu TEdit + sinnvollem Programmaufbau

[xaromz]

Hallo,

Zitat von DashRendar:

Danke für Deine Antwort. Allerdings verstehe ich nur die Antwort auf meine dritte Frage. Mit dem "getter" und properties habe ich zumind. in Delphi noch nie gearbeitet und mir ist auch nicht ganz klar wie man über die Eigenschaften einer Klasse das Ein-, Auslesen und "interne" speichern von mehreren TEdit-Werten regelt. Ja, ich habe auch in der Borland-Hilfe zum "getter" geguckt, aber aus den Beispieln / Erklärungen die da stehen werde ich auch nicht schlau.

Wie Du die Properties einsetzt, hängt davon ab, wie Dein Formular aussieht.
Ich werde mal ein Beispiel skizzieren. Dabei geht es um die Eingabe einer Adresse. Sämtliche Felder lassen sich lesen, der Name zusätzlich ändern:

Delphi-Quellcode:

interface

type
  TForm1 = class(TForm)
    UserNameEdit: TEdit;
    StreetEdit: TEdit;
    PostalEdit: TEdit;
    CityEdit: TEdit;
    TelephoneEdit: TEdit;
  private
    function GetUserName: String;
    function GetStreet: String;
    function GetCity: String;
    function GetQualifiedCity: String;
    function GetTelephone: String;
    procedure SetUserName(const Value: String);
  public
    property UserName: String read GetUserName write SetUserName;
    property Street: String read GetStreet;
    property City: String read GetCity;
    property QualifiedCity: String read GetQualifiedCity;
    property Telephone: String read GetTelephone;
  end;

implementation

function TForm1.GetUserName: String;
begin
  Result := UserNameEdit.Text;
end;

function TForm1.GetStreet: String;
begin
  Result := StreetEdit.Text;
end;

function TForm1.GetCity: String;
begin
  Result := CityEdit.Text;
end;

function TForm1.GetQualifiedCity: String;
begin
  // z. B. Postleitzahl und Stadt zurückgeben
  Result := PostalEdit + '-' + CityEdit.Text;
end;

function TForm1.GetTelephone: String;
begin
  Result := TelephoneEdit.Text;
end;

procedure TForm1.SetUserName(const Value: String);
begin
  UserNameEdit.Text := Value;
end;

Jetzt kannst Du auf die Eingaben ganz einfach zugreifen:

Delphi-Quellcode:

//Lesen
Name := Form1.UserName;
Street := Form1.Street;
City := Form1.City;
Telephone := Form1.Telephone;

//Schreiben
Form1.UserName := 'Schmidt';

Wid Du siehst, musst Du außerhalb des Formulars nicht wissen, wie die Edits heißen. Du musst nicht einmal wissen, ob es überhaupt welche gibt.
In den Getter- und Setter-Methoden kannst Du außerdem noch zusätzliche Prüfungen einbauen oder die Ausgabe verändern (wie z. B. bei GetQualifiedCity).

Zitat von DashRendar:

Gibt es also auch eine nicht-OOP Lösung für Frage 2 und 3? Im übrigen hatte ich ja nicht vor globale Variablen zu deklarieren, sondern die Variabeln im public-Teil des Interfaces zu deklarieren, mit einer Trennung von Oberfläche und Programmlogik wärs dann allerdings schon vorbei.

Es gibt natürlich immer eine nicht-OOP-Lösung. Aber sowas werde ich hier nicht verbreiten. Ich will Dich ja nicht versauen .
Wie ich oben schon schrieb, auch im Public-Teil sollten Variablen vermieden werden. Du wirst in der gesamten VCL keinen Fall erleben, in dem eine Variable als Public deklariert wäre.

Gruß
xaromz