Probleme mit Streams und Read bzw. Write

[Alex_ITA01]

Hallo erstmal,
ich habe folgendes Problem. In einer Stringliste habe ich jede Menge Objecte die ich alle als Stream abspeichern will. Also ich will die Stringliste als Stream abspeichern und später wieder laden können (eine kleine Art Datenbank...).

Hier der Sourceausschnitt:
Im Debugger ist beim Speichern alles ganz gut gelaufen (in den Daten stehen richtige Werte).
Nur das Laden funktioniert nicht. In meinem Datensatz steht immer "Mist"...

MFG Alex

Delphi-Quellcode:

type
  PDatensatz = ^TDatensatz;
  TDatensatz = record
    FStr1,
    FStr2,
    FStr3,
    FStr4   : String;
  end;

...

procedure TMainForm.MI_SpeichernClick(Sender: TObject);
var
  TmpStream : TFileStream;
  i : Integer;
  Datensatz : PDatensatz;
begin
  SaveDialog1.InitialDir := ExtractFilePath(Application.ExeName);
  if SaveDialog1.Execute then
  begin
    TmpStream   := TFileStream.Create(SaveDialog1.FileName, fmCreate);

    for i := 0 to SL.Count - 1 do
    begin
      TObject(Datensatz) := SL.Objects[i];
      TmpStream.Write(Datensatz^, SizeOf(TDatensatz));
    end;
    TmpStream.Free;
  end;
end;
{ ---------------------------------------------------------------------------- }
procedure TMainForm.MI_LadenClick(Sender: TObject);
var
  TmpStream : TFileStream;
  Datensatz : PDatensatz;
begin
  OpenDialog1.InitialDir := ExtractFilePath(Application.ExeName);
  if OpenDialog1.Execute then
  begin
    TmpStream   := TFileStream.Create(OpenDialog1.FileName, fmOpenRead);

    New(Datensatz);
    TmpStream.Read(Datensatz^, SizeOf(TDatensatz));
    if Assigned(Datensatz) then
    begin
      if Assigned(SL) then
        SL.AddObject(IntToStr(SL.Count + 1),TObject(Datensatz));
    end;
    
    TmpStream.Free;
  end;
end;

[Bernhard Geyer]

Probiers mal damit

Delphi-Quellcode:

  TDatensatz = record
    FStr1,
    FStr2,
    FStr3,
    FStr4   : String[200];
  end;

Der Delphi-String-Typ ist was spezielles. In deinem Record wird bei einfacher Angabe von String nur eine Zeiger auf einen Speicherbereich vermerkt, wo dann der String mit Länge und Refernzzählung liegt. D.h. in deiner Datei landet auch nur der Zeicher auf den eigentlichen String.
Mit String[200] wird wirklich soviel Speicher in deinem Record reserviert und auch entsprechend in deiner Datei gespeichert.

[Alex_ITA01]

achso, verstehe...
würde es dann auch gehen, wenn ich ein  packed record daraus mache?

MFG Alex

[Alex_ITA01]

wie mache ich das eigentlich, dass ich in einer Art Schleife einlese, denn ich weiß ja nicht wie viele Datensätze ich gespeichert habe vorher...

Danke Bernhard Geyer... Es hat so geklappt!!!

[Bernhard Geyer]

Zitat von Alex_ITA01:

wie mache ich das eigentlich, dass ich in einer Art Schleife einlese, denn ich weiß ja nicht wie viele Datensätze ich gespeichert habe vorher...

Wenn das Position-Property gleich dem Size-Property ist bist du am Dateiende.

[Alex_ITA01]

okay Danke schön!!!
MFG Alex

[barf00s]

das würde aber bedeuten das ein einziger datensatz 800 bytes belegt (4*200bytes)
das könnte man auch verkleinern in dem man "string" lässt und lediglich die speicher"routine" abändert

um nen string innem stream zu speichern könnte man sich folgender prozedur bedienen

Delphi-Quellcode:

procedure WriteStringToStream(Stream: TStream; const Value: string);
begin
  Stream.Write(Length(Value, 4); // 4 = SizeOf(Length(Value)) = SizeOf(Integer)
  Stream.Write(Value[1], Length(Value));
end;

das lesen analog dazu

Delphi-Quellcode:

procedure ReadStringFromStream(Stream: TStream; var Value: string); // wenn nötig kann man das var auch weglassen
var
  iLength: integer;

begin
  Stream.Read(iLength, 4);
  SetLength(Value, iLength);
  Stream.Read(Value[1], iLength);
end;

[Alex_ITA01]

okay, dass mit der Datengröße ist ein Argument
Aber wieso meckert der Compiler bei folgender Zeile:

Delphi-Quellcode:

procedure TMainForm.WriteStringToStream(Stream: TStream; Value: string);
begin
  Stream.Write(Length(Value), 4); // <----------- VARIABLE Erforderlich...
  Stream.Write(Value[1], Length(Value));
end;

MFG Alex